WOLFRAM

Wolfram Language & System Documentation Center

LLMSynthesize[prompt]

generates text according to the input prompt.

LLMSynthesize[{prompt1,…}]

combines multiple prompti together.

LLMSynthesize[…,prop]

returns the specified property of the generated text.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
Authentication  
LLMEvaluator  
ProgressReporting  
Applications  
Possible Issues  
See Also
Related Guides
History
Cite this Page

LLMSynthesize

This functionality requires LLM access »

LLMSynthesize[prompt]

generates text according to the input prompt.

LLMSynthesize[{prompt1,…}]

combines multiple prompti together.

LLMSynthesize[…,prop]

returns the specified property of the generated text.

Details and Options

  • LLMSynthesize generates text according to the instruction in the prompt using a large language model (LLM). It can create content, complete sentences, extract information and more.
  • LLMSynthesize requires external service authentication, billing and internet connectivity.
  • Possible values for prompt can be:
  • "text"static text
    LLMPrompt["name"]a repository prompt
    StringTemplate[…]templated text
    TemplateObject[…]template for creating a prompt
    Image[…]an image
    {prompt1,…}a list of prompts
  • Template objects are automatically converted to strings via TemplateObject[…][].
  • A prompt created with TemplateObject can contain text and images.
  • Not every LLM supports image input.
  • Supported values for prop include:
  • "CompletionText"textual answer by the LLM
    "CompletionToolsText"textual answer including tool interactions
    "FormattedBoxes"completion formatted as Notebook Assistant boxes
    "FormattedText"formatted "Markdown" completion
    "FullText"string representation of "History"
    "History"complete history including prompt and completion
    "LLMEvaluator" runtime LLMEvaluator value
    "NotebookObject"formatted completion in a new notebook
    "Prompt"content submitted to the LLM
    "PromptText"string representation of "Prompt"
    "ToolRequests"list of LLMToolRequest objects
    "ToolResponses"list of LLMToolResponse objects
    "Usage"token usage
    {prop1,prop2,…}multiple properties
    Allall properties
  • "FullTextAnnotations", "ToolRequests" and "ToolResponses" give associations with elements in the format {start,end}val, where val refers to an object and start and end refer to the span of characters where val is specified in "FullText".
  • The following options can be specified:
  • AuthenticationAutomaticauthentication scheme
    LLMEvaluator$LLMEvaluatorLLM configuration to use
    ProgressReporting$ProgressReportinghow to report the progress of the computation
  • LLMEvaluator can be set to an LLMConfiguration object or an association with any of the following keys:
  • "MaxTokens"maximum amount of tokens to generate
    "Model"base model
    "PromptDelimiter"string to insert between prompts
    "Prompts"initial prompts or LLMPromptGenerator objects
    "StopTokens"tokens on which to stop generation
    "Temperature"sampling temperature
    "ToolMethod"method to use for tool calling
    "Tools"list of LLMTool objects to make available
    "TopProbabilities"sampling classes cutoff
    "TotalProbabilityCutoff"sampling probability cutoff (nucleus sampling)
  • Valid forms of "Model" include:
  • namenamed model
    {service,name}named model from service
    <|"Service"service,"Name"name,"Task"task|>fully specified model
  • Possible values for task include "Chat" and "Completion".
  • The generated text is sampled from a distribution. Details of the sampling can be specified using the following properties of the LLMEvaluator:
  • "Temperature"tAutomaticsample using a positive temperature t
    "TopProbabilities"kAutomaticsample only among the k highest-probability classes
    "TotalProbabilityCutoff"pAutomaticsample among the most probable choices with an accumulated probability of at least p (nucleus sampling)
  • The Automatic value of these parameters uses the default for the specified "Model".
  • Prompts specified in the "Prompts" property of the LLMEvaluator are prepended to the input prompt with role set as "System" if task is "Chat"
  • Multiple prompts are separated by the "PromptDelimiter" property of the LLMEvaluator.
  • Possible values for Authentication are:
  • Automaticchoose the authentication scheme automatically
    Environmentcheck for a key in the environment variables
    SystemCredentialcheck for a key in the system keychain
    ServiceObject[…]inherit the authentication from a service object
    "string"provide an explicit API key
  • With AuthenticationAutomatic, the function checks the variable ToUpperCase[service]<>"_API_KEY" in Environment and SystemCredential; otherwise, it uses ServiceConnect[service].
  • LLMSynthesize uses machine learning. Its methods, training sets and biases included therein may change and yield varied results in different versions of the Wolfram Language.

Examples

open all close all

Basic Examples  (3)

Synthesize text based on a simple description:

Wolfram Language code: LLMSynthesize["A short poem about a boar"]

Ask a question:

Wolfram Language code: LLMSynthesize["What's the plural of mouse?"]

Return the full context of the LLM:

Wolfram Language code: LLMSynthesize["What is the biggest mountain? ", "FullText"]

Scope  (4)

Synthesize text based on a prompt:

Wolfram Language code: LLMSynthesize["the product of 5 and 6 is "]

Use a prompt with both text and images:

Wolfram Language code: LLMSynthesize[{"what is this image?", [image], "Tell me just one word about it"}, LLMEvaluator -> <|"Model" -> {"OpenAI", "gpt-4o"}|>]

Specify a property to return:

Wolfram Language code: LLMSynthesize["the product of 5 and 6 is ", "FullText"]

Import the completion text as formatted boxes:

Wolfram Language code: LLMSynthesize["what is the tallest mountain?", "FormattedBoxes", LLMEvaluator -> "AgentOne"]

Options  (10)

Authentication  (4)

Provide an authentication key for the API:

Wolfram Language code: LLMSynthesize["the product of 5 and 6 is ", Authentication -> "<my-key>"]

Store the API key using the operating system's keychain:

Wolfram Language code: SystemCredential["OPENAI_API_KEY"] = "<my-key>"

Look for the key in the system keychain:

Wolfram Language code: LLMSynthesize["the product of 5 and 6 is ", Authentication -> SystemCredential]

Store the API key in an environment variable:

Wolfram Language code: SetEnvironment["OPENAI_API_KEY" -> "<my-key>"]

Look for the key in the system environment:

Wolfram Language code: LLMSynthesize["the product of 5 and 6 is ", Authentication -> Environment]

Authenticate via a service object:

Wolfram Language code: so = ServiceConnect["OpenAI"]
Wolfram Language code: LLMSynthesize["the product of 5 and 6 is ", Authentication -> so]

LLMEvaluator  (5)

Use the Wolfram computationally assisted generation (CAG):

Wolfram Language code: LLMSynthesize["the first 100 digits of Pi", LLMEvaluator -> "WolframAIAssistant"]

By default, the text generation continues until a termination token is generated:

Wolfram Language code: LLMSynthesize["answer with only the first 20 digits of Pi"]

Limit the amount of generated samples (tokens):

Wolfram Language code: LLMSynthesize["answer with only the first 20 digits of Pi", LLMEvaluator -> <|"Model" -> "gpt-4o-mini", "MaxTokens" -> 3|>]

Specify that the sampling should be performed at zero temperature:

Wolfram Language code: Table[LLMSynthesize["Answer with random a color", LLMEvaluator -> <|"Model" -> "gpt-4o-mini", "Temperature" -> 0|>], 3]

Specify a high temperature to get more variation in the generation:

Wolfram Language code: Table[LLMSynthesize["Answer with a random color", LLMEvaluator -> <|"Model" -> "gpt-4o-mini", "Temperature" -> 1.5|>], 3]

Specify the maximum cumulative probability before cutting off the distribution:

Wolfram Language code: LLMSynthesize["What's the plural of mouse?", LLMEvaluator -> <|"TotalProbabilityCutoff" -> .2, "Model" -> "gpt-4o-mini"|>]

Specify the service and the model to use for the generation:

Wolfram Language code: LLMSynthesize["What's the plural of mouse?", LLMEvaluator -> <|"Model" -> {"Anthropic", "claude-haiku-4-5-20251001"}|>]

ProgressReporting  (1)

Do not report any progress information:

Wolfram Language code: LLMSynthesize["What's the tallest mountain?", ProgressReporting -> False]

Applications  (2)

Define a function that builds a prompt programmatically:

Wolfram Language code: promptfunction[prompt_][args___] := LLMSynthesize[TemplateApply[prompt, {args}]]

Use it to create a natural language synonym generator:

Wolfram Language code: synonyms = promptfunction["write `2` synonyms of `1`"]

Apply it to a sequence of arguments:

Wolfram Language code: synonyms["city", 2]

Get personalized instruction about the Wolfram Language:

Wolfram Language code: LLMSynthesize["Plot a rational polynomial in the complex plane", "FormattedBoxes", LLMEvaluator -> "WolframAIAssistant"]

Click "Insert and evaluate" on the suggested expression:

Wolfram Language code: ComplexPlot[(z ^ 2 + 1) / (z ^ 2 - 1), {z, -2 - 2 I, 2 + 2 I}]

Possible Issues  (3)

The text generation is not guaranteed to follow instructions to the letter:

Wolfram Language code: pi = LLMSynthesize["Pi to the 57th decimal digit"]
Wolfram Language code: StringLength[pi]

Use exact arithmetic for precise computations:

Wolfram Language code: N[Pi, 57 + 1]

Some models may only support a subset of the possible generation settings:

Wolfram Language code: LLMSynthesize["Answer with random a color", LLMEvaluator -> <|"Temperature" -> 0|>]

Tokens used by the model, such as reasoning ones, may not appear in the output:

Wolfram Language code: LLMSynthesize["answer with only the first 20 digits of Pi", LLMEvaluator -> <|"MaxTokens" -> 3|>]
Wolfram Research (2023), LLMSynthesize, Wolfram Language function, https://reference.wolfram.com/language/ref/LLMSynthesize.html (updated 2026).

Text

Wolfram Research (2023), LLMSynthesize, Wolfram Language function, https://reference.wolfram.com/language/ref/LLMSynthesize.html (updated 2026).

CMS

Wolfram Language. 2023. "LLMSynthesize." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/LLMSynthesize.html.

APA

Wolfram Language. (2023). LLMSynthesize. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LLMSynthesize.html

BibTeX

@misc{reference.wolfram_2026_llmsynthesize, author="Wolfram Research", title="{LLMSynthesize}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/LLMSynthesize.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_llmsynthesize, organization={Wolfram Research}, title={LLMSynthesize}, year={2026}, url={https://reference.wolfram.com/language/ref/LLMSynthesize.html}, note=[Accessed: 12-June-2026]}