WOLFRAM

Wolfram Language & System Documentation Center

Markdown (.md)

Background & Context

    • Registered MIME types: text/markdown, text/x-markdown
    • A markup language allowing formatting text documents.
    • Plain text format.

Import & Export

Notebook Interface

  • Save As exports the active notebook as a Markdown file.

Import Elements

  • General Import elements:
  • "Elements" list of elements and options available in this file
    "Summary"summary of the file
    "Rules"list of rules for all available elements
  • Data representation elements:
  • "FormattedText"a sequence of formatted text for the whole document
    "Hyperlinks"a list of Hyperlink objects
    "Images"a list of Image objects
    "Notebook"a Notebook expression
    "NotebookObject"a NotebookObject expression
    "Plaintext"a string giving the textual content of the whole document
    "Tables"a list of Tabular objects
  • Metadata elements:
  • "Title"document title

Import Options

  • Import options include:
  • ByteOrderingAutomaticordering of bytes
    CharacterEncoding"UTF8ISOLatin1"raw character encoding used in the file
    "ImportImages"Truewhether to import images
  • By default, Import attempts to interpret the data as "UTF8"-encoded text. If any sequence of bytes stored in the file cannot be represented in "UTF8", Import uses "ISOLatin1" instead.

Export Options

  • Export options include:
  • "ExpressionFormattingFunction"Automatichow expressions stored in a Tabular object are converted to strings
    "SnippetRowCount"Infinitynumber of rows taken from the beginning and the end of table data during conversion to strings
    GeneratedAssetFormatAutomaticthe file format of asset files
    GeneratedAssetLocationAutomaticthe location of asset files
    "WolframLanguageTag""wl"tag used for Wolfram Language code blocks
  • GeneratedAssetFormat can be set to the following values:
  • Automaticautomatic setting
    <|"Image"fmt1,"AnimatedImage"fmt2|>use different formats for static and animated images
    "fmt"use format "fmt" for static images
  • The following image formats are supported as the value of GeneratedAssetFormat option: "AVIF", "BMP", "GIF", "JPEG", "JPEG2000", "PNG", "TIFF", "WebP".
  • GeneratedAssetLocation can be set to the following values:
  • Automaticautomatic setting
    "CloudObject"storing asset files in cloud objects
    "CloudObjectPublic"storing asset files in cloud objects with permission set to public
    "LocalObject"storing asset files in local objects
    "dir/"storing asset files under the directory dir
    Nonestoring asset files as data URLs
  • In GeneratedAssetLocation"dir/", if the directory "dir" already exists then the trailing path name separator is optional.
  • "ExpressionFormattingFunction" can be set to the following values:
  • Automaticdefault conversion to string
    formany form supported by Format such as InputForm
    farbitrary function that converts an expression to a string
  • "SnippetRowCount" can be set to the following values:
  • Infinityall rows are exported
    nonly the first n rows are exported
    {n}the first and the last n rows are exported
    {m,n}the first m and and the last n rows are exported

Examples

open all close all

Basic Examples  (3)

Import a Markdown file as plain text:

Wolfram Language code: Import["ExampleData/geese.md"]

Import summary of a Markdown file:

Wolfram Language code: Import["ExampleData/geese.md", "Summary"]

Export a mathematical expression to Markdown:

Wolfram Language code: Export["formula.md", Sqrt[a - b / 4]]

Import the rasterized expression:

Wolfram Language code: Import["formula.md", "FormattedText"]

Scope  (10)

Import  (2)

Import a Markdown file as formatted text:

Wolfram Language code: Import["ExampleData/geese.md", "FormattedText"]

Import a Markdown file as a NotebookObject:

Wolfram Language code: Import["ExampleData/geese.md", "NotebookObject"]

Export  (8)

Export a styled text:

Wolfram Language code: ExportString[Style["Hello", FontWeight -> Bold], "Markdown"]
Wolfram Language code: ExportString[Row[{Style["Hello", Bold], " ", Style["World!", Italic]}], "Markdown"]

Export a Hyperlink expression:

Wolfram Language code: ExportString[Hyperlink["hello", "www.wolfram.com"], "Markdown"]

Export an Image object:

Wolfram Language code: ExportString[RandomImage[], "Markdown"]

Export a Video object:

Wolfram Language code: ExportString[Video["ExampleData/fish.mp4"], "Markdown"]

Export a Tabular object:

Wolfram Language code: tabular = Import["ExampleData/USstates.arrow", {"Tabular", 1 ;; 3}]
Wolfram Language code: markdown = ExportString[tabular, "Markdown"]

Import it back:

Wolfram Language code: ImportString[markdown, {"Markdown", "FormattedText"}]

Export a QuantityArray:

Wolfram Language code: qa = QuantityArray[{{1.4, 2.3}, {2.8, 2.7}, {4.2, 3.5}}, {"Seconds", "Meters"}]
Wolfram Language code: markdown = ExportString[qa, "Markdown"]

Import it back as a Tabular object:

Wolfram Language code: ImportString[markdown, {"Markdown", "FormattedText"}]

Export a Notebook expression including item cells:

Wolfram Language code: nb = Notebook[{Cell["This is my todo list.", "Title"], Cell["Today", "Item"], Cell["item 1", "SubitemNumbered"], Cell["item 2", "SubitemNumbered"]}]
Wolfram Language code: ExportString[nb, "Markdown"]
Wolfram Language code: ImportString[%, {"Markdown", "FormattedText"}]

Import a notebook file as a NotebookObject:

Wolfram Language code: nb = Import["ExampleData/document.nb", "NotebookObject"]

Export to Markdown while the notebook is open:

Wolfram Language code: ExportString[nb, "Markdown"]//IconizedObject[«Pane»]

Import Elements  (9)

Available Elements  (1)

List of available elements:

Wolfram Language code: Import["ExampleData/geese.md", "Elements"]

"FormattedText"  (1)

Import the file as formatted text:

Wolfram Language code: Import["ExampleData/geese.md", "FormattedText"]

"Hyperlinks"  (1)

Import hyperlinks:

Wolfram Language code: Import["ExampleData/geese.md", "Hyperlinks"]

"Images"  (1)

Import images:

Wolfram Language code: Import["ExampleData/geese.md", "Images"]

"Notebook"  (1)

Import the file as a Wolfram Notebook expression:

Wolfram Language code: Import["ExampleData/geese.md", "Notebook"]//Short[#, 5]&

"NotebookObject"  (1)

Import the file as a Wolfram Notebook:

Wolfram Language code: Import["ExampleData/geese.md", "NotebookObject"]

"Plaintext"  (1)

Import the file as plain text:

Wolfram Language code: Import["ExampleData/geese.md", "Plaintext"]

"Tables"  (1)

Import images:

Wolfram Language code: Import["ExampleData/geese.md", "Tables"]

"Title"  (1)

Import document title:

Wolfram Language code: Import["ExampleData/geese.md", "Title"]

Import Options  (3)

CharacterEncoding  (1)

The character encoding can be set to any value from $CharacterEncodings:

Wolfram Language code: input = "é";
Wolfram Language code: ImportString[input, "Markdown", CharacterEncoding -> "UTF8"]
Wolfram Language code: ImportString[input, "Markdown", CharacterEncoding -> "ISOLatin1"]

"ImportImages"  (2)

By default, images are imported:

Wolfram Language code: Import["ExampleData/geese.md", "FormattedText"]

With "ImportImages"False, images are not imported:

Wolfram Language code: Import["ExampleData/geese.md", "FormattedText", "ImportImages" -> False]

Export Options  (10)

"ExpressionFormattingFunction"  (1)

By default, Export uses different conversion to string depending on column types:

Wolfram Language code: tabular = Import["ExampleData/USstates.arrow", {"Tabular", 1 ;; 3}]
Wolfram Language code: ColumnTypes[tabular]
Wolfram Language code: ExportString[tabular, "Markdown"]

Use "ExpressionFormattingFunction"->InputForm to get string versions of expressions suitable for input to the Wolfram Language:

Wolfram Language code: ExportString[tabular, "Markdown", "ExpressionFormattingFunction" -> InputForm]//Short[#, 5]&

Use an arbitrary function that converts expressions to strings:

Wolfram Language code: ExportString[tabular, "Markdown", "ExpressionFormattingFunction" -> Function[x, ToString[x, CForm]]]//Short[#, 5]&

GeneratedAssetFormat  (2)

By default, static images are exported as "PNG":

Wolfram Language code: ExportString[RandomImage[], "Markdown"]

Specify different format for static images:

Wolfram Language code: ExportString[RandomImage[], "Markdown", GeneratedAssetFormat -> "JPEG"]

By default, animated images, Video and Manipulate objects are exported as "WebP":

Wolfram Language code: ExportString[AnimatedImage["ExampleData/wave.gif"], "Markdown"]

Specify different format for animated images:

Wolfram Language code: ExportString[AnimatedImage["ExampleData/wave.gif"], "Markdown", GeneratedAssetFormat -> <|"AnimatedImage" -> "PNG"|>]

GeneratedAssetLocation  (5)

Assets are automatically generated in the "img" folder in the same directory as the .md file:

Wolfram Language code: Export[FileNameJoin[{$TemporaryDirectory, "file.md"}], RandomImage[]]
Wolfram Language code: FileNames["*.*", FileNameJoin[{$TemporaryDirectory, "img"}]]

Store each asset as a LocalObject:

Wolfram Language code: ExportString[RandomImage[], "Markdown", GeneratedAssetLocation -> "LocalObject"]

Store each asset as a CloudObject with permission set to private:

Wolfram Language code: ExportString[RandomImage[], "Markdown", GeneratedAssetLocation -> "CloudObject"]

Store each asset as a CloudObject with permission set to public:

Wolfram Language code: ExportString[RandomImage[], "Markdown", GeneratedAssetLocation -> "CloudObjectPublic"]

Store each asset as a data URL:

Wolfram Language code: ExportString[RandomImage[], "Markdown", GeneratedAssetLocation -> None]//Short

"SnippetRowCount"  (1)

By default, all rows of table data are exported:

Wolfram Language code: tabular = Import["ExampleData/USstates.arrow"]
Wolfram Language code: tabular["RowCount"]
Wolfram Language code: StringCount[ExportString[tabular, "Markdown"], " "]

Use the "SnippetRowCount" option to export the first 2 rows and the last 3 rows:

Wolfram Language code: ExportString[tabular, "Markdown", "SnippetRowCount" -> {2, 3}]

"WolframLanguageTag"  (1)

By default, "wl" is used as the Wolfram Language tag:

Wolfram Language code: ExportString[Notebook[{Cell["2+2", "Input"]}], "Markdown"]

Use the previously supported tag on most Markdown viewers:

Wolfram Language code: ExportString[Notebook[{Cell["2+2", "Input"]}], "Markdown", "WolframLanguageTag" -> "mathematica"]