Gudermannian
Gudermannian[z]
gives the Gudermannian function 
.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- The Gudermannian function is generically defined by
. - Gudermannian[z] has branch cut discontinuities in the complex
plane running from 
to 
for integers 
, where the function is continuous from the right. - Gudermannian can be evaluated to arbitrary numerical precision.
- Gudermannian automatically threads over lists. »
- Gudermannian can be used with Interval and CenteredInterval objects. »
Examples
open all close allBasic Examples (4)
Gudermannian[4.2]Plot over a subset of the reals:
Plot[Gudermannian[x], {x, -10, 10}]Plot over a subset of the complexes:
ComplexPlot3D[Gudermannian[z], {z, -2 - 2I π, 2 + 2I π}, PlotLegends -> Automatic]Series expansion at the origin:
Series[Gudermannian[x], {x, 0, 5}]Scope (38)
Numerical Evaluation (6)
Gudermannian[4.6]N[Gudermannian[4 / 3], 50]The precision of the output tracks the precision of the input:
Gudermannian[1.11111111111111111111111]N[Gudermannian[I Pi + 5]]Evaluate efficiently at high precision:
Gudermannian[29.`100]//TimingGudermannian[58.`10000];//TimingCompute the elementwise values of an array using automatic threading:
Gudermannian[{{.1, -.1}, {0, .2}}]Or compute the matrix Gudermannian function using MatrixFunction:
MatrixFunction[Gudermannian[#]&, {{.1, -.1}, {0, .2}}]Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:
Gudermannian[Interval[{1.4, 1.5}]]Gudermannian[CenteredInterval[1, 1 / 100]]Or compute average-case statistical intervals using Around:
Gudermannian[Around[3, 0.01]]Specific Values (3)
Gudermannian[0]Gudermannian[Infinity]Gudermannian[-Infinity]Find a value of 
for which the 
using Solve:
Solve[Gudermannian[x] == 0.8, x, Reals]//Quietxval = x /. First[%]Plot[Gudermannian[x], {x, -10, 10}, Epilog -> Style[Point[{xval, Gudermannian[xval]}], PointSize[Large], Red]]Visualization (3)
Plot the Gudermannian function:
Plot[Gudermannian[x], {x, -7, 7}]Plot the real part of Gudermannian[z]:
ComplexContourPlot[Re[Gudermannian[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]Plot the imaginary part of Gudermannian[z]:
ComplexContourPlot[Im[Gudermannian[z]], {z, -3 - 3 I, 3 + 3 I}, IconizedObject[«PlotOptions»]]
Table[PolarPlot[Gudermannian[k ϕ], {ϕ, -5π, 5π}, Frame -> True, FrameTicks -> {{{-1, 0, 1}, None}, {{-1, 0, 1}, None}}, PlotLabel -> "k=" <> ToString[k], PlotRange -> All], {k, 1, 4}]Function Properties (11)
Gudermannian is defined for all real values:
FunctionDomain[Gudermannian[x], x]Gudermannian is defined for all complex values except branch points:
FunctionDomain[Gudermannian[z], z, Complexes]FunctionRange[Gudermannian[x], x, y]
Gudermannian has the mirror property ![gd(TemplateBox[{z}, Conjugate])=TemplateBox[{{gd, (, z, )}}, Conjugate]](Files/Gudermannian.en/11.png "gd(TemplateBox[{z}, Conjugate])=TemplateBox[{{gd, (, z, )}}, Conjugate]"){kind=small}
:
FullSimplify[Gudermannian[Conjugate[z]] == Conjugate[Gudermannian[z]]]Gudermannian is an odd function:
Gudermannian[-z]
is an analytic function of 
for real 
:
FunctionAnalytic[Gudermannian[x], x]It is neither analytic nor meromorphic in the complex plane:
FunctionAnalytic[Gudermannian[x], x, Complexes]FunctionDiscontinuities[Gudermannian[x], x]Gudermannian is non-decreasing:
FunctionMonotonicity[Gudermannian[x], x]Gudermannian is injective:
FunctionInjective[Gudermannian[x], x]Plot[{Gudermannian[x], 1}, {x, -10, 10}]FunctionSurjective[Gudermannian[x], x]Plot[{Gudermannian[x], 2}, {x, -10, 10}]Gudermannian is neither non-negative nor non-positive:
FunctionSign[Gudermannian[x], x]Gudermannian has no singularities or discontinuities:
FunctionSingularities[Gudermannian[x], x]FunctionDiscontinuities[Gudermannian[x], x]Gudermannian is neither convex nor concave:
FunctionConvexity[Gudermannian[x], x]TraditionalForm formatting:
Gudermannian[x]//TraditionalFormDifferentiation (3)
The first derivative with respect to z:
D[Gudermannian[z], z]Higher derivatives with respect to z:
Table[D[Gudermannian[z], {z, k}], {k, 1, 3}]//FullSimplifyPlot the higher derivatives with respect to z:
Plot[%, {z, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]Formula for the 
derivative with respect to z:
D[Gudermannian[z], {z, k}]// FullSimplifyIntegration (4)
Compute the indefinite integral using Integrate:
Integrate[Gudermannian[x], x]FullSimplify[D[%, x] == Gudermannian[x], x∈Reals]Integrate[Gudermannian[x], {x, 0, 5}]The definite integral of Gudermannian over a period is 0:
Integrate[Gudermannian[x], {x, -4, 4}]Integrate[Exp[x] Gudermannian[x], x]//FullSimplifyIntegrate[ x Gudermannian[x^2], {x, 0, 3}]//FullSimplifySeries Expansions (4)
Find the Taylor expansion using Series:
Series[Gudermannian[x], {x, 0, 7}]Plots of the first three approximations around 
:
terms = Normal@Table[Series[Gudermannian[x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{Gudermannian[x], terms}, {x, 0, 10}, PlotRange -> {{0, 3}, {0, 3}}]The first-order Fourier series:
FourierSeries[Gudermannian[x], x, 1]The Taylor expansion at a generic point:
Series[Gudermannian[x], {x, x0, 2}]// FullSimplifyGudermannian can be applied to a power series:
Gudermannian[x + O[x] ^ 4]Function Representations (4)
Gudermannian can be represented in terms of Exp and ArcTan on the real line:
FullSimplify[Gudermannian[x] == 2 ArcTan[Exp[x]] - (π/2), x∈Reals]Representation as an integral on the real line:
Integrate[(1/Cosh[t]), {t, 0, x}, Assumptions -> x > 0]Since Gudermannian is odd, the same result is obtained for negative 
:
Integrate[(1/Cosh[t]), {t, 0, x}, Assumptions -> x < 0]Gudermannian can be represented in terms of Tanh and ArcTan away from the imaginary axis:
FullSimplify[Gudermannian[x] == 2ArcTan[Tanh[x / 2]], Re[x] > 0]FullSimplify[Gudermannian[x] == 2ArcTan[Tanh[x / 2]], Re[x] < 0]This representation is invalid on the half that is further from the origin of each branch cut strip:
Gudermannian[x] == 2ArcTan[Tanh[x / 2]] /. x -> 3.2IRepresent Gudermannian using Piecewise:
FunctionExpand[Gudermannian[x]]This representation is correct at all points, including branch cuts:
% == Gudermannian[x] /. x -> 3.2 IApplications (3)
Nonperiodic solution of a pendulum equation:
θ[t_] := 2 Gudermannian[t]y''[t] + Sin[y[t]] /. y -> θ//FullSimplifySolve a differential equation with the Gudermannian function as the inhomogeneous term:
DSolve[y'[x] + y[x] + Gudermannian[x] == 0, y[x], x]The cumulative distribution function (CDF) of the standard distribution of the hyperbolic secant is a scaled and shifted version of the Gudermannian function:
F[x] := (2 / π) ArcTan[Exp[π x / 2]]FullSimplify[2 / π ArcTan[Exp[π x / 2]] == 1 / 2 + (1 / π)Gudermannian[(π x/2)], x∈Reals]Properties & Relations (2)
Use FunctionExpand to expand Gudermannian in terms of elementary functions:
Gudermannian[x]//FunctionExpandSin[Gudermannian[x]]//FunctionExpandUse FullSimplify to prove identities involving the Gudermannian function:
FullSimplify[ArcTan[Sinh[x]], x∈Reals]Related Links
MathWorldSolve a differential equation with the Gudermannian function as the inhomogeneous term:
Text
Wolfram Research (2008), Gudermannian, Wolfram Language function, https://reference.wolfram.com/language/ref/Gudermannian.html (updated 2020).
CMS
Wolfram Language. 2008. "Gudermannian." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2020. https://reference.wolfram.com/language/ref/Gudermannian.html.
APA
Wolfram Language. (2008). Gudermannian. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Gudermannian.html