WOLFRAM

Wolfram Language & System Documentation Center

ImageTrim[image,roi]

gives the smallest subimage of image that includes the specified region of interest roi.

ImageTrim[image,roi,r]

adds a margin of size r back to the resulting image.

ImageTrim[image,{roi1,roi2,…},…]

extracts multiple subimages specified by roii from image.

ImageTrim[video,…]

extracts the subimages from video.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Region of Interest  
Margin  
Options  
DataRange  
Padding  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

ImageTrim

ImageTrim[image,roi]

gives the smallest subimage of image that includes the specified region of interest roi.

ImageTrim[image,roi,r]

adds a margin of size r back to the resulting image.

ImageTrim[image,{roi1,roi2,…},…]

extracts multiple subimages specified by roii from image.

ImageTrim[video,…]

extracts the subimages from video.

Details and Options

  • Image trimming, also known as image cropping, is the process of removing border pixels from an image and is typically used for extracting regions of interest.
  • ImageTrim[image,roi] returns a subimage containing the region of interest roi. The region roi can be any of the following:
  • {{x1,y1},…}or {{x1,y1,z1},…}a list of 2D or 3D image positions
    regiona 2D or 3D geometric region (Point, Rectangle, etc.)
    maskimagenonzero pixels of a 2D or 3D object
    fa region returned by a function f
  • For video inputs, the trim specification can be a fixed specification for all frames or a function of time (in seconds from the start).
  • ImageTrim assumes the standard image coordinate system.
  • For integer coordinate values the trimmed image will include all pixels touching the point . Coordinates lie at the center of pixels. »
  • ImageTrim[image,{pt1,…},{rx,ry}] specifies different horizontal and vertical margins.
  • The following options can be given:
  • DataRange Fullrange of pixel positions in image
    Padding Nonepadding scheme to use
  • By default, if fewer elements exist than are requested, ImageTrim returns the elements that are present. By setting the Padding option to anything else, pixels outside the original image can also be included. »
  • Possible settings for DataRange include:
  • Automatic{{0,1},{0,h/w}} in 2D, {{0,1},{0,d/w},{0,h/w}} in 3D
    Full{{0,w},{0,h}} in 2D, {{0,1},{0,d},{0,h}} in 3D (default)
    {{left,right},{bottom,top}}explicit coordinate ranges in 2D
    {{left,right},{front,back},{bottom,top}}explicit coordinate ranges in 3D

Examples

open all close all

Basic Examples  (1)

Trim an image:

Wolfram Language code: ImageTrim[[image], {{30, 30}, {100, 100}}]

Scope  (7)

Data  (3)

Trim a 2D image:

Wolfram Language code: ImageTrim[[image], {{30, 30}, {170, 100}}]

Trim frames of a video:

Wolfram Language code: ImageTrim[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\), {{160, 20}, {320, 180}}]

Trim a 3D image:

Wolfram Language code: ImageTrim[[image], {{0, 0, 0}, {50, 50, 16}}]

Region of Interest  (3)

Extract a single-pixel image:

Wolfram Language code: ImageTrim[[image], {140, 30}]

Extract an image containing a list of positions:

Wolfram Language code: ImageTrim[[image], {{0, 10}, {60, 120}}]

Specify the region of interest using a graphics primitive:

Wolfram Language code: ImageTrim[[image], Rectangle[{0, 10}, {60, 120}]]

Extract an image containing the nonzero pixels of a reference image:

Wolfram Language code: ImageTrim[[image], [image]]

Define the region of interest using a function:

Wolfram Language code: ImageTrim[[image], PixelValuePositions[#, Red, .4]&]

Trim multiple regions of interest:

Wolfram Language code: ImageTrim[[image], {Rectangle[{0, 10}, {60, 120}], Rectangle[{120, 0}, {165, 100}]}]

Trim frames of a video using a region that evolves with time:

Wolfram Language code: ImageTrim[\!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-83a60)"]\), t  {{50t, 50}, {100 + 50t, 150}}]

Extract three slices from a 3D image:

Wolfram Language code: i = \!\(\*Graphics3DBox[«10»]\); ImageTrim[i, {{1, 1, 15}, {46, 46, 17}}]

Trim multiple regions of interest:

Wolfram Language code: ImageTrim[i, {Cuboid[{0, 0, 0}, {23, 23, 23}], Cuboid[{23, 23, 23}, {0, 46, 46}]}]

Margin  (1)

By default, no extra margin is added to the trimmed regions:

Wolfram Language code: i = [image];
Wolfram Language code: ImageTrim[i, Rectangle[{50, 10}, {105, 80}]]

This is equivalent to zero margin:

Wolfram Language code: ImageTrim[i, Rectangle[{50, 10}, {105, 80}], 0]

Use a larger margin:

Wolfram Language code: ImageTrim[[image], Rectangle[{50, 10}, {105, 80}], 20]

Options  (2)

DataRange  (1)

Remove pixels from each side using the standard coordinate system:

Wolfram Language code: i = [image];
Wolfram Language code: ImageTrim[i, {{30, 30}, {170, 90}}]

This is equivalent to DataRange->Full:

Wolfram Language code: ImageTrim[i, {{50, 30}, {150, 90}}, DataRange -> Full]

Remove 25% of pixels from each side using a scaled coordinate system:

Wolfram Language code: ImageTrim[i, {{.25, .25}, {.75, .75}}, DataRange -> {{0, 1}, {0, 1}}]

Padding  (1)

By default, the returned subimage is not padded to include coordinates outside of an image:

Wolfram Language code: ImageTrim[[image], {{80, 70}, {250, 200}}]

Pad the subimage to include all specified coordinates:

Wolfram Language code: ImageTrim[[image], {{80, 70}, {250, 200}}, Padding -> Red]

Applications  (7)

Trim faces detected from an image:

Wolfram Language code: i = [image];
Wolfram Language code: ImageTrim[i, FindFaces[i]]

Trim lines of detected text from an image:

Wolfram Language code: i = [image];
Wolfram Language code: Framed /@ ImageTrim[i, TextRecognize[i, "Line", "BoundingBox"]]//Column

Trim the detected barcode:

Wolfram Language code: i = [image];
Wolfram Language code: ImageTrim[i, BarcodeRecognize[i, "BoundingBox"]]

Trim the area around the maximum:

Wolfram Language code: ImageTrim[[image], ImageValuePositions[#, "Max"]&, 30]

Trim around an object of a specific color:

Wolfram Language code: i = [image];
Wolfram Language code: ImageTrim[i, ImageValuePositions[i, Red, .2], 10]

Trim areas that contain no keypoints:

Wolfram Language code: i = [image];
Wolfram Language code: ImageTrim[i, ImageKeypoints[#, "KeypointStrength" -> .0001]&]

Add some margins around keypoints:

Wolfram Language code: ImageTrim[i, ImageKeypoints[#, "KeypointStrength" -> .0001]&, 20]

Trim a 3D image to a detected region of interest:

Wolfram Language code: knee = ExampleData[{"TestImage3D", "MRknee"}]

Find the region of interest:

Wolfram Language code: roi = DeleteSmallComponents[Erosion[Binarize[knee], 3]]

Trim the volume around it:

Wolfram Language code: ImageTrim[ knee, roi]

Mask the image with the region of interest before trimming:

Wolfram Language code: ImageTrim[roi knee, roi]

Properties & Relations  (2)

Half-integer coordinates represent the center of the pixels and return the specific pixel:

Wolfram Language code: ImageTrim[[image], {1.5, 1.5}]

Integer coordinates yield an image including all neighboring pixels:

Wolfram Language code: ImageTrim[[image], {2, 2}]

Show the two pixel positions on the image:

Wolfram Language code: HighlightImage[[image], {Black, PointSize[.1], {2, 2}, {1.5, 1.5}, Dashed, Line[{{1.5, 0}, {1.5, 1.5}, {0, 1.5}}], Line[{{2, 0}, {2, 2}, {0, 2}}]}, Axes -> True, ImageSize -> 200]

Trimming with multiple coordinates is the same as using their bounds:

Wolfram Language code: coords = {{137, 117}, {138, 62}, {189, 19}, {193, 133}, {191, 16}, {136, 16}, {150, 26}, {193, 83}, {173, 85}, {175, 29}}; ImageTrim[i = [image], coords]

Compute the coordinate bounds:

Wolfram Language code: bounds = Transpose[CoordinateBounds[coords]]
Wolfram Language code: ImageTrim[i, coords] == ImageTrim[i, bounds]
Wolfram Research (2010), ImageTrim, Wolfram Language function, https://reference.wolfram.com/language/ref/ImageTrim.html (updated 2021).

Text

Wolfram Research (2010), ImageTrim, Wolfram Language function, https://reference.wolfram.com/language/ref/ImageTrim.html (updated 2021).

CMS

Wolfram Language. 2010. "ImageTrim." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2021. https://reference.wolfram.com/language/ref/ImageTrim.html.

APA

Wolfram Language. (2010). ImageTrim. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ImageTrim.html

BibTeX

@misc{reference.wolfram_2026_imagetrim, author="Wolfram Research", title="{ImageTrim}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/ImageTrim.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_imagetrim, organization={Wolfram Research}, title={ImageTrim}, year={2021}, url={https://reference.wolfram.com/language/ref/ImageTrim.html}, note=[Accessed: 13-June-2026]}