WOLFRAM

Wolfram Language & System Documentation Center

PeanoCurve[n]

gives the line segments representing the n^(th)-step Peano curve.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Curve Specification  
Curve Styling  
Options  
DataRange  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

PeanoCurve

PeanoCurve[n]

gives the line segments representing the n^(th)-step Peano curve.

Details and Options

  • PeanoCurve is also known as Peano space-filling curve.
  • PeanoCurve returns a Line primitive corresponding to a path that starts at {0,0}, then joins all integer points in the 3n-1 by 3n-1 square, and ends at {3n-1,3n-1}. »
  • PeanoCurve takes a DataRange option that can be used to specify the range the coordinates should be assumed to occupy.

Examples

open all close all

Basic Examples  (2)

A 2D Peano curve:

Wolfram Language code: Graphics[PeanoCurve[2]]

Lengths of the approximations to the Peano curve:

Wolfram Language code: Table[RegionMeasure[PeanoCurve[n]], {n, 4}]

The formula:

Wolfram Language code: FindSequenceFunction[%, n]

Visualize the Peano curve in 2D with splines:

Wolfram Language code: Graphics[{Thickness[Large], PeanoCurve[3] /. Line -> BSplineCurve}]

Scope  (6)

Curve Specification  (2)

A 2D Peano curve:

Wolfram Language code: Graphics[PeanoCurve[2]]

The n^(th) approximation of the Peano curve:

Wolfram Language code: Table[Graphics[PeanoCurve[n]], {n, 1, 4}]

Curve Styling  (4)

Peano curves with different thicknesses:

Wolfram Language code: Table[Graphics[{Thickness[i], PeanoCurve[3]}], {i, {Medium, Large}}]

Thickness in scaled size:

Wolfram Language code: Table[Graphics[{Thickness[i], PeanoCurve[2]}], {i, {.005, .05, .1}}]

Thickness in printer's points:

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], PeanoCurve[2]}], {i, {1, 5, 10}}]

Dashed curves:

Wolfram Language code: Table[Graphics[{Dashing[i], PeanoCurve[3]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, PeanoCurve[3]}], {d, {Dotted, Dashed, DotDashed}}]

Colored curves:

Wolfram Language code: Table[Graphics[{c, PeanoCurve[3]}], {c, {Red, Green, Blue, Yellow}}]

Options  (1)

DataRange  (1)

DataRange allows you to specify the range of mesh coordinates to generate:

Wolfram Language code: PeanoCurve[1]

Specify a different range:

Wolfram Language code: PeanoCurve[1, DataRange -> {{0, 1}, {0, 1}}]

Applications  (4)

PeanoCurve is constructed recursively by transforming segments into curves linked together by lines:

Wolfram Language code: scups[curve_] := With[{part = Partition[First[curve], UpTo[10], 9]}, Graphics[Apply[{{Thick, Line[#1]}, {Dashing[{0, 0.02}], Line[#2]}}&, Map[Partition[#, UpTo[9], 8]&, part], {1}]]]
Wolfram Language code: Row[{scups[PeanoCurve[1]], scups[PeanoCurve[2]]}, Spacer[40]]

Next iteration:

Wolfram Language code: color[curve_, n_ : 1] := With[{color = ColorData[97, "ColorList"], data = First[scups[curve]]}, Graphics[MapIndexed[{color[[First[#2]]], #1}&, Partition[data, n]]]]
Wolfram Language code: Row[{color[PeanoCurve[2]], color[PeanoCurve[3], 9]}, Spacer[40]]

Visualize the Peano curve in 2D:

Wolfram Language code: Graphics[PeanoCurve[2]]

With splines:

Wolfram Language code: % /. Line -> BSplineCurve

Build a simple polygon:

Wolfram Language code: Graphics[{Orange, Polygon[Join[First@PeanoCurve[4], {{81, 80}, {81, -1}, {0, -1}}]]}]

Apply a Peano curve texture to a surface:

Wolfram Language code: ParametricPlot3D[{1.16 ^ v Cos[v](1 + Cos[u]), -1.16 ^ v Sin[v](1 + Cos[u]), -2 1.16 ^ v(1 + Sin[u])}, {u, 0, 2Pi}, {v, -15, 6}, PlotStyle -> Directive[Specularity[White, 30], Texture[Graphics[PeanoCurve[4]]]], TextureCoordinateFunction -> ({#4, 2#5}&), Lighting -> "Neutral", Mesh -> None, PlotRange -> All, Boxed -> False, Axes -> False]

Properties & Relations  (3)

PeanoCurve consists of lines:

Wolfram Language code: PeanoCurve[1]

Find the perimeter of the 2D Peano curve:

Wolfram Language code: Table[Graphics[PeanoCurve[n]], {n, 3}]
Wolfram Language code: Table[RegionMeasure[PeanoCurve[n]], {n, 4}]
Wolfram Language code: FindSequenceFunction[%, n]

DataRange->range is equivalent to using RescalingTransform[{...},range]:

Wolfram Language code: Region[PeanoCurve[2, DataRange -> {{1, 2}, {1, 3}}], Frame -> True]

Use RescalingTransform:

Wolfram Language code: box = TransformedRegion[PeanoCurve[2], RescalingTransform[{{0, 3^2 - 1}, {0, 3^2 - 1}}, {{1, 2}, {1, 3}}]];
Wolfram Language code: Region[box, Frame -> True]

Possible Issues  (2)

By default, the coordinates of a Peano curve are not in the unit square:

Wolfram Language code: PeanoCurve[1]

Using DataRange to generate a Peano curve in the unit square:

Wolfram Language code: PeanoCurve[1, DataRange -> {{0, 1}, {0, 1}}]

PeanoCurve can be too large to generate:

Wolfram Language code: PeanoCurve[20]

Neat Examples  (1)

Traversal animations:

Wolfram Language code: With[{curve = PeanoCurve[4]}, Manipulate[Graphics[{curve, Red, Thick, Line[Take[First[curve], i]]}, ImageSize -> Medium], {i, 1, 6561, 1}]]
Wolfram Research (2017), PeanoCurve, Wolfram Language function, https://reference.wolfram.com/language/ref/PeanoCurve.html.

Text

Wolfram Research (2017), PeanoCurve, Wolfram Language function, https://reference.wolfram.com/language/ref/PeanoCurve.html.

CMS

Wolfram Language. 2017. "PeanoCurve." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PeanoCurve.html.

APA

Wolfram Language. (2017). PeanoCurve. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PeanoCurve.html

BibTeX

@misc{reference.wolfram_2026_peanocurve, author="Wolfram Research", title="{PeanoCurve}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/PeanoCurve.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_peanocurve, organization={Wolfram Research}, title={PeanoCurve}, year={2017}, url={https://reference.wolfram.com/language/ref/PeanoCurve.html}, note=[Accessed: 12-June-2026]}