WOLFRAM

Wolfram Language & System Documentation Center

Rectangle[{xmin,ymin},{xmax,ymax}]

represents an axis-aligned filled rectangle from {xmin,ymin} to {xmax,ymax}.

Rectangle[{xmin,ymin}]

corresponds to a unit square with its bottom-left corner at {xmin,ymin}.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Options  
RoundingRadius  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

Rectangle

Rectangle[{xmin,ymin},{xmax,ymax}]

represents an axis-aligned filled rectangle from {xmin,ymin} to {xmax,ymax}.

Rectangle[{xmin,ymin}]

corresponds to a unit square with its bottom-left corner at {xmin,ymin}.

Details and Options

Examples

open all close all

Basic Examples  (5)

A unit square:

Wolfram Language code: Graphics[Rectangle[]]

Two squares:

Wolfram Language code: Graphics[{Red, Rectangle[{0, 0}], Blue, Rectangle[{0.5, 0.5}]}]

Various rectangles:

Wolfram Language code: Graphics[{Red, Rectangle[{0, 0}, {1, 3}], Blue, Rectangle[{2, 1}, {4, 2}]}]

Differently styled rectangles:

Wolfram Language code: {Graphics[{Pink, Rectangle[]}], Graphics[{EdgeForm[Thick], Pink, Rectangle[]}], Graphics[{EdgeForm[Dashed], Pink, Rectangle[]}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, Rectangle[]}]}

Area and centroid:

Wolfram Language code: Area[Rectangle[{x1, y1}, {x2, y2}]]
Wolfram Language code: RegionCentroid[Rectangle[{x1, y1}, {x2, y2}]]

Scope  (17)

Graphics  (7)

Specification  (3)

A unit square:

Wolfram Language code: Graphics[Rectangle[{1, 1}]]

A rectangle parallel to each axis:

Wolfram Language code: Graphics[Rectangle[{0, 0}, {2, 1}]]

Short form for a unit cube with corner at the origin:

Wolfram Language code: Graphics[Rectangle[], Frame -> True]

Styling  (1)

Color directives specify the face colors of rectangles:

Wolfram Language code: Table[Graphics[{c, Rectangle[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary of a rectangle:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], Rectangle[]}]

Coordinates  (3)

Use Scaled coordinates:

Wolfram Language code: Graphics[Rectangle[Scaled[{0, .4}], Scaled[{1, .6}]], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]

Use ImageScaled coordinates:

Wolfram Language code: Graphics[Rectangle[ImageScaled[{0, .4}], ImageScaled[{1, .6}]], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]

Use Offset coordinates:

Wolfram Language code: Graphics[Rectangle[Offset[{10, 20}, {0, 0}], Offset[{-10, -20}, {1, 1}]], Frame -> True]

Regions  (10)

Embedding dimension:

Wolfram Language code: RegionEmbeddingDimension[Rectangle[{Subscript[x, min], Subscript[y, min]}, {Subscript[x, max], Subscript[y, max]}]]

Geometric dimension:

Wolfram Language code: RegionDimension[Rectangle[{Subscript[x, min], Subscript[y, min]}, {Subscript[x, max], Subscript[y, max]}]]

Point membership test:

Wolfram Language code: ℛ = Rectangle[{0, 0}];
Wolfram Language code: {RegionMember[ℛ, {0, 1}], RegionMember[ℛ, {0, 2}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Area:

Wolfram Language code: ℛ = Rectangle[{0, 0}];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = Rectangle[{-1, -1}, {1, 1}];
Wolfram Language code: {RegionDistance[ℛ, {2, 3}], RegionDistance[ℛ, {1, 0}]}

Plot it:

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}, ∞] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = Rectangle[{-1, -1}, {1, 1}];
Wolfram Language code: {SignedRegionDistance[ℛ, {2, 3}], SignedRegionDistance[ℛ, {0, 0}]}

Plot it:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}, ∞] == 1]

Nearest point in the region:

Wolfram Language code: ℛ = Rectangle[{1, 2}, {3, 4}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

Nearest points:

Wolfram Language code: pts = Table[{2, 3} + 4{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A rectangle is bounded:

Wolfram Language code: ℛ = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: BoundedRegionQ[ℛ]

Get its bounds:

Wolfram Language code: rr = RegionBounds[ℛ]

Integrate over a rectangle:

Wolfram Language code: ℛ = Rectangle[{Subscript[x, min], Subscript[y, min]}, {Subscript[x, max], Subscript[y, max]}];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

Optimize over a rectangle:

Wolfram Language code: ℛ = Rectangle[{1, 2}, {3, 4}];
Wolfram Language code: Minimize[{x y - x, {x, y}∈ℛ}, {x, y}]

Solve equations in a rectangle:

Wolfram Language code: ℛ = Rectangle[{1, 2}, {3, 4}];
Wolfram Language code: Reduce[x^2 + y^2 == 7 && {x, y}∈ℛ, {x, y}]

Options  (1)

RoundingRadius  (1)

Use rounded corners:

Wolfram Language code: Graphics[Rectangle[{0, 0}, {2, 1}, RoundingRadius -> 0.3]]
Wolfram Language code: Table[Graphics[Rectangle[{0, 0}, {2, 1}, RoundingRadius -> m], PlotLabel -> m], {m, {0, .1, 2, .5}}]

Applications  (6)

A simple bar chart:

Wolfram Language code: data = RandomReal[{3, 10}, {10, 2}];
Wolfram Language code: Graphics[{EdgeForm[StandardGray], Blue, Table[{Blue, Rectangle[{i - .4, 0}, {i, data[[i, 1]]}], Red, Rectangle[{i + .4, 0}, {i, data[[i, 2]]}]}, {i, 10}]}, AspectRatio -> 1 / GoldenRatio, Frame -> True]

Golden rectangle:

Wolfram Language code: gr[0] := {{0, 0}, {1, -1}}; gr[n_] := Module[{ϕ = GoldenRatio, a, b, c, d}, {{a, b}, {c, d}} = gr[n - 1]; Switch[Mod[n, 4], 0, {{a, d}, {a + ϕ ^ -n, d - ϕ ^ -n}}, 1, {{c, d + ϕ ^ -n}, {c + ϕ ^ -n, d}}, 2, {{c - ϕ ^ -n, b + ϕ ^ -n}, {c, b}}, 3, {{a - ϕ ^ -n, b}, {a, b - ϕ ^ -n}}]];
Wolfram Language code: Graphics[{EdgeForm[Opacity[.5]], Table[{ColorData[24, k + 1], Rectangle@@gr[k]}, {k, 0, 8}]}]

Square wheel:

Wolfram Language code: Animate[With[{q = Quotient[θ, π / 2], m = Mod[θ, π / 2]}, Graphics[{EdgeForm[Gray], LightGray, Rotate[Rectangle[{q, 0}], -m, {q + 1, 0}]}, Axes -> {True, False}, PlotRange -> {{-.5, 5.5}, {-0.5, 1.5}}, ImageSize -> 350]], {θ, 0, 2Pi}, AnimationRunning -> False, AnimationDirection -> ForwardBackward, DefaultDuration -> 2]

The trajectory of the square wheel:

Wolfram Language code: Graphics[{EdgeForm[Gray], FaceForm[LightGray], Table[With[{q = Quotient[θ, π / 2], m = Mod[θ, π / 2]}, Rotate[Rectangle[{q, 0}], -m, {q + 1, 0}]], {θ, 0, 2Pi, Pi / 12}]}, Axes -> {True, False}, PlotRange -> {{-.5, 5.5}, {-0.5, 1.5}}, ImageSize -> 350]

A Rectangle with equal side lengths is a square:

Wolfram Language code: SquareRegion[{x_, y_}, r_] := Rectangle[{x, y}, {x + r, y + r}]
Wolfram Language code: SquareRegion[{1, 2}, 3]

Visualize it:

Wolfram Language code: Region[%]

Maximize the area of a rectangle with a fixed perimeter:

Wolfram Language code: r = Rectangle[{0, 0}, {x, y}]; Maximize[{Area[r], 2x + 2y == 4 && 0 < x && 0 < y}, {x, y}, Reals]

The resulting rectangle is a square:

Wolfram Language code: Region[r /. {x -> 1, y -> 1}]

Indeed, it will always be a square:

Wolfram Language code: Assuming[p > 0, Simplify[Maximize[{Area[r], 2x + 2y == p && 0 < x && 0 < y}, {x, y}, Reals]]]

Properties & Relations  (9)

Use Rotate to get all possible rectangles:

Wolfram Language code: Graphics[{Pink, Rotate[Rectangle[{0, 0}, {4, 3}], 30Degree]}, Frame -> True]

Rectangle is a special case of Cuboid:

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[{0, 0}, {1, 1}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Rectangle is a special case of Parallelogram:

Wolfram Language code: Subscript[ℛ, 1] = Parallelogram[{0, 0}, {{1, 0}, {0, 1}}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Rectangle is a special case of Polygon:

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Rectangle is the union of two Triangle objects:

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: t1 = Triangle[{{0, 0}, {1, 0}, {1, 1}}]; t2 = Triangle[{{1, 1}, {0, 1}, {0, 0}}]; Subscript[ℛ, 2] = RegionUnion[t1, t2];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Language code: Region[Subscript[ℛ, 2]]

ImplicitRegion can represent any Rectangle region:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 ≤ x ≤ 1 && 0 ≤ y ≤ 1, {x, y}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion can represent any Rectangle region:

Wolfram Language code: Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 1}, {v, 0, 1}}]; Subscript[ℛ, 2] = Rectangle[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

MeshRegion can represent any Rectangle region:

Wolfram Language code: MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 3, 4}]]
Wolfram Language code: RegionEqual[%, Rectangle[]]

BoundaryMeshRegion can represent any Rectangle region:

Wolfram Language code: BoundaryMeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Line[{1, 2, 3, 4, 1}]]
Wolfram Language code: RegionEqual[%, Rectangle[]]

Possible Issues  (1)

RoundingRadius only affects Graphics:

Wolfram Language code: RegionMeasure[Rectangle[{0, 0}, {1, 1}, RoundingRadius -> 1 / 3]]
Wolfram Language code: {DiscretizeGraphics[Rectangle[{0, 0}, {1, 1}, RoundingRadius -> 1 / 3]], Graphics[Rectangle[{0, 0}, {1, 1}, RoundingRadius -> 1 / 3]]}

Neat Examples  (3)

A collection of random squares:

Wolfram Language code: Graphics[{EdgeForm[Black], Table[{Hue[RandomReal[]], Rotate[Rectangle[RandomReal[2, 2]], RandomReal[2Pi]]}, {20}]}]

A color wheel:

Wolfram Language code: Animate[Graphics[{EdgeForm[Opacity[.5]], Table[{Hue[(t + k) / 20, 1, .9], Rotate[Rectangle[{1, -Sin[Pi / 20]}, {1 + 2Sin[Pi / 20], Sin[Pi / 20]}], 2Pi t / 20, {0, 0}]}, {t, 20}]}], {k, 1, 20}, AnimationRunning -> False]

Digital petals:

Wolfram Language code: Graphics[Table[{EdgeForm[Opacity[.6]], Hue[(-11 + q + 10 r) / 72], With[{t = 2Pi q / 12}, Rotate[Rectangle[(8 - r)({Cos[t], Sin[t]} - 1 / 4), (8 - r)({Cos[t], Sin[t]} + 1 / 4)], t + Pi / 4]]}, {r, 6}, {q, 12}]]
Wolfram Research (1988), Rectangle, Wolfram Language function, https://reference.wolfram.com/language/ref/Rectangle.html (updated 2019).

Text

Wolfram Research (1988), Rectangle, Wolfram Language function, https://reference.wolfram.com/language/ref/Rectangle.html (updated 2019).

CMS

Wolfram Language. 1988. "Rectangle." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Rectangle.html.

APA

Wolfram Language. (1988). Rectangle. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Rectangle.html

BibTeX

@misc{reference.wolfram_2026_rectangle, author="Wolfram Research", title="{Rectangle}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Rectangle.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_rectangle, organization={Wolfram Research}, title={Rectangle}, year={2019}, url={https://reference.wolfram.com/language/ref/Rectangle.html}, note=[Accessed: 13-June-2026]}