WOLFRAM

Wolfram Language & System Documentation Center

JacobiAmplitude[u,m]

gives the amplitude TemplateBox[{u, m}, JacobiAmplitude] for Jacobi elliptic functions.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation  
Series Expansions  
Function Representations  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

JacobiAmplitude

JacobiAmplitude[u,m]

gives the amplitude TemplateBox[{u, m}, JacobiAmplitude] for Jacobi elliptic functions.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • JacobiAmplitude[u,m] converts from the argument u for an elliptic function to the amplitude ϕ.
  • JacobiAmplitude is the inverse of the elliptic integral of the first kind. If u=TemplateBox[{phi, m}, EllipticF], then phi=TemplateBox[{u, m}, JacobiAmplitude].
  • JacobiAmplitude[u,m] has a branch cut discontinuity in the complex u plane running from 2 s TemplateBox[{m}, EllipticK]+ⅈ (4 t+1) TemplateBox[{{1, -, m}}, EllipticK] to 2 s TemplateBox[{m}, EllipticK]+ⅈ (4 t+3) TemplateBox[{{1, -, m}}, EllipticK] for every pair of integers and .
  • For certain special arguments, JacobiAmplitude automatically evaluates to exact values.
  • JacobiAmplitude can be evaluated to arbitrary numerical precision.
  • JacobiAmplitude automatically threads over lists.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: JacobiAmplitude[4., 2 / 3]

Plot over a subset of the reals:

Wolfram Language code: Plot[JacobiAmplitude[x, 2 / 3], {x, -4, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[JacobiAmplitude[z, 1 / 3], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansions about the origin:

Wolfram Language code: Series[JacobiAmplitude[z, m], {z, 0, 6}]
Wolfram Language code: Series[JacobiAmplitude[z, m], {m, 0, 1}]

Scope  (26)

Numerical Evaluation  (5)

Evaluate to high precision:

Wolfram Language code: N[JacobiAmplitude[Pi / 3, 1 / 5], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: JacobiAmplitude[Pi / 3, 0.200000000000000000000000000]

Evaluate for complex arguments:

Wolfram Language code: JacobiAmplitude[0.2 + 0.1 I, 0.2 I]

Evaluate JacobiAmplitude efficiently at high precision:

Wolfram Language code: JacobiAmplitude[Pi / 3, 0.2`500]//Timing
Wolfram Language code: JacobiAmplitude[Pi / 3, 0.2`10000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: JacobiAmplitude[ Around[2 / 3, 0.001], 1 / 3]

Compute the elementwise values of an array:

Wolfram Language code: JacobiAmplitude[{{1 / 2, -1}, {-5 / 3, 1 / 2}}, 1]

Or compute the matrix JacobiAmplitude function using MatrixFunction:

Wolfram Language code: MatrixFunction[JacobiAmplitude[#, 1]&, {{1 / 2, -1}, {-5 / 3, 1 / 2}}]//FullSimplify

Specific Values  (4)

Simple exact values are generated automatically:

Wolfram Language code: {JacobiAmplitude[x, 0], JacobiAmplitude[x, 1]}
Wolfram Language code: {JacobiAmplitude[0, m], JacobiAmplitude[EllipticK[m], m]}
Wolfram Language code: JacobiAmplitude[EllipticK[m] / 2 + I EllipticK[1 - m] / 2, m]

Values at infinity for some special cases:

Wolfram Language code: {JacobiAmplitude[Infinity, 0], JacobiAmplitude[Infinity, 1]}

Find a root of TemplateBox[{x, {-, 3}}, JacobiAmplitude]⩵1:

Wolfram Language code: xzero = x /. FindRoot[JacobiAmplitude[x, -3] == 1, {x, 2}]
Wolfram Language code: Plot[JacobiAmplitude[x, -3], {x, -3, 6}, WorkingPrecision -> 10, Epilog -> Style[Point[{xzero, JacobiAmplitude[xzero, -3]}], PointSize[Large], Red]]

Parity transformation is automatically applied:

Wolfram Language code: JacobiAmplitude[-u, m]

Visualization  (3)

Plot the JacobiAmplitude functions for various values of parameter :

Wolfram Language code: Plot[{JacobiAmplitude[x, -1], JacobiAmplitude[x, 1 / 2], JacobiAmplitude[x, 1], JacobiAmplitude[x, 2]}, {x, -4, 4}, PlotLegends -> "Expressions"]

Plot JacobiAmplitude as a function of its parameter :

Wolfram Language code: Plot[{JacobiAmplitude[1, m], JacobiAmplitude[2, m], JacobiAmplitude[3, m]}, {m, -10, 10}, PlotLegends -> "Expressions"]

Plot the real part of TemplateBox[{z, 2}, JacobiAmplitude]:

Wolfram Language code: ComplexContourPlot[Re[JacobiAmplitude[z, 2]], {z, -6 - 6I, 6 + 6I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{z, 2}, JacobiAmplitude]:

Wolfram Language code: ComplexContourPlot[Im[JacobiAmplitude[z, 2]], {z, -6 - 6I, 6 + 6I}, IconizedObject[«PlotOptions»]]

Function Properties  (5)

TemplateBox[{x, {2, /, 3}}, JacobiAmplitude] is an analytic function of x:

Wolfram Language code: FunctionAnalytic[JacobiAmplitude[x, 2 / 3], x]

It has no singularities or discontinuities:

Wolfram Language code: FunctionSingularities[JacobiAmplitude[x, 2 / 3], x]
Wolfram Language code: FunctionDiscontinuities[JacobiAmplitude[x, 2 / 3], x]

TemplateBox[{x, {2, /, 3}}, JacobiAmplitude] is injective:

Wolfram Language code: FunctionInjective[JacobiAmplitude[x, 2 / 3], x]
Wolfram Language code: Plot[{JacobiAmplitude[x, 2 / 3], 3}, {x, -5, 5}]

TemplateBox[{x, {2, /, 3}}, JacobiAmplitude] is surjective:

Wolfram Language code: FunctionSurjective[JacobiAmplitude[x, 2 / 3], x]
Wolfram Language code: Plot[{JacobiAmplitude[x, 2 / 3], -5}, {x, -10, 10}]

JacobiAmplitude is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[JacobiAmplitude[x, 2 / 3], x]

JacobiAmplitude is neither convex nor concave:

Wolfram Language code: FunctionConvexity[JacobiAmplitude[x, 1 / 3], x]

Differentiation  (3)

First derivative:

Wolfram Language code: D[JacobiAmplitude[x, m], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[JacobiAmplitude[x, m], {x, n}], {n, 1, 4}]//FullSimplify

Plot higher derivatives for :

Wolfram Language code: Plot[Evaluate[derivs /. m -> 2 / 3], {x, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Derivative with respect to :

Wolfram Language code: D[JacobiAmplitude[x, m], m]

Series Expansions  (3)

Taylor expansion for TemplateBox[{x, {2, /, 3}}, JacobiAmplitude]:

Wolfram Language code: Series[JacobiAmplitude[x, 2 / 3], {x, 0, 7}]

Plot the first three approximations for TemplateBox[{x, {2, /, 3}}, JacobiAmplitude] around :

Wolfram Language code: terms = Normal@Table[Series[JacobiAmplitude[x, 2 / 3], {x, 0, n}], {n, 1, 5, 2}]; Plot[{JacobiAmplitude[x, 2 / 3], terms}, {x, -2, 2}]

Taylor expansion for TemplateBox[{1, m}, JacobiAmplitude]:

Wolfram Language code: Series[JacobiAmplitude[1, m], {m, 0, 3}]

Plot the first three approximations for TemplateBox[{1, m}, JacobiAmplitude] around :

Wolfram Language code: terms = Normal@Table[Series[JacobiAmplitude[1, m], {m, 0, n}], {n, 1, 3}]; Plot[{JacobiAmplitude[1, m], terms}, {m, -9, 9}]

JacobiAmplitude can be applied to a power series:

Wolfram Language code: JacobiAmplitude[u, Log[1 + m] + O[m] ^ 3]
Wolfram Language code: JacobiAmplitude[u Cos[u] + O[u] ^ 10, m]//Simplify

Function Representations  (3)

JacobiAmplitude is the inverse of EllipticF:

Wolfram Language code: Solve[u == EllipticF[ϕ, m], ϕ]//Quiet

Integral representation:

Wolfram Language code: Integrate[JacobiDN[t, m], {t, 0, u}]

TraditionalForm formatting:

Wolfram Language code: JacobiAmplitude[u, m]//TraditionalForm

Applications  (4)

Solution of the pendulum equation in the overswing mode:

Wolfram Language code: ϕ[t_] = With[{k = 1 + 10^-3}, 2JacobiAmplitude[k t, k^-2]];

Check with the pendulum equation:

Wolfram Language code: ϕ''[t] + Sin[ϕ[t]]//FullSimplify

Plot the solution:

Wolfram Language code: Plot[ϕ[t], {t, 0, 36}]

Relativistic solution of the sine‐Gordon equation:

Wolfram Language code: u[t_, x_, {v_, k_}] = Piecewise[{{π - 2JacobiAmplitude[(x - v t/kSqrt[1 - v^2]), k^2], k ≤ 1}, {2 (π - JacobiAmplitude[((1 + k) (x - v t)/2 k Sqrt[1 - v^2]), (4 k/(1 + k)^2)] + JacobiAmplitude[((1 + k) (x - v t)/2 k Sqrt[1 - v^2]) - (1 + (1/k)) EllipticK[(1/k^2)], (4 k/(1 + k)^2)]), k > 1}}];

Verify the solution by substituting into the sine‐Gordon equation:

Wolfram Language code: Assuming[k < 1, Subscript[∂, {t, 2}]u[t, x, {v, k}] - Subscript[∂, {x, 2}]u[t, x, {v, k}] + Sin[u[t, x, {v, k}]] //FullSimplify]

Plot the solution for different values of and :

Wolfram Language code: Plot3D[u[t, x, {0.95, 0.99}], {x, -4, 4}, {t, 0, 2}]
Wolfram Language code: Plot3D[u[t, x, {0.8, 1.2}], {x, -4, 4}, {t, 0, 2}]

Form and plot generalized Fourier series:

Wolfram Language code: Function[m, Plot[Evaluate[Table[Sum[-(-1) ^ k Sin[k JacobiAmplitude[2 EllipticK[m] / Pi v, m]] / k, {k, o}], {o, 8}]], {v, -2Pi, 2Pi}, ImageSize -> Small]] /@ {0, 0.33, 0.66, 0.99}

Spherical triangle from an elliptic parameter and triple such that :

Wolfram Language code: SphericalTriangleAnglesAndSides[m_, {u1_, u2_, u3_}] /; inputQ[m, {u1, u2, u3}] := {JacobiAmplitude[2EllipticK[m]{u1, u2, u3}, m], ArcSin[Sqrt[m]JacobiSN[2EllipticK[m]{u1, u2, u3}, m]]}
Wolfram Language code: inputQ[m_, us_List] := 0 < m < 1 && Min[us] > 0 && Total[us] == 1

Angles at vertices , and and sides opposite to each corresponding vertex:

Wolfram Language code: {{∠A, ∠B, ∠C}, {a, b, c}} = SphericalTriangleAnglesAndSides[0.7, {0.2, 0.3, 0.5}]

Verify Cagnoli's equation, which relates the measurements of all the angles and sides of a spherical triangle:

Wolfram Language code: Sin[b]Sin[c] + Cos[b]Cos[c]Cos[∠A] == Sin[∠B]Sin[∠C] - Cos[∠B]Cos[∠C]Cos[a]

Compute the area of the triangle, also known as the spherical excess:

Wolfram Language code: Total[{∠A, ∠B, ∠C}] - Pi

Compute the excess using L'Huilier's theorem [MathWorld]:

Wolfram Language code: With[{𝓈 = Total[{a, b, c}] / 2}, 4ArcTan[Sqrt[Tan[(𝓈/2)]Tan[(𝓈 - a/2)]Tan[(𝓈 - b/2)]Tan[(𝓈 - c/2)]]]]

Compute corresponding points on 3D unit sphere:

Wolfram Language code: pC = {1, 0, 0}; normalBC = {0, 0, 1}; pB = RotationTransform[a, normalBC][pC]; normalAB = RotationTransform[-∠B, pB][normalBC]; pA = RotationTransform[-c, normalAB][pB];

Check consistency between points found and spherical sides:

Wolfram Language code: {{(pC.pB/Norm[pC] Norm[pB]), Cos[a]}, {(pA.pC/Norm[pA] Norm[pC]), Cos[b]}, {(pA.pB/Norm[pA] Norm[pB]), Cos[c]}}

Visualize the triangle:

Wolfram Language code: Show[ Graphics3D[{{Opacity[1 / 10, Gray], Sphere[{0, 0, 0}, 1]}, {Green, Sphere[{0, 0, 0}, 1 / 50], Arrowheads[Medium], Arrow[{{0, 0, 0}, pA}], Arrow[{{0, 0, 0}, pB}], Arrow[{{0, 0, 0}, pC}] }}], {ParametricPlot3D[RotationTransform[a t, {pB, pC}][pB]//Evaluate, {t, 0, 1}], ParametricPlot3D[RotationTransform[b t, {pA, pC}][pA]//Evaluate, {t, 0, 1}], ParametricPlot3D[RotationTransform[c t, {pA, pB}][pA]//Evaluate, {t, 0, 1}]}]

Properties & Relations  (5)

Compose with inverse functions:

Wolfram Language code: {EllipticF[JacobiAmplitude[z, m], m], JacobiAmplitude[EllipticF[z, m], m]}

Use PowerExpand to disregard the multivaluedness of the inverse function:

Wolfram Language code: PowerExpand[%]

Apply trigonometric functions to JacobiAmplitude:

Wolfram Language code: {Cos[JacobiAmplitude[z, m]], Sin[JacobiAmplitude[z, m]]}

Solve a transcendental equation:

Wolfram Language code: Solve[JacobiAmplitude[x, m]^2 + 3JacobiAmplitude[x, m] == a, x]//Quiet

Obtain from a differential equation:

Wolfram Language code: DSolve[Subscript[∂, z]w[z] - JacobiDN[z, m] == 0, w[z], z]

JacobiAmplitude has branch cuts from 2 s TemplateBox[{m}, EllipticK]+ⅈ (4 t+1) TemplateBox[{{1, -, m}}, EllipticK] to 2 s TemplateBox[{m}, EllipticK]+ⅈ (4 t+3) TemplateBox[{{1, -, m}}, EllipticK] for any integers and :

Wolfram Language code: Table[JacobiAmplitude[2s EllipticK[m] + I (4t + 1)EllipticK[1 - m], m], {s, -2, 2}, {t, -2, 2}]//Flatten//Union
Wolfram Language code: Table[JacobiAmplitude[2s EllipticK[m] + I (4t + 3)EllipticK[1 - m], m], {s, -2, 2}, {t, -2, 2}]//Flatten//Union

Visualize branch cuts for different moduli:

Wolfram Language code: ShowJacobiAmplitudeBranchCuts[m_ ? NumericQ] := Module[{K, Kp, rK, iK, rKp, iKp}, K = EllipticK[m];Kp = EllipticK[1 - m]; {rK, iK} = ReIm[K];{rKp, iKp} = ReIm[Kp]; Graphics[{Brown, Line[Flatten[Table[{{2s rK - (4t + 1)iKp, 2s iK + (4t + 1)rKp}, {2s rK - (4t + 3)iKp, 2s iK + (4t + 3)rKp}}, {s, -3, 3}, {t, -2, 2}], 1]]}, Frame -> True, AspectRatio -> 1, ImageSize -> Small, GridLines -> Automatic, GridLinesStyle -> LightGray] ]
Wolfram Language code: {ShowJacobiAmplitudeBranchCuts[-3], ShowJacobiAmplitudeBranchCuts[1 / 3], ShowJacobiAmplitudeBranchCuts[3], ShowJacobiAmplitudeBranchCuts[3 + I]}

Possible Issues  (1)

The branch cuts of TemplateBox[{u, m}, JacobiAmplitude] for cross the real axis at 2(2 s+1) TemplateBox[{{1, /, m}}, EllipticK]/sqrt(m) for integer :

Wolfram Language code: With[{m = 3}, branchPoints = {PointSize[Medium], Point[Table[{2(2s + 1)EllipticK[1 / m] / Sqrt[m], 0}, {s, -2, 2}]]}; Plot[JacobiAmplitude[u, m], {u, -6, 6}, Epilog -> branchPoints]]

For physical applications where a continuous version of the amplitude is desired for , use the following definition:

Wolfram Language code: am[u_, m_] := -(π/2) + JacobiAmplitude[(1/2) (1 + Sqrt[m]) u, (4 Sqrt[m]/(1 + Sqrt[m])^2)] - JacobiAmplitude[(1/2) (1 + Sqrt[m]) u - (1 + (1/Sqrt[m])) EllipticK[(1/m)], (4 Sqrt[m]/(1 + Sqrt[m])^2)];

The preceding function coincides with sin^(-1)(TemplateBox[{u, m}, JacobiSN]) for real and :

Wolfram Language code: With[{m = 3}, Plot[{ArcSin[JacobiSN[u, m]], am[u, m]}, {u, -6, 6}, IconizedObject[«Plot options»]]]
Wolfram Research (1988), JacobiAmplitude, Wolfram Language function, https://reference.wolfram.com/language/ref/JacobiAmplitude.html (updated 2020).

Text

Wolfram Research (1988), JacobiAmplitude, Wolfram Language function, https://reference.wolfram.com/language/ref/JacobiAmplitude.html (updated 2020).

CMS

Wolfram Language. 1988. "JacobiAmplitude." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/JacobiAmplitude.html.

APA

Wolfram Language. (1988). JacobiAmplitude. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/JacobiAmplitude.html

BibTeX

@misc{reference.wolfram_2026_jacobiamplitude, author="Wolfram Research", title="{JacobiAmplitude}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/JacobiAmplitude.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_jacobiamplitude, organization={Wolfram Research}, title={JacobiAmplitude}, year={2020}, url={https://reference.wolfram.com/language/ref/JacobiAmplitude.html}, note=[Accessed: 13-June-2026]}