WOLFRAM

Wolfram Language & System Documentation Center

MardiaCombinedTest[data]

tests whether data follows a MultinormalDistribution using the Mardia combined test.

MardiaCombinedTest[data,"property"]

returns the value of "property".

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Testing  
Reporting  
Options  
Method  
SignificanceLevel  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

MardiaCombinedTest

MardiaCombinedTest[data]

tests whether data follows a MultinormalDistribution using the Mardia combined test.

MardiaCombinedTest[data,"property"]

returns the value of "property".

Details and Options

  • MardiaCombinedTest performs a goodness-of-fit test with null hypothesis that data was drawn from a MultinormalDistribution and alternative hypothesis that it was not.
  • By default, a probability value or -value is returned.
  • A small -value suggests that it is unlikely that the data is normally distributed.
  • The data can be univariate {x1,x2,…} or multivariate {{x1,y1,…},{x2,y2,…},…}.
  • The Mardia combined test effectively pools the results from MardiaSkewnessTest and MardiaKurtosisTest.
  • MardiaCombinedTest[data,dist,"HypothesisTestData"] returns a HypothesisTestData object htd that can be used to extract additional test results and properties using the form htd["property"].
  • MardiaCombinedTest[data,dist,"property"] can be used to directly give the value of "property".
  • Properties related to the reporting of test results include:
  • "DegreesOfFreedom"the degrees of freedom used in a test
    "PValue"-value
    "PValueTable"formatted version of "PValue"
    "ShortTestConclusion"a short description of the conclusion of a test
    "TestConclusion"a description of the conclusion of a test
    "TestData"test statistic and -value
    "TestDataTable"formatted version of "TestData"
    "TestStatistic"test statistic
    "TestStatisticTable"formatted "TestStatistic"
  • The following properties are independent of which test is being performed.
  • Properties related to the data distribution include:
  • "FittedDistribution"fitted distribution of data
    "FittedDistributionParameters"distribution parameters of data
  • The following options can be given:
  • Method Automaticthe method to use for computing -values
    SignificanceLevel 0.05cutoff for diagnostics and reporting
  • For a test for goodness of fit, a cutoff is chosen such that is rejected only if . The value of used for the "TestConclusion" and "ShortTestConclusion" properties is controlled by the SignificanceLevel option. By default, is set to 0.05.
  • With the setting Method->"MonteCarlo", datasets of the same length as the input are generated under using the fitted distribution. The EmpiricalDistribution from MardiaCombinedTest[si,"TestStatistic"] is then used to estimate the -value.

Examples

open all close all

Basic Examples  (3)

Perform a test for multivariate normality:

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];
Wolfram Language code: htd = MardiaCombinedTest[data, "HypothesisTestData"]
Wolfram Language code: htd[Automatic]

Extract the test statistic from the Mardia combined test:

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];
Wolfram Language code: MardiaCombinedTest[data, "TestStatistic"]

Obtain a formatted test table:

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0, 0}, IdentityMatrix[3]], 1000];
Wolfram Language code: MardiaCombinedTest[data, "TestDataTable"]

Scope  (5)

Testing  (2)

Perform a Mardia test for multivariate normality:

Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000]; data2 = RandomVariate[MultivariateTDistribution[IdentityMatrix[2], 3], 1000];

The -value for the normal data is large compared to the -value for the non-normal data:

Wolfram Language code: MardiaCombinedTest[data1]
Wolfram Language code: MardiaCombinedTest[data2]

Create a HypothesisTestData object for repeated property extraction:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 10^5];
Wolfram Language code: ℋ = MardiaCombinedTest[data, "HypothesisTestData"]

The properties available for extraction:

Wolfram Language code: ℋ["Properties"]

Reporting  (3)

Tabulate the results of the Mardia combined test:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 10^3];
Wolfram Language code: ℋ = MardiaCombinedTest[data, "HypothesisTestData"];

The full test table:

Wolfram Language code: ℋ["TestDataTable"]

A -value table:

Wolfram Language code: ℋ["PValueTable"]

The test statistic:

Wolfram Language code: ℋ["TestStatisticTable"]

Retrieve the entries from a Mardia combined test table for custom reporting:

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 10^4]; data2 = RandomVariate[BinormalDistribution[.5], 10^3];
Wolfram Language code: ℋ1 = MardiaCombinedTest[data1, "TestData"]
Wolfram Language code: ℋ2 = MardiaCombinedTest[data2, "TestData"]
Wolfram Language code: BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"SubscriptBox[M, S]", "p‐value"}]

Report test conclusions using "ShortTestConclusion" and "TestConclusion":

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[StudentTDistribution[4], {100, 2}]];
Wolfram Language code: ℋ = MardiaCombinedTest[data, "HypothesisTestData"];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

The conclusion may differ at a different significance level:

Wolfram Language code: ℋ = MardiaCombinedTest[data, "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ["ShortTestConclusion"]
Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

Options  (4)

Method  (3)

Use Monte Carlo-based methods or a computation formula:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: MardiaCombinedTest[data, Method -> "MonteCarlo"]
Wolfram Language code: MardiaCombinedTest[data, Method -> Automatic]

Set the number of samples to use for Monte Carlo-based methods:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 500];
Wolfram Language code: pts = Table[{i, MardiaCombinedTest[data, Method -> {"MonteCarlo", "MonteCarloSamples" -> i}]}, {i, Range[5, 1000, 150]}];

The Monte Carlo estimate converges to the true -value with increasing samples:

Wolfram Language code: pval = MardiaCombinedTest[data];
Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {0, 1}, FrameLabel -> {"Samples", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {1000, pval}}]}]]

Set the random seed used in Monte Carlo-based methods:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 500];
Wolfram Language code: pts = Table[{i, MardiaCombinedTest[data, Method -> {"MonteCarlo", "MonteCarloSamples" -> 100, "RandomSeed" -> i}]}, {i, Range[1, 10]}];

The seed affects the state of the generator and has some effect on the resulting -value:

Wolfram Language code: pval = MardiaCombinedTest[data];
Wolfram Language code: Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

SignificanceLevel  (1)

Set the significance level used for "TestConclusion" and "ShortTestConclusion":

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[StudentTDistribution[5], {100, 2}]];
Wolfram Language code: MardiaCombinedTest[data, "ShortTestConclusion", SignificanceLevel -> .1]
Wolfram Language code: MardiaCombinedTest[data, "ShortTestConclusion", SignificanceLevel -> .25]

By default, 0.05 is used:

Wolfram Language code: MardiaCombinedTest[data, "TestConclusion"]//TraditionalForm

Applications  (2)

A power curve for the Mardia combined test:

Wolfram Language code: data = Table[RandomVariate[MultivariateTDistribution[IdentityMatrix[2], 3], {500, i}], {i, n = {10, 15, 20, 25, 30}}];
Wolfram Language code: ℋ = Table[MardiaCombinedTest[data[[i, j]]], {i, Length[data]}, {j, Length[data[[i]]]}];
Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

Visualize the approximate power curve:

Wolfram Language code: Plot[pC[x], {x, 10, 30}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {7, 0}]

Estimate the power of the Mardia combined test when the underlying distribution is a MultivariateTDistribution, the test size is 0.05, and the sample size is 12:

Wolfram Language code: pC[12.]

Five morphological measures were recorded for two separate varieties of a crab species. A researcher hopes to simultaneously compare all the measures across the species using multivariate analysis of variance, which requires that the data is multivariate normal:

Wolfram Language code: data = ExampleData[{"Statistics", "CrabMeasures"}];
Wolfram Language code: ExampleData[{"Statistics", "CrabMeasures"}, "ColumnDescriptions"]
Wolfram Language code: var = data[[All, 1]];

Use MardiaCombinedTest to determine if both sets of data are multivariate normal:

Wolfram Language code: MardiaCombinedTest[d1 = Pick[data[[All, -5 ;; -1]], var, "B"], "TestDataTable"]
Wolfram Language code: MardiaCombinedTest[d2 = Pick[data[[All, -5 ;; -1]], var, "O"], "TestDataTable"]

Univariate density estimates of the five measures for each species:

Wolfram Language code: measures = {"frontal lobe size", "rear width", "carapace length", "carapace width", "body depth"};
Wolfram Language code: {SmoothHistogram[Transpose@d1, PlotRange -> (r = {0, .16}), ImageSize -> (s = 180), PlotLabel -> "Blue crab"], SmoothHistogram[Transpose@d2, PlotRange -> r, ImageSize -> s, PlotLabel -> "Orange crab", PlotLegends -> measures]}

The deviation from normality appears to be in the skewness:

Wolfram Language code: MardiaKurtosisTest[#, "ShortTestConclusion"]& /@ {d1, d2}
Wolfram Language code: MardiaSkewnessTest[#, "ShortTestConclusion"]& /@ {d1, d2}

Properties & Relations  (3)

The multivariate test statistic:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], 100];
Wolfram Language code: MCombined[data_] := With[{p = Dimensions[data][[2]], n = Length[data]}, ((1 + n) (3 + n) (1 + p)/n (-5 + n + p + n p))MardiaSkewnessTest[data, "TestStatistic"] + MardiaKurtosisTest[data, "TestStatistic"] ^ 2]
Wolfram Language code: MCombined[data]
Wolfram Language code: MardiaCombinedTest[data, "TestStatistic"]

Under , the test statistic asymptotically follows a ChiSquareDistribution:

Wolfram Language code: data = RandomVariate[BinormalDistribution[.5], {1000, 250}];
Wolfram Language code: t = MCombined /@ data;
Wolfram Language code: With[{dim = 2, n = 100}, DistributionFitTest[t, ChiSquareDistribution[(1/6) dim (dim + 1) (dim + 2) + 1]]]

For univariate data, the test is equivalent to the JarqueBeraALMTest:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: JarqueBeraALMTest[data, "TestDataTable"]
Wolfram Language code: MardiaCombinedTest[data, "TestDataTable"]

The Mardia combined test works with the values only when the input is a TimeSeries:

Wolfram Language code: ts = TemporalData[TimeSeries, {{{{-0.49926617600557877, -0.9693358407186422, 0.5958383000077166}, {-1.33047395864177, -0.8677417392521979, -0.07701839279253664}, {-0.0007329523045247477, 0.3732688420773089, 0.4231608535246955}, {-0.628458 ... 1802556, -0.646006722738045, 0.22111034631867293}, {0.5843977994899021, 0.20194372201917066, 0.04486228650659786}}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 3, {ValueDimensions -> 3, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: ts["ValueDimensions"]
Wolfram Language code: MardiaCombinedTest[ts]
Wolfram Language code: MardiaCombinedTest[ts["Values"]]

Possible Issues  (1)

If the covariance matrix of the data is not positive definite, the test will fail:

Wolfram Language code: data = {{37, 67, 72, 25}, {39, 27, 22, 51}, {63, 71, 59, 2}};
Wolfram Language code: PositiveDefiniteMatrixQ@Covariance[data]
Wolfram Language code: MardiaCombinedTest[data]

The number of data points must be greater than the dimension of the data:

Wolfram Language code: Tally@Table[PositiveDefiniteMatrixQ[Covariance[RandomVariate[NormalDistribution[], {4, 5}]]], 10 ^ 3]
Wolfram Language code: Tally@Table[PositiveDefiniteMatrixQ[Covariance[RandomVariate[NormalDistribution[], {5, 5}]]], 10 ^ 3]
Wolfram Language code: Tally@Table[PositiveDefiniteMatrixQ[Covariance[RandomVariate[NormalDistribution[], {6, 5}]]], 10 ^ 3]

Neat Examples  (1)

Compute the statistic when the null hypothesis is true:

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], {250, 100}];
Wolfram Language code: T1 = MardiaCombinedTest[#, "TestStatistic"]& /@ data1;

The test statistic given a particular alternative:

Wolfram Language code: data2 = RandomVariate[MultivariateTDistribution[{{1, .2}, { .2, 1}}, 10], {250, 100}];
Wolfram Language code: T2 = MardiaCombinedTest[#, "TestStatistic"]& /@ data2;

Compare the distributions of the test statistics:

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}, PlotRange -> All]
Wolfram Research (2010), MardiaCombinedTest, Wolfram Language function, https://reference.wolfram.com/language/ref/MardiaCombinedTest.html.

Text

Wolfram Research (2010), MardiaCombinedTest, Wolfram Language function, https://reference.wolfram.com/language/ref/MardiaCombinedTest.html.

CMS

Wolfram Language. 2010. "MardiaCombinedTest." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MardiaCombinedTest.html.

APA

Wolfram Language. (2010). MardiaCombinedTest. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MardiaCombinedTest.html

BibTeX

@misc{reference.wolfram_2026_mardiacombinedtest, author="Wolfram Research", title="{MardiaCombinedTest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/MardiaCombinedTest.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mardiacombinedtest, organization={Wolfram Research}, title={MardiaCombinedTest}, year={2010}, url={https://reference.wolfram.com/language/ref/MardiaCombinedTest.html}, note=[Accessed: 12-June-2026]}