![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/49.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
HermiteH
HermiteH[n,x]
gives the Hermite polynomial ![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/1.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- Explicit polynomials are given for non‐negative integers n.
- The Hermite polynomials satisfy the differential equation
. - The Hermite polynomials are orthogonal polynomials with weight function
in the interval 
. - For certain special arguments, HermiteH automatically evaluates to exact values.
- HermiteH can be evaluated to arbitrary numerical precision.
- HermiteH automatically threads over lists.
- HermiteH[n,x] is an entire function of x with no branch cut discontinuities.
- HermiteH can be used with Interval and CenteredInterval objects. »
Examples
open all close allBasic Examples (5)
Compute the 10
Hermite polynomial:
HermiteH[10, x]Plot over a subset of the reals:
Plot[HermiteH[1 / 2, x], {x, -2, 2}]Plot over a subset of the complexes:
ComplexPlot3D[HermiteH[1 / 2, z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]Series expansion at the origin:
Series[HermiteH[1 / 2, x], {x, 0, 3}]//FullSimplifySeries expansion at Infinity:
Series[HermiteH[1 / 2, x], {x, ∞, 5}]//FullSimplifyScope (44)
Numerical Evaluation (6)
HermiteH[3., 5]HermiteH[.71, .87]//ChopN[HermiteH[2 / 3, 8 / 7], 50]//ChopThe precision of the output tracks the precision of the input:
HermiteH[1.30000000000000000000000000, 3]//ChopHermiteH[5.3 + I, .8 + I]Evaluate efficiently at high precision:
HermiteH[4 / 3, 8 / 7`100]//TimingHermiteH[31 / 3, 1 / 7`1000];//TimingCompute worst-case guaranteed intervals using Interval and CenteredInterval objects:
HermiteH[1 / 2, Interval[{0.1, 0.2}]]HermiteH[1 / 2, CenteredInterval[2, 1 / 100]]Or compute average-case statistical intervals using Around:
HermiteH[2, Around[.9, 0.1]]Compute the elementwise values of an array:
HermiteH[3, {{2, 0}, {1 / 2, -2}}]Or compute the matrix HermiteH function using MatrixFunction:
MatrixFunction[HermiteH[3, #]&, {{2, 0}, {1 / 2, -2}}]Specific Values (6)
Values of HermiteH at fixed points:
Table[HermiteH[10, x ], {x, 1, 5}]HermiteH for symbolic n:
HermiteH[n, 0]HermiteH[1, 0]HermiteH[0, 0]Find the first positive maximum of HermiteH[10,x ]:
xmax = x /. Solve[D[HermiteH[10, x ], x] == 0 && 0 < x < 5, x][[1]]Plot[HermiteH[10, x ], {x, -1, 1}, Epilog -> Style[Point[{xmax, HermiteH[10, xmax ]}], PointSize[Large], Red]]Compute the associated HermiteH[7,x] polynomial:
HermiteH[7, x]Different HermiteH types give different symbolic forms:
Table[HermiteH[n, x], {n, 0, 3}]Visualization (3)
Plot the HermiteH polynomial for various orders:
Plot[{HermiteH[1, x], HermiteH[2, x], HermiteH[3, x], HermiteH[4, x]}, {x, -2, 2}]
ComplexContourPlot[Re[HermiteH[10, z]], {z, -1 - I, 1 + I}, Contours -> 24]
ComplexContourPlot[Im[HermiteH[10, z]], {z, -1 - I, 1 + I}, Contours -> 24]Plot the Hermite polynomial as a function of two variables:
Plot3D[HermiteH[n, z], {n, 0, 3}, {z, -2, 2}, PlotRange -> All]Function Properties (14)
HermiteH is defined for all real and complex values:
FunctionDomain[HermiteH[n, z], z]FunctionDomain[HermiteH[n, z], z, Complexes]Approximate function range of ![TemplateBox[{2, x}, HermiteH]](Files/HermiteH.en/8.png "TemplateBox[{2, x}, HermiteH]"){kind=small}
:
FunctionRange[HermiteH[2, x], x, y]FunctionRange[HermiteH[2, z], z, y, Complexes]Hermite polynomial of an even order is even:
HermiteH[2, -x] == HermiteH[2, x]Hermite polynomial of an odd order is odd:
HermiteH[1, -x] == -HermiteH[1, x]HermiteH has the mirror property 
:
HermiteH[1, Conjugate[z]] == Conjugate[HermiteH[1, z]]HermiteH threads elementwise over lists:
HermiteH[3, {1.2, 1.5, 1.8}]![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/10.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
FunctionAnalytic[HermiteH[n, x], x, Assumptions -> n∈Reals]![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/12.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
is neither non-decreasing nor non-increasing for 
:
Table[FunctionMonotonicity[HermiteH[n, x], x], {n, 2, 5}]
FunctionMonotonicity[HermiteH[n, x], x, Assumptions -> 0 <= n < 1]
FunctionMonotonicity[HermiteH[n, x], x, Assumptions -> n < 0]![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/16.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
Table[FunctionInjective[HermiteH[n, x], x], {n, 4}]Plot[{HermiteH[1, x], HermiteH[2, x], HermiteH[3, x], 3}, {x, -3, 3}]![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/18.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
is surjective for positive odd values of for 
:
Table[FunctionSurjective[HermiteH[n, x], x], {n, 1, 7, 2}]Plot[{HermiteH[3, x], HermiteH[4, x], -35}, {x, -2.2, 2.2}]![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/20.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
FunctionSign[HermiteH[n, x], x, Assumptions -> n <= 0, StrictInequalities -> True]
Table[FunctionSign[HermiteH[n, x], x], {n, 4}]HermiteH has no singularities or discontinuities:
FunctionSingularities[HermiteH[n, x], x]FunctionDiscontinuities[HermiteH[n, x], x]![TemplateBox[{n, x}, HermiteH]](Files/HermiteH.en/23.png "TemplateBox[{n, x}, HermiteH]"){kind=small}
Table[FunctionConvexity[HermiteH[n, x], x], {n, 5}]FunctionConvexity[HermiteH[n, x], x, Assumptions -> n < 0]
FunctionConvexity[HermiteH[n, x], x, Assumptions -> 0 < n < 1]TraditionalForm formatting:
HermiteH[n, x]//TraditionalFormDifferentiation (3)
First derivative with respect to z:
D[HermiteH[n, z], z]Higher derivatives with respect to z:
Table[D[HermiteH[n, z], {z, k}], {k, 1, 3}]//FullSimplifyPlot the higher derivatives with respect to z when n=3:
Plot[Evaluate[% /. { n -> 3}], {z, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]Formula for the 
derivative with respect to z:
D[HermiteH[n, z], {z, k}]// FullSimplifyIntegration (3)
Compute the indefinite integral using Integrate:
Integrate[HermiteH[n, x], x]FullSimplify[D[%, x]]Integrate[HermiteH[n, x], {x, 0, 5}]Integrate[x HermiteH[n, x], x]//FullSimplifyIntegrate[ x HermiteH[n, x^2], {x, 0, 3}]//FullSimplifySeries Expansions (5)
Find the Taylor expansion using Series:
Series[HermiteH[n, x], {x, 0, 3}]// FullSimplifyPlots of the first three approximations around 
:
terms = Normal@Table[Series[HermiteH[6, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{HermiteH[6, x], terms}, {x, -2, 2}]General term in the series expansion using SeriesCoefficient:
SeriesCoefficient[HermiteH[n, x], {x, 1, m}]Find the series expansion at Infinity:
Series[HermiteH[n, x], {x, Infinity, 2}]Find series expansion for an arbitrary symbolic direction 
:
Series[HermiteH[n, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0]// FullSimplifyTaylor expansion at a generic point:
Series[HermiteH[n, x], {x, x0, 2}]Function Identities and Simplifications (4)
HermiteH may reduce to simpler form:
HermiteH[2, x]Exponential generating function of HermiteH:
ExponentialGeneratingFunction[HermiteH[n, x], n, t]HermiteH[n, x] == (2x/2(n + 1))HermiteH[n + 1, x] - (1/2(n + 1))HermiteH[n + 2, x]//FullSimplifyExpress HermiteH in terms of LaguerreL:
Table[(-1)^⌊(k/2)⌋2^k⌊(k/2)⌋!x^(1 - (-1)^k/2) LaguerreL[⌊(k/2)⌋, (-1)^k - 1 / 2, x^2]//Expand, {k, 5}]Table[HermiteH[k, x], {k, 5}]Generalizations & Extensions (2)
Applications (5)
Solve the Hermite differential equation:
DSolve[{Derivative[2][w][z] - 2 z Derivative[1][w][z] + 2 n w[z] == 0}, w[z], z]Quantum harmonic oscillator wave functions:
ψ[n_, x_] := (HermiteH[n, x] E^-(x^2/2)/Sqrt[2^n n! Sqrt[π]])Plot[ψ[50, x], {x, -10, 10}]Subsuperscript[∫, -∞, ∞] Abs[ψ[10, x]]^2ⅆxCompute the expectation value of 
:
Subsuperscript[∫, -∞, ∞]x^2 Abs[ψ[10, x]]^2ⅆxMomentum and position wave functions for a harmonic oscillator have the same form:
{FourierTransform[ψ[2, x], x, ω], I^2ψ[2, x]}//SimplifyRSolve[{f[0] == 1, f[1] == c, f[n + 1] + 2n f[n - 1] == c f[n]}, f[n], n]Set up generalized Fourier series based on normalized Hermite functions:
ψ[n_, x_] := (HermiteH[n, x] E^-(x^2/2)/Sqrt[2^n n! Sqrt[π]])Find series coefficients for 
:
coeffs = Table[Subsuperscript[∫, -∞, ∞]Sin[x] ψ[n, x]ⅆx, {n, 0, 10}]Compare approximation and exact function:
Plot[{Sin[x], Table[ψ[n, x], {n, 0, 10}].coeffs}, {x, -2Pi, 2Pi}]Gibbs-like phenomenon for approximation of discontinuous function:
Plot[Evaluate[{UnitStep[x], Sum[ψ[n, x]Subsuperscript[∫, -∞, ∞]UnitStep[x] ψ[n, x]ⅆx, {n, 0, 50}]}], {x, -3, 3}]Find an integral for symbolic 
:
Integrate[x HermiteH[n, x], x]//FullSimplifyEvaluation for non-negative integer values of n requires Limit:
Limit[%, n -> 3]Compare with integration for explicit 
:
Integrate[x HermiteH[3, x], x]Properties & Relations (3)
Get the list of coefficients in a Hermite polynomial:
CoefficientList[HermiteH[10, x], x]HermiteH can be represented as a DifferentialRoot:
DifferentialRootReduce[HermiteH[n, x], x]The exponential generating function for HermiteH:
ExponentialGeneratingFunction[HermiteH[n, k], n, x]Possible Issues (2)
Cancellations in the polynomial form may lead to inaccurate numerical results:
HermiteH[100, x] /. x -> N[5, 16]Evaluate the function directly:
HermiteH[100, N[5, 16]]Plot the 100
Hermite polynomial:
Plot[HermiteH[100, x] Exp[-x ^ 2 / 2], {x, -20, 20}, PlotPoints -> 200]Machine-precision evaluation of explicit polynomials may be numerically unstable due to cancellations:
poly = HermiteH[100, x];Plot[poly Exp[-x ^ 2 / 2], {x, -20, 20}, PlotPoints -> 200]Neat Examples (4)
Distribution of the zeros of the first 20 Hermite polynomials:
ListPlot[Flatten[Table[Thread[{n, x /. Solve[HermiteH[n, x] == 0, x]}], {n, 20}], 1]]Interpolation between Hermite polynomials:
DensityPlot[Abs[(E^-(x^2/2) HermiteH[n, x]/Sqrt[n! 2^n])]^2, {n, 0, 5}, {x, -2, 2}]Comparison of quantum and classical probability distributions for a harmonic oscillator:
Block[{n = 20}, Plot[{(E^-x^2 HermiteH[n, x]^2/2^n n! Sqrt[π]), Piecewise[{{(1/Sqrt[2 n + 1 - x^2] π), x^2 < 2 n + 1}}]}, {x, -Sqrt[3n], Sqrt[3n]}, PlotPoints -> 200]]Generalized Lissajous figures:
Block[{n = 11, m = 13}, ParametricPlot[{ Exp[-x ^ 2 / 2]HermiteH[n, x] / Sqrt[2 ^ n n!], Exp[-x ^ 2 / 2]HermiteH[m, x] / Sqrt[2 ^ m m!]}, {x, -8, 8}]]Related Links
MathWorld
The Wolfram Functions Site
NKS|OnlineText
Wolfram Research (1988), HermiteH, Wolfram Language function, https://reference.wolfram.com/language/ref/HermiteH.html (updated 2022).
CMS
Wolfram Language. 1988. "HermiteH." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2022. https://reference.wolfram.com/language/ref/HermiteH.html.
APA
Wolfram Language. (1988). HermiteH. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/HermiteH.html