WOLFRAM

Wolfram Language & System Documentation Center

LaplacianFilter[data,r]

convolves data with a radius-r Laplacian kernel.

LaplacianFilter[data,{r1,r2,…}]

uses radius ri at level i in data.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Data  
Parameters  
Options  
WorkingPrecision  
Padding  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

LaplacianFilter

LaplacianFilter[data,r]

convolves data with a radius-r Laplacian kernel.

LaplacianFilter[data,{r1,r2,…}]

uses radius ri at level i in data.

Details and Options

  • LaplacianFilter is commonly used in image processing to highlight regions of rapid-intensity change by approximating the second spatial derivatives of an image.
  • The data can be any of the following:
  • listarbitrary-rank numerical array
    tseriestemporal data such as TimeSeries, TemporalData, …
    imagearbitrary Image or Image3D object
    audioan Audio object
    videoa Video object
  • For multichannel images and audio signals, LaplacianFilter operates separately on each channel.
  • LaplacianFilter[data,…] by default returns a result of the same dimensions as data.
  • The following options can be given:
  • Padding "Fixed"padding method
    WorkingPrecision Automaticthe precision to use
  • With setting Padding->None, LaplacianFilter[data,…] normally returns a result smaller than data.

Examples

open all close all

Basic Examples  (2)

Laplacian filter of a list:

Wolfram Language code: list = {0, 0, 0, 0, 0, 1, 1, 1, 1, 1, 0, 0, 0, 0, 0}; res = LaplacianFilter[list, 1]//Chop
Wolfram Language code: ListLinePlot[{list, res}, ...]

Laplacian filtering of a color image:

Wolfram Language code: LaplacianFilter[[image], 1]

Scope  (9)

Data  (7)

Laplacian filter of a 2D Array:

Wolfram Language code: LaplacianFilter[BoxMatrix[1, 7], 1]//MatrixForm

Filter a TimeSeries object:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{0., -0.27267267057145633, -0.6672983789995302, -0.5338541947930846, -0.6117404489279314, -0.6755527076595494, -0.02125421294486496, -0.10792797291843935, -0.6138271235477938, -0.3248568606554575, -0.08843449054 ... 2053424, -0.49980440691873723, -0.5388679788215971, -0.4101602764645551}}, {{0, 1., 0.01}}, 1, {"Continuous", 1}, {"Continuous", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}}}, False, 10.1]; filtered = LaplacianFilter[ts, 15]; ListLinePlot[{ts, filtered}, PlotLegends -> {"original data", "filtered"}]

Filter an Audio signal:

Wolfram Language code: a = AudioGenerator[{"Triangle", 10}]; b = AudioNormalize[LaplacianFilter[a, 10]]; AudioPlot[{a, b}]

Filter a grayscale image:

Wolfram Language code: LaplacianFilter[[image], 2]//ImageAdjust

Filter a color image:

Wolfram Language code: LaplacianFilter[[image], 2]// ImageAdjust

Filter video frames:

Wolfram Language code: LaplacianFilter[Video["ExampleData/fish.mp4"], 3]

Filter a 3D image:

Wolfram Language code: LaplacianFilter[[image], 1]

Parameters  (2)

Apply the Laplacian filter in the horizontal direction only:

Wolfram Language code: ImageAdjust[LaplacianFilter[[image], {0, 1}]]

Use different radii in the horizontal direction:

Wolfram Language code: ImageAdjust[LaplacianFilter[[image], {0, #}]]& /@ {1, 3, 9}

Filter a 3D image in the vertical plane only:

Wolfram Language code: i = [image]; LaplacianFilter[i, {1, 0, 0}]

Filtering of the horizontal planes only:

Wolfram Language code: LaplacianFilter[i, {0, 1, 1}]

Options  (5)

WorkingPrecision  (3)

With integer arrays, the machine precision is used by default:

Wolfram Language code: LaplacianFilter[{0, 0, 1, 1, 1, 0, 0}, 1]

Use infinite precision:

Wolfram Language code: LaplacianFilter[{0, 0, 1, 1, 1, 0, 0}, 1, WorkingPrecision -> Infinity]

With real arrays, the precision of the input is used by default:

Wolfram Language code: LaplacianFilter[{1.0000000000000000000, 2.0000000000000000000, 3.0000000000000000000, 4.0000000000000000000}, 1]

Specify the precision to use:

Wolfram Language code: LaplacianFilter[{1.0000000000000000000, 2.0000000000000000000, 3.0000000000000000000, 4.0000000000000000000}, 1, WorkingPrecision -> MachinePrecision]

WorkingPrecision is ignored when filtering images:

Wolfram Language code: LaplacianFilter[[image], 1, WorkingPrecision -> Infinity]

An image of a real type is always returned:

Wolfram Language code: ImageType[%]

Padding  (2)

Laplacian filtering using different padding schemes:

Wolfram Language code: v = {1, 2, 3, 2, 1, 0, 0, 0}; pad = {"Fixed", "Periodic", "Reflected"}; ListLinePlot[LaplacianFilter[v, 5, Padding -> #]& /@ pad, PlotLegends -> pad, PlotRange -> All]

Padding->None returns an image smaller than the input image:

Wolfram Language code: LaplacianFilter[[image], {20, 20}, Padding -> None]

Applications  (3)

Find edges in an image:

Wolfram Language code: LaplacianFilter[[image], 2]

Subtract the Laplacian filter from the original image to emphasize details:

Wolfram Language code: i = [image]; ImageSubtract[i, LaplacianFilter[i, 10]]

Get borders from a colored map:

Wolfram Language code: ColorConvert[LaplacianFilter[[image], 1], "Grayscale"]

Properties & Relations  (3)

LaplacianFilter is a linear filter:

Wolfram Language code: list1 = {1, 1, 1, 1, 1, 0, 0, 3, 2, 1, 0, 0, 0, 0, 0}; list2 = {2, 2, 2, 2, 1, 5, 4, 6, 2, 2, 1, 1, 1, 1, 1}; LaplacianFilter[list1 + list2, 1] == LaplacianFilter[list1, 1] + LaplacianFilter[list2, 1]

Impulse response of LaplacianFilter of radius 2:

Wolfram Language code: (ker = LaplacianFilter[ArrayPad[{{1}}, 3], 2])//MatrixForm

Perform Laplacian filtering using ImageConvolve:

Wolfram Language code: i = RandomImage[1, 50]; LaplacianFilter[i, 2] == ImageConvolve[i, ker]

Laplacian filtering of a binary image gives a real-valued image:

Wolfram Language code: d = Image[DiskMatrix[23, 81], "Bit"]
Wolfram Language code: LaplacianFilter[d, 1]//ImageAdjust
Wolfram Language code: ImageType[%]

Neat Examples  (1)

Create a random texture from uniform noise:

Wolfram Language code: LaplacianFilter[GaussianFilter[[image], 15], 50]//ImageAdjust
Wolfram Research (2008), LaplacianFilter, Wolfram Language function, https://reference.wolfram.com/language/ref/LaplacianFilter.html (updated 2025).

Text

Wolfram Research (2008), LaplacianFilter, Wolfram Language function, https://reference.wolfram.com/language/ref/LaplacianFilter.html (updated 2025).

CMS

Wolfram Language. 2008. "LaplacianFilter." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/LaplacianFilter.html.

APA

Wolfram Language. (2008). LaplacianFilter. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/LaplacianFilter.html

BibTeX

@misc{reference.wolfram_2026_laplacianfilter, author="Wolfram Research", title="{LaplacianFilter}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/LaplacianFilter.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_laplacianfilter, organization={Wolfram Research}, title={LaplacianFilter}, year={2025}, url={https://reference.wolfram.com/language/ref/LaplacianFilter.html}, note=[Accessed: 12-June-2026]}