WOLFRAM

Wolfram Language & System Documentation Center

InverseRadonTransform[expr,{p,ϕ},{x,y}]

gives the inverse Radon transform of expr.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Gaussian Functions  
Piecewise and Generalized Functions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

InverseRadonTransform

InverseRadonTransform[expr,{p,ϕ},{x,y}]

gives the inverse Radon transform of expr.

Details and Options

  • The inverse Radon transform provides the mathematical basis for tomographic image reconstruction.
  • Geometrically, the inversion procedure recovers an image from the values of its Radon transform along different projections of the image for fixed angles and varying .
  • InverseRadonTransform computes a radial Fourier transform, followed by a two-dimensional inverse Fourier transform, to accomplish the above inversion. »
  • The following options can be given:
  • Assumptions$Assumptionsassumptions on parameters
    GenerateConditionsFalsewhether to generate results that involve conditions on parameters
    MethodAutomaticwhat method to use
  • In TraditionalForm, InverseRadonTransform is output using TemplateBox[{{f, (, {p, ,, phi}, )}, p, phi, x, y}, InverseRadonTransform].

Examples

open all close all

Basic Examples  (1)

Compute the inverse Radon transform of a function:

Wolfram Language code: InverseRadonTransform[E^-p^2 (Cos[ϕ]^2 + 2 p^2 Sin[ϕ]^2) , {p, ϕ}, {x, y}]

Plot the function along with the inverse transform:

Wolfram Language code: {DensityPlot[E^-p^2 (Cos[ϕ]^2 + 2 p^2 Sin[ϕ]^2), {ϕ, -π / 2, π / 2}, {p, -3, 3}, Frame -> None, Ticks -> None], DensityPlot[%, {x, -2, 2}, {y, -2, 2}, Frame -> None, Ticks -> None]}

Scope  (5)

Basic Uses  (1)

Compute the inverse Radon transform of a function for symbolic parameter values:

Wolfram Language code: InverseRadonTransform[E^-p^2 p Cos[ϕ], {p, ϕ}, {x, y}]

Use exact values for the parameters:

Wolfram Language code: InverseRadonTransform[E^-p^2 p Cos[ϕ], {p, ϕ}, {1 / 3, 1 / 5}]

Use inexact values for the parameters:

Wolfram Language code: InverseRadonTransform[E^-p^2 p Cos[ϕ], {p, ϕ}, {0.3, 0.7}]

Gaussian Functions  (2)

Inverse Radon transform of a Gaussian function:

Wolfram Language code: InverseRadonTransform[E^-p^2, {p, ϕ}, {x, y}]

Plot the function along with the inverse transform:

Wolfram Language code: {DensityPlot[E^-p^2, {ϕ, -π / 2, π / 2}, {p, -10, 10}, Frame -> None, Ticks -> None], DensityPlot[%, {x, -2, 2}, {y, -2, 2}, Frame -> None, Ticks -> None]}

Polynomial Gaussian function:

Wolfram Language code: InverseRadonTransform[E^-p^2 (1 + 2 p^2) , {p, ϕ}, {x, y}]
Wolfram Language code: {DensityPlot[E^-p^2 (1 + 2 p^2) , {ϕ, -π / 2, π / 2}, {p, -10, 10}, Frame -> None, Ticks -> None], DensityPlot[%, {x, -2, 2}, {y, -2, 2}, Frame -> None, Ticks -> None]}

Product of a polynomial Gaussian function with trigonometric functions:

Wolfram Language code: InverseRadonTransform[ E^-p^2 p (-3 + 2 p^2) Sin[ϕ] Sin[2 ϕ], {p, ϕ}, {x, y}]
Wolfram Language code: {DensityPlot[ E^-p^2 p (-3 + 2 p^2) Sin[ϕ] Sin[2 ϕ], {ϕ, -π / 2, π / 2}, {p, -2, 2}, Frame -> None, Ticks -> None, PlotPoints -> 200], DensityPlot[%, {x, -2, 2}, {y, -2, 2}, Frame -> None, Ticks -> None]}

Piecewise and Generalized Functions  (2)

Inverse Radon transform of a piecewise function:

Wolfram Language code: InverseRadonTransform[Piecewise[{{2*Sqrt[1 - p^2], -1 < p < 1}}, 0], {p, ϕ}, {x, y}]
Wolfram Language code: {DensityPlot[ Piecewise[{{2*Sqrt[1 - p^2], -1 < p < 1}}, 0], {ϕ, -π / 2, π / 2} , {p, -2, 2}, Frame -> None, Ticks -> None, PlotPoints -> 200], DensityPlot[%, {x, -2, 2}, {y, -2, 2}, Frame -> None, Ticks -> None]}

Inverse Radon transform of an expression involving DiracDelta:

Wolfram Language code: InverseRadonTransform[DiracDelta[p - a Cos[ϕ] - b Sin[ϕ]], {p, ϕ}, {x, y}]

Applications  (2)

Compute the symbolic inverse Radon transform of a function:

Wolfram Language code: InverseRadonTransform[E^-p^2 , {p, ϕ}, {x, y}]
Wolfram Language code: {DensityPlot[E^-p^2 , {ϕ, -π / 2, π / 2}, {p, -5, 5}, Frame -> None, Ticks -> None], DensityPlot[%, {x, -2, 2}, {y, -2, 2}, Frame -> None, Ticks -> None]}

Obtain the same result using InverseRadon:

Wolfram Language code: disk = Image[DiskMatrix[50, 201], "Bit"];
Wolfram Language code: {rad = Radon[disk, {201, 201}], InverseRadon[rad, {201, 201}]}

Use the Radon transform to solve a Poisson equation:

Wolfram Language code: peqn = Laplacian[u[x, y], {x, y}] == E^-x^2 - y^2 y (-2 + x^2 + y^2);

Apply RadonTransform to the equation:

Wolfram Language code: RadonTransform[peqn, {x, y}, {p, ϕ}]

Solve the ordinary differential equation using DSolveValue:

Wolfram Language code: DSolveValue[% /. {RadonTransform[u[x, y], {x, y}, {p, ϕ}] -> f[p]}, f[p], p]

Set the arbitrary constants in the solution to 0:

Wolfram Language code: % /. {C[i_] -> 0}

Obtain the solution for the original equation using InverseRadonTransform:

Wolfram Language code: sol = InverseRadonTransform[%, {p, ϕ}, {x, y}]

Verify the solution:

Wolfram Language code: peqn /. {u -> Function[{x, y}, Evaluate[sol]]}//Simplify

Plot the solution:

Wolfram Language code: Plot3D[sol, {x, -3, 3}, {y, -3, 3}, PlotRange -> All]

Properties & Relations  (3)

InverseRadonTransform and RadonTransform are mutual inverses:

Wolfram Language code: RadonTransform[InverseRadonTransform[F[p, ϕ], {p, ϕ}, {x, y}], {x, y}, {p, ϕ}]
Wolfram Language code: InverseRadonTransform[RadonTransform[f[x, y], {x, y}, {p, ϕ}], {p, ϕ}, {x, y}]

InverseRadonTransform is a linear operator:

Wolfram Language code: InverseRadonTransform[a f[p, ϕ] + b g[p, ϕ], {p, ϕ}, {x, y}]

Compute the inverse Radon transform using Fourier transforms:

Wolfram Language code: f[p_, ϕ_] := E^-p^2 p Sqrt[π] (Cos[ϕ] + Sin[ϕ])

Find the Fourier transform with respect to p:

Wolfram Language code: FourierTransform[f[p, ϕ], p, k, FourierParameters -> {0, -2π}]

Express the result in terms of a unit vector ξ = { u1,u2}, assuming that k=TemplateBox[{xi}, Abs]:

Wolfram Language code: Simplify[% /. {Sin[a_] :> TrigExpand[Sin[a]]} /. {Cos[ϕ] -> u1 / k, Sin[ϕ] -> u2 / k} /. {k -> Sqrt[u1 ^ 2 + u2 ^ 2]}, Im[u1] == 0 && Im[u2] == 0]

Compute the inverse Fourier transform with respect to { u1,u2}:

Wolfram Language code: InverseFourierTransform[%, {u1, u2}, {x, y}, FourierParameters -> {0, -2 * Pi}]

Obtain the same result directly using InverseRadonTransform:

Wolfram Language code: InverseRadonTransform[f[p, ϕ], {p, ϕ}, {x, y}]

Neat Examples  (1)

Create a table of inverse Radon transforms:

Wolfram Language code: flist = {Sqrt[Pi] / E ^ p ^ 2, (p * Sqrt[Pi] * Cos[ϕ]) / E ^ p ^ 2, ((1 / 2) * Sqrt[Pi] * (Cos[ϕ] ^ 2 + 2 * p ^ 2 * Sin[ϕ] ^ 2)) / E ^ p ^ 2, ((1 / 2) * (1 + 2 * p ^ 2) * Sqrt[Pi]) / E ^ p ^ 2, ((1 / 4) * (3 + 4 * (p ^ 2 + p ^ 4)) * Sqrt[Pi]) / E ^ p ^ 2, Piecewise[{{2 * Sqrt[1 - p ^ 2], -1 < p < 1}}, 0], ((1 / 2) * (-1 + 2 * p ^ 2) * Sqrt[Pi] * Cos[2 * ϕ]) / E ^ p ^ 2};
Wolfram Language code: Grid[Prepend[{#, InverseRadonTransform[#1, {p, ϕ}, {x, y}]}& /@ flist, {"Function", "Inverse Radon Transform"}], IconizedObject[«Grid options»]]//TraditionalForm
Wolfram Research (2017), InverseRadonTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseRadonTransform.html.

Text

Wolfram Research (2017), InverseRadonTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/InverseRadonTransform.html.

CMS

Wolfram Language. 2017. "InverseRadonTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/InverseRadonTransform.html.

APA

Wolfram Language. (2017). InverseRadonTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/InverseRadonTransform.html

BibTeX

@misc{reference.wolfram_2026_inverseradontransform, author="Wolfram Research", title="{InverseRadonTransform}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/InverseRadonTransform.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_inverseradontransform, organization={Wolfram Research}, title={InverseRadonTransform}, year={2017}, url={https://reference.wolfram.com/language/ref/InverseRadonTransform.html}, note=[Accessed: 12-June-2026]}