WOLFRAM

Wolfram Language & System Documentation Center

InverseJacobiSC[v,m]

gives the inverse Jacobi elliptic function .

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation and Integration  
Series Expansions  
Function Identities and Simplifications  
Other Features  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

InverseJacobiSC

InverseJacobiSC[v,m]

gives the inverse Jacobi elliptic function .

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • gives the value of u for which .
  • InverseJacobiSC has branch cut discontinuities in the complex v plane with branch points at and infinity, and in the complex m plane with branch points at and infinity.
  • The inverse Jacobi elliptic functions are related to elliptic integrals.
  • For certain special arguments, InverseJacobiSC automatically evaluates to exact values.
  • InverseJacobiSC can be evaluated to arbitrary numerical precision.
  • InverseJacobiSC automatically threads over lists.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: InverseJacobiSC[3.5, 0.3]//Chop
Wolfram Language code: JacobiSC[%, 0.3]

Plot the function over a subset of the reals:

Wolfram Language code: Plot[InverseJacobiSC[x, 1 / 2], {x, -10, 10}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[InverseJacobiSC[z, 1 / 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansions at the origin:

Wolfram Language code: Series[InverseJacobiSC[z, m], {z, 0, 7}]
Wolfram Language code: Series[InverseJacobiSC[z, m], {m, 0, 1}]

Scope  (29)

Numerical Evaluation  (5)

Evaluate to high precision:

Wolfram Language code: N[InverseJacobiSC[3, 1 / 2], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: InverseJacobiSC[3, 0.5000000000000000000000000000000000]

Evaluate for complex arguments:

Wolfram Language code: InverseJacobiSC[1.2 + 0.3I, 1.5 - I]

Evaluate InverseJacobiSC efficiently at high precision:

Wolfram Language code: InverseJacobiSC[3, 0.5`500]//Timing
Wolfram Language code: InverseJacobiSC[3, 0.5`50000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: InverseJacobiSC[Around[3, 0.01], .5]

Compute the elementwise values of an array:

Wolfram Language code: InverseJacobiSC[{{-I, 0}, {0, I}}, 1]

Or compute the matrix InverseJacobiSC function using MatrixFunction:

Wolfram Language code: MatrixFunction[InverseJacobiSC[#, 1]&, {{-I, 0}, {0, I}}]//FullSimplify

Specific Values  (4)

Simple exact results are generated automatically:

Wolfram Language code: {InverseJacobiSC[ν, 0], InverseJacobiSC[ν, 1]}
Wolfram Language code: {InverseJacobiSC[0, m], InverseJacobiSC[I, m]}

Values at infinity:

Wolfram Language code: InverseJacobiSC[ν, Infinity]
Wolfram Language code: InverseJacobiSC[Infinity, m]

Find a real root of the equation TemplateBox[{x, {1, /, 3}}, InverseJacobiSC]=1:

Wolfram Language code: f[x_] := InverseJacobiSC[x, 1 / 3] - 1; xzero = Solve[f[x] == 0 && 1.0 < x < 2.0, x][[1, 1, 2]]//Quiet
Wolfram Language code: Plot[f[ν], {ν, 0, 2}, Epilog -> Style[Point[{xzero, f[xzero]}], PointSize[Large], Red]]

Parity transformation is automatically applied:

Wolfram Language code: InverseJacobiSC[-ν, m]

Visualization  (3)

Plot InverseJacobiSC for various values of the second parameter :

Wolfram Language code: Plot[{InverseJacobiSC[ν, -5], InverseJacobiSC[ν, 0], InverseJacobiSC[ν, 1], InverseJacobiSC[ν, 2]}, {ν, -3, 3}]

Plot InverseJacobiSC as a function of its parameter :

Wolfram Language code: Plot[{InverseJacobiSC[1, m], InverseJacobiSC[3 / 2, m], InverseJacobiSC[2, m]}, {m, -3, 3}]

Plot the real part of TemplateBox[{z, 2}, InverseJacobiSC]:

Wolfram Language code: ComplexContourPlot[Re[InverseJacobiSC[z, 2]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of TemplateBox[{z, 2}, InverseJacobiSC]:

Wolfram Language code: ComplexContourPlot[Im[InverseJacobiSC[z, 2]], {z, -3 - 3I, 3 + 3I}, IconizedObject[«PlotOptions»]]

Function Properties  (6)

InverseJacobiSC is not an analytic function:

Wolfram Language code: FunctionAnalytic[InverseJacobiSC[x, m], {x, m}]

It has both singularities and discontinuities:

Wolfram Language code: Reduce[FunctionSingularities[InverseJacobiSC[x, 3], x], x, Reals]//Quiet
Wolfram Language code: Reduce[FunctionDiscontinuities[InverseJacobiSC[x, 3], x], x, Reals]//Quiet

TemplateBox[{x, 3}, InverseJacobiSC] is nondecreasing on its real domain:

Wolfram Language code: FunctionMonotonicity[{InverseJacobiSC[x, 3], (-1/Sqrt[2]) < x < (1/Sqrt[2])}, x]

TemplateBox[{x, {1, /, 3}}, InverseJacobiSC] is injective:

Wolfram Language code: FunctionInjective[InverseJacobiSC[x, 1 / 3], x]
Wolfram Language code: Plot[{InverseJacobiSC[x, 1 / 3], .3}, {x, -5, 5}]

TemplateBox[{x, 3}, InverseJacobiSC] is not surjective:

Wolfram Language code: FunctionSurjective[InverseJacobiSC[x, 3], x]
Wolfram Language code: Plot[{InverseJacobiSC[x, 3], 2}, {x, -5, 5}]

TemplateBox[{x, {1, /, 3}}, InverseJacobiSC] is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[InverseJacobiSC[x, 1 / 3], x]

TemplateBox[{x, {1, /, 3}}, InverseJacobiSC] is neither convex nor concave:

Wolfram Language code: FunctionConvexity[InverseJacobiSC[x, 1 / 3], x]

Differentiation and Integration  (4)

First derivative:

Wolfram Language code: D[InverseJacobiSC[ν, m], ν]

Higher derivatives:

Wolfram Language code: derivs = Table[D[InverseJacobiSC[ν, m], {ν, n}], {n, 1, 3}]//Simplify

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. m -> 2], {ν, -1, 1}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Differentiate InverseJacobiSC with respect to the second argument :

Wolfram Language code: D[InverseJacobiSC[ν, m], m]

Definite integral of an odd function over an interval centered at the origin is 0:

Wolfram Language code: Integrate[InverseJacobiSC[ν, m], {ν, -ν0, ν0}, Assumptions -> ν0∈Reals]

Series Expansions  (3)

Taylor expansion for TemplateBox[{nu, m}, InverseJacobiSC] around :

Wolfram Language code: Series[InverseJacobiSC[ν, m], {ν, 0, 5}]

Plot the first three approximations for TemplateBox[{nu, 2}, InverseJacobiSC] around :

Wolfram Language code: terms = Normal@Table[Series[InverseJacobiSC[ν, 2], {ν, 0, n}], {n, 2, 12, 4}]; Plot[{InverseJacobiSC[ν, 2], terms}, {ν, -1.1, 1.1}]

Taylor expansion for TemplateBox[{nu, m}, InverseJacobiSC] around :

Wolfram Language code: Series[InverseJacobiSC[ν, m], {m, 0, 3}]//FullSimplify

Plot the first three approximations for TemplateBox[{nu, m}, InverseJacobiSC] around :

Wolfram Language code: terms = Normal@Table[Series[InverseJacobiSC[2, m], {m, 0, n}], {n, 1, 3}]; Plot[{InverseJacobiSC[2, m], terms}, {m, -1, 1}]

InverseJacobiSC can be applied to a power series:

Wolfram Language code: InverseJacobiSC[ν, Exp[m] + O[m] ^ 2]

Function Identities and Simplifications  (2)

InverseJacobiSC is the inverse function of JacobiSC:

Wolfram Language code: Solve[ν == JacobiSC[u, m], u][[1, 1]]//Quiet

Compose with inverse function:

Wolfram Language code: {InverseJacobiSC[JacobiSC[ν, m], m], JacobiSC[InverseJacobiSC[ν, m], m]}

Use PowerExpand to disregard multivaluedness of the inverse function:

Wolfram Language code: PowerExpand[%]

Other Features  (2)

InverseJacobiSC threads elementwise over lists:

Wolfram Language code: InverseJacobiSC[{ν1, ν2}, m]

TraditionalForm formatting:

Wolfram Language code: InverseJacobiSC[ν, m]//TraditionalForm

Applications  (2)

Plot contours of constant real and imaginary parts in the complex plane:

Wolfram Language code: Table[ContourPlot[f[InverseJacobiSC[x + I y, 1 + I]], {x, -3, 3}, {y, -3, 3}, Contours -> 24], {f, {Re, Im}}]

Construct lowpass elliptic filter for analog signal:

Wolfram Language code: 𝒩 = 5;ωPass = 4.8;ℊPass = 0.92;ℊStop = 0.08;

Compute filter ripple parameters and associate elliptic function parameter:

Wolfram Language code: ϵp = Sqrt[ℊPass^-2 - 1];ϵs = Sqrt[ℊStop^-2 - 1]; m1 = (ϵp / ϵs)^2; K1 = EllipticK[m1]; K1p = EllipticK[1 - m1];

Use elliptic degree equation to find the ratio of the pass and the stop frequencies:

Wolfram Language code: us = Range[1, 2⌊(𝒩/2)⌋ - 1, 2] / 𝒩; m = 1 - (1 - m1) ^ 𝒩 Apply[Times, JacobiSN[us K1p, 1 - m1] ^ 8]

Compute corresponding stop frequency and elliptic parameters:

Wolfram Language code: K = EllipticK[m];Kp = EllipticK[1 - m]; ωStop = ωPass / Sqrt[m]

Compute ripple locations and poles and zeros of the transfer function:

Wolfram Language code: ζs = JacobiCD[us K, m]; zeros = I ωStop / ζs;

Compute poles of the transfer function:

Wolfram Language code: Subscript[ν, 0] = (1/𝒩 K1)InverseJacobiSC[(1/ϵp), 1 - m1]; poles = ωPass I JacobiCD[(us - I Subscript[ν, 0])K, m];

Assemble the transfer function:

Wolfram Language code: H[ω_] = Piecewise[{{ℊPass, Mod[𝒩, 2] == 0}, {(1/1 + I ω / ωPass JacobiCS[Subscript[ν, 0] K, 1 - m]), Mod[𝒩, 2] == 1}}] Apply[Times, ((1 - I ω / zeros)(1 - I ω / Conjugate[zeros])/(1 - I ω / poles)(1 - I ω / Conjugate[poles]))];
Wolfram Language code: Plot[Abs[H[ω]], {ω, 0, 8}, PlotRange -> All, Epilog -> {Pink, Dashed, Line[{{0, ℊPass}, {ωPass, ℊPass}, {ωPass, ℊStop}}], Line[{{ωStop, ℊPass}, {ωStop, ℊStop}, {10, ℊStop}}]}]

Compare with the result of EllipticFilterModel:

Wolfram Language code: tf = EllipticFilterModel[{"Lowpass", {ωPass, ωStop}, -20Log10[{ℊPass, ℊStop}]}];
Wolfram Language code: Plot[Abs[tf[I ω]], {ω, 0, 8}]

Properties & Relations  (1)

Obtain InverseJacobiSC from solving equations containing elliptic functions:

Wolfram Language code: Solve[JacobiSC[x, m]^2 + 2JacobiSC[x, m] == a, x]
Wolfram Research (1988), InverseJacobiSC, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseJacobiSC.html.

Text

Wolfram Research (1988), InverseJacobiSC, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseJacobiSC.html.

CMS

Wolfram Language. 1988. "InverseJacobiSC." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseJacobiSC.html.

APA

Wolfram Language. (1988). InverseJacobiSC. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseJacobiSC.html

BibTeX

@misc{reference.wolfram_2026_inversejacobisc, author="Wolfram Research", title="{InverseJacobiSC}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/InverseJacobiSC.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inversejacobisc, organization={Wolfram Research}, title={InverseJacobiSC}, year={1988}, url={https://reference.wolfram.com/language/ref/InverseJacobiSC.html}, note=[Accessed: 13-June-2026]}