WOLFRAM

Wolfram Language & System Documentation Center

KochCurve[n]

gives the line segments representing the n^(th)-step Koch curve.

KochCurve[n,{θ1,θ2,…}]

takes a series of steps of unit length at successive relative angles θi.

KochCurve[n,{{r1,θ1},{r2,θ2},…}]

takes successive steps of lengths proportional to ri.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Curve Specification  
Curve Styling  
Options  
DataRange  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

KochCurve

KochCurve[n]

gives the line segments representing the n^(th)-step Koch curve.

KochCurve[n,{θ1,θ2,…}]

takes a series of steps of unit length at successive relative angles θi.

KochCurve[n,{{r1,θ1},{r2,θ2},…}]

takes successive steps of lengths proportional to ri.

Details and Options

  • KochCurve is also known as Koch snowflake.
  • KochCurve[n] is generated from the unit interval by repeatedly removing the middle third of the subsequent cells and replacing it with a triangle. »
  • KochCurve[n] is equivalent to KochCurve[n,{0,60 °,-120 °,60 °}].
  • KochCurve takes a DataRange option that can be used to specify the range the coordinates should be assumed to occupy.

Examples

open all close all

Basic Examples  (2)

A 2D Koch curve:

Wolfram Language code: Graphics[KochCurve[2]]

Lengths of the approximations to the Koch mesh:

Wolfram Language code: Table[ArcLength[KochCurve[n]], {n, 5}]//Rationalize

The formula:

Wolfram Language code: FindSequenceFunction[%, n]

The first four iterations of the Koch snowflake:

Wolfram Language code: Table[Graphics[GeometricTransformation[KochCurve[i], {RotationTransform[Pi, {1 / 2, 0}], RotationTransform[-Pi / 3, {1, 0}], RotationTransform[Pi / 3, {0, 0}]}]], {i, 4}]

Scope  (7)

Curve Specification  (3)

A 2D Koch curve:

Wolfram Language code: Graphics[KochCurve[2]]

The n^(th) approximation of the Koch curve:

Wolfram Language code: Table[Graphics[KochCurve[n]], {n, 1, 4}]

Specify the length of the relative angles:

Wolfram Language code: Graphics@KochCurve[2, {{1, 0}, {1, 90°}, {1, -90°}, {2, -90°}, {1, 90°}, {1, 90°}, {1, -90°}}]

Curve Styling  (4)

Koch curves with different thicknesses:

Wolfram Language code: Table[Graphics[{Thickness[i], KochCurve[3]}], {i, {Medium, Large}}]

Thickness in scaled size:

Wolfram Language code: Table[Graphics[{Thickness[i], KochCurve[2]}], {i, {.005, .05, .1}}]

Thickness in printer's points:

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], KochCurve[2]}], {i, {1, 5, 10}}]

Dashed curves:

Wolfram Language code: Table[Graphics[{Dashing[i], KochCurve[3]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, KochCurve[3]}], {d, {Dotted, Dashed, DotDashed}}]

Colored curves:

Wolfram Language code: Table[Graphics[{c, KochCurve[3]}], {c, {Red, Green, Blue, Yellow}}]

Options  (1)

DataRange  (1)

DataRange allows you to specify the range of mesh coordinates to generate:

Wolfram Language code: KochCurve[1]

Specify a different range:

Wolfram Language code: KochCurve[1, DataRange -> {{-1, 1}, {-1, 1}}]

Applications  (4)

KochCurve is generated by repeatedly removing the middle third of the cells and replacing it with a triangle:

Wolfram Language code: Column[Table[Graphics[KochCurve[n]], {n, 1, 3}]]

Generate Cesàro fractal:

Wolfram Language code: Graphics[KochCurve[3, {0, 85°, -85°, -85°, 85°}]]

Quadratic type 1 curve:

Wolfram Language code: Graphics[KochCurve[3, {0, 90°, -90°, -90°, 90°}]]

Quadratic type 2 curve:

Wolfram Language code: Graphics[KochCurve[3, {{1, 0}, {1, 90°}, {1, -90°}, {2, -90°}, {1, 90°}, {1, 90°}, {1, -90°}}]]

Properties & Relations  (3)

KochCurve consists of lines:

Wolfram Language code: KochCurve[1]

AnglePath can be used to generate the first iteration of the Koch curve:

Wolfram Language code: path = {{1, 0}, {1, 90°}, {1, -90°}, {1, -90°}, {1, 0°}, {1, 90°}, {1, 90°}, {1, -90°}};
Wolfram Language code: {Graphics[KochCurve[1, path]], Graphics[Line[AnglePath[path]]]}

DataRange -> range is equivalent to using RescalingTransform[{...},range]:

Wolfram Language code: Region[KochCurve[2, DataRange -> {{1, 2}, {1, 3}}], Frame -> True]

Use RescalingTransform:

Wolfram Language code: box = TransformedRegion[mr = KochCurve[2], RescalingTransform[RegionBounds[mr], {{1, 2}, {1, 3}}]];
Wolfram Language code: Region[box, Frame -> True]

Neat Examples  (1)

Koch snowflake in animation:

Wolfram Language code: Animate[Graphics[GeometricTransformation[KochCurve[i], {RotationTransform[Pi, {1 / 2, 0}], RotationTransform[-Pi / 3, {1, 0}], RotationTransform[Pi / 3, {0, 0}]}]], {i, 1, 6, 1}]
Wolfram Research (2017), KochCurve, Wolfram Language function, https://reference.wolfram.com/language/ref/KochCurve.html.

Text

Wolfram Research (2017), KochCurve, Wolfram Language function, https://reference.wolfram.com/language/ref/KochCurve.html.

CMS

Wolfram Language. 2017. "KochCurve." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/KochCurve.html.

APA

Wolfram Language. (2017). KochCurve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/KochCurve.html

BibTeX

@misc{reference.wolfram_2026_kochcurve, author="Wolfram Research", title="{KochCurve}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/KochCurve.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_kochcurve, organization={Wolfram Research}, title={KochCurve}, year={2017}, url={https://reference.wolfram.com/language/ref/KochCurve.html}, note=[Accessed: 12-June-2026]}