Wolfram Language & System Documentation Center

WatsonUSquareTest

WatsonUSquareTest[data]

tests whether data is normally distributed using the Watson test.

WatsonUSquareTest[data,dist]

tests whether data is distributed according to dist using the Watson test.

WatsonUSquareTest[data,dist,"property"]

returns the value of "property".

Details and Options

WatsonUSquareTest performs the Watson goodness-of-fit test with null hypothesis that data was drawn from a population with distribution dist, and alternative hypothesis that it was not.
By default, a probability value or -value is returned.
A small -value suggests that it is unlikely that the data came from dist.
The dist can be any symbolic distribution with numeric and symbolic parameters or a dataset.
The data can be univariate {x₁,x₂,…} or multivariate {{x₁,y₁,…},{x₂,y₂,…},…}.
The Watson test assumes that the data came from a continuous distribution.
The Watson test effectively uses a test statistic based on where and , is the empirical CDF of data, and is the CDF of dist.
For multivariate tests, the sum of the univariate marginal -values is used and is assumed to follow a UniformSumDistribution under .
WatsonUSquareTest[data,dist,"HypothesisTestData"] returns a HypothesisTestData object htd that can be used to extract additional test results and properties using the form htd["property"].
WatsonUSquareTest[data,dist,"property"] can be used to directly give the value of "property".
Properties related to the reporting of test results include:

	"PValue"	-value
	"PValueTable"	formatted version of "PValue"
	"ShortTestConclusion"	a short description of the conclusion of a test
	"TestConclusion"	a description of the conclusion of a test
	"TestData"	test statistic and -value
	"TestDataTable"	formatted version of "TestData"
	"TestStatistic"	test statistic
	"TestStatisticTable"	formatted "TestStatistic"

The following properties are independent of which test is being performed.
Properties related to the data distribution include:
"FittedDistribution" fitted distribution of data

"FittedDistributionParameters" distribution parameters of data
The following options can be given:
Method Automatic the method to use for computing -values

SignificanceLevel 0.05 cutoff for diagnostics and reporting
For a test for goodness of fit, a cutoff is chosen such that is rejected only if . The value of used for the "TestConclusion" and "ShortTestConclusion" properties is controlled by the SignificanceLevel option. By default, is set to 0.05.
With the setting Method->"MonteCarlo", datasets of the same length as the input are generated under using the fitted distribution. The EmpiricalDistribution from WatsonUSquareTest[s_i,dist,"TestStatistic"] is then used to estimate the -value.

Examples

open all close all

Basic Examples (4)

Perform a Watson test for normality:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^4];

Wolfram Language code: WatsonUSquareTest[data]

Test the fit of some data to a particular distribution:

Wolfram Language code: data = RandomVariate[LaplaceDistribution[1, 2], 10^3];

Wolfram Language code: WatsonUSquareTest[data, LaplaceDistribution[1, 2]]

Compare the distributions of two datasets:

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: data2 = RandomVariate[NormalDistribution[], 150];

Wolfram Language code: WatsonUSquareTest[data1, data2]

Extract the test statistic from a Watson test:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^3];

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[], "TestStatistic"]

Scope (9)

Testing (6)

Perform a Watson test for normality:

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10^4];
data2 = RandomVariate[StudentTDistribution[3], 10^4];

The -value for the normal data is large compared to the -value for the non-normal data:

Wolfram Language code: WatsonUSquareTest[data1]

Wolfram Language code: WatsonUSquareTest[data2]

Test the goodness of fit to a particular distribution:

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10^3];
data2 = RandomVariate[CauchyDistribution[0, 1], 10^3];

Wolfram Language code: WatsonUSquareTest[data1, CauchyDistribution[0, 1]]

Wolfram Language code: WatsonUSquareTest[data2, CauchyDistribution[0, 1]]

Compare the distributions of two datasets:

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 10^3];
data2 = RandomVariate[NormalDistribution[], 10^3];

Wolfram Language code: WatsonUSquareTest[data1, data2]

The two datasets do not have the same distribution:

Wolfram Language code: data3 = RandomVariate[NormalDistribution[0, 1.25], 10^3];

Wolfram Language code: WatsonUSquareTest[data1, data3]

Test for multivariate normality:

Wolfram Language code:

data1 = RandomVariate[BinormalDistribution[.5], 10^3];
data2 = RandomVariate[LaplaceDistribution[1, 2], {10^3, 2}];

Wolfram Language code: WatsonUSquareTest[data1]

Wolfram Language code: WatsonUSquareTest[data2]

Test for goodness of fit to any multivariate distribution:

Wolfram Language code:

data1 = RandomVariate[BinormalDistribution[.5], 10^3];
data2 = RandomVariate[𝒹 = LaplaceDistribution[1, 2], {10^3, 2}];

Wolfram Language code: 𝒟 = ProductDistribution[𝒹, 𝒹];

Wolfram Language code: WatsonUSquareTest[data1, 𝒟]

Wolfram Language code: WatsonUSquareTest[data2, 𝒟]

Create a HypothesisTestData object for repeated property extraction:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 10^5];

Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"]

The properties available for extraction:

Wolfram Language code: ℋ["Properties"]

Reporting (3)

Tabulate the results of the Watson test:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"];

The full test table:

Wolfram Language code: ℋ["TestDataTable"]

A -value table:

Wolfram Language code: ℋ["PValueTable"]

The test statistic:

Wolfram Language code: ℋ["TestStatisticTable"]

Retrieve the entries from a Watson test table for custom reporting:

Wolfram Language code:

data1 = RandomVariate[NormalDistribution[], 100];
data2 = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: ℋ1 = WatsonUSquareTest[data1, Automatic, "TestData"]

Wolfram Language code: ℋ2 = WatsonUSquareTest[data2, Automatic, "TestData"]

Wolfram Language code:

BarChart[{Labeled[ℋ1, "Set 1"], Labeled[ℋ2, "Set 2"]}, ChartLabels -> {"SubscriptBox[D, n]", "p‐value"}]

Report test conclusions using "ShortTestConclusion" and "TestConclusion":

Wolfram Language code: data = BlockRandom[SeedRandom[1];RandomVariate[ParetoDistribution[1.05, 2], 100]];

Wolfram Language code: ℋ = WatsonUSquareTest[data, ParetoDistribution[1, 2], "HypothesisTestData"];

Wolfram Language code: ℋ["ShortTestConclusion"]

Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

The conclusion may differ at a different significance level:

Wolfram Language code: ℋ = WatsonUSquareTest[data, ParetoDistribution[1, 2], "HypothesisTestData", SignificanceLevel -> .001];

Wolfram Language code: ℋ["ShortTestConclusion"]

Wolfram Language code: ℋ["TestConclusion"]//TraditionalForm

Options (3)

Method (3)

Use Monte Carlo-based methods for a computation formula:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[], Method -> "MonteCarlo"]

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[], Method -> Automatic]

Set the number of samples to use for Monte Carlo-based methods:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code:

pts = Table[{i, WatsonUSquareTest[data, NormalDistribution[], Method -> {"MonteCarlo", "MonteCarloSamples" -> i}]}, {i, Range[5, 100, 5]}];

The Monte Carlo estimate converges to the true -value with increasing samples:

Wolfram Language code: pval = WatsonUSquareTest[data, NormalDistribution[]];

Wolfram Language code:

Show[ListLinePlot[pts, PlotRange -> {0, 1}, FrameLabel -> {"Samples", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

Set the random seed used in Monte Carlo-based methods:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];

Wolfram Language code:

pts = Table[{i, WatsonUSquareTest[data, NormalDistribution[], Method -> {"MonteCarlo", "RandomSeed" -> i, "MonteCarloSamples" -> 50}]}, {i, Range[1, 10]}];

The seed affects the state of the generator and has some effect on the resulting -value:

Wolfram Language code: pval = WatsonUSquareTest[data, NormalDistribution[]];

Wolfram Language code:

Show[ListLinePlot[pts, PlotRange -> {Min[pts[[All, 2]]], Max[pts[[All, 2]]]}, FrameLabel -> {"Seed", "P-Value"}, Frame -> True, AxesOrigin -> {0, 0}], Graphics[{Dashed, Line[{{0, pval}, {100, pval}}]}]]

Applications (2)

A power curve for the Watson test:

Wolfram Language code: data = Table[RandomVariate[UniformDistribution[{-4, 4}], {500, i}], {i, n = {5, 7, 10, 15, 20, 25, 30}}];

Wolfram Language code: ℋ = Table[WatsonUSquareTest[data[[i, j]], NormalDistribution[]], {i, Length[data]}, {j, Length[data[[i]]]}];

Wolfram Language code: pC = Interpolation[Transpose[{n, Table[Probability[x ≤ 0.05, xi], {i, ℋ}]}], InterpolationOrder -> 1];

Visualize the approximate power curve:

Wolfram Language code: Plot[pC[x], {x, 5, 30}, PlotRange -> {0, 1}, Ticks -> {n, Automatic}, AxesOrigin -> {0, 0}]

Estimate the power of the Watson test when the underlying distribution is a UniformDistribution[{-4,4}], the test size is 0.05, and the sample size is 12:

Wolfram Language code: pC[12.]

A statistics class decides to test a board game spinner for bias. Each of the 50 students in the class spins the spinner once. A device was used to record the angle of rotation in radians for each spin:

Wolfram Language code:

data = {25.1, 28.51, 15.58, 7.98, 7.87, 28.9, 28.72, 10.64, 27.33, 23.86, 6.49, 11.02, 8.66, 28.84, 31.14, 24.05, 15.92, 12.66, 20.31, 17.06, 17.45, 21.94, 9.8, 7.26, 11.44, 23.78, 18.83, 13.17, 23.12, 18.06, 21.79, 26.57, 22.11, 21.12, 13.24, 24.26, 18.48, 28.63, 20.51, 8.21, 21.82, 17.09, 30.67, 14.99, 28.42, 21.64, 16.75, 8.06, 9.5, 30.55};

Wolfram Language code: ListPlot[Table[{Cos[x], Sin[x]}, {x, data}], AspectRatio -> 1]

Convert each measure to a measure on :

Wolfram Language code: conv[d_] := With[{r = d / 2π}, 2π(r - IntegerPart[r])]

Wolfram Language code: cData = conv /@ data;

A test for uniformity on the circle shows the spinner to be unbiased:

Wolfram Language code: WatsonUSquareTest[cData, UniformDistribution[{0, 2π}], "TestDataTable"]

Properties & Relations (8)

By default, univariate data is compared to a NormalDistribution:

Wolfram Language code: data = RandomVariate[NormalDistribution[2, 3], 10^4];

Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"];

Wolfram Language code: ℋ["TestDataTable"]

The parameters have been estimated from the data:

Wolfram Language code: ℋ["FittedDistribution"]

Multivariate data is compared to a MultinormalDistribution by default:

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{1, 2, 3}, IdentityMatrix[3]], 1000];

Wolfram Language code: ℋ = WatsonUSquareTest[data, Automatic, "HypothesisTestData"];

Wolfram Language code: ℋ["TestDataTable"]

Wolfram Language code: ℋ["FittedDistribution"]//TraditionalForm

The parameters of the test distribution are estimated from the data if not specified:

Wolfram Language code: data = RandomVariate[NormalDistribution[1, 2], 1000];

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[μ, σ], "FittedDistribution"]

Specified parameters are not estimated:

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[μ, 2], "FittedDistribution"]

Wolfram Language code: WatsonUSquareTest[data, NormalDistribution[1, 2], "FittedDistribution"]

Maximum-likelihood estimates are used for unspecified parameters of the test distribution:

Wolfram Language code: data = RandomVariate[ExponentialDistribution[3], 10^3];

Wolfram Language code: ℋ = WatsonUSquareTest[data, ExponentialDistribution[λ], "FittedDistribution"]

Wolfram Language code: WatsonUSquareTest[data, ExponentialDistribution[λ]]

If the parameters are unknown, WatsonUSquareTest applies a correction when possible:

Wolfram Language code: data = RandomVariate[NormalDistribution[3, 4], 10^4];

Wolfram Language code: est = EstimatedDistribution[data, NormalDistribution[μ, σ]]

The parameters are estimated but no correction is applied:

Wolfram Language code: WatsonUSquareTest[data, est]

Wolfram Language code: ℋ = WatsonUSquareTest[data, NormalDistribution[μ, σ], "HypothesisTestData"];

The fitted distribution is the same as before, and the -value is corrected:

Wolfram Language code: ℋ["FittedDistribution"]

Wolfram Language code: ℋ["PValue"]

Independent marginal densities are assumed in tests for multivariate goodness of fit:

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], 100];

Wolfram Language code: WatsonUSquareTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0.252}, {0.252, 0.665}}], "TestStatistic"]

The test statistic is identical when independence is assumed:

Wolfram Language code: WatsonUSquareTest[data, MultinormalDistribution[{0, 0}, {{0.118, 0}, {0, 0.665}}], "TestStatistic"]

The Watson statistic can be defined using NExpectation:

Wolfram Language code:

n = 10;
h0 = NormalDistribution[1, 2];
data = RandomVariate[h0, n];

Wolfram Language code:

f[x_] := CDF[h0, x]
Overscript[f,  ^ ][x_] := CDF[EmpiricalDistribution[data], x]

Wolfram Language code:

d[x_] := Overscript[f,  ^ ][x] - f[x]
Overscript[d, _] = NExpectation[d[x], xh0];

Wolfram Language code: n NExpectation[(d[x] - Overscript[d, _]) ^ 2, xh0]

Wolfram Language code: WatsonUSquareTest[data, h0, "TestStatistic"]

The Watson test works with the values only when the input is a TimeSeries:

Wolfram Language code:

ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 
    0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 
    0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, 
    -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, 
  {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];

Wolfram Language code: WatsonUSquareTest[ts]

Wolfram Language code: WatsonUSquareTest[ts["Values"]]

Possible Issues (3)

The Watson test is not intended for discrete distributions:

Wolfram Language code: data = RandomVariate[DiscreteUniformDistribution[{-10, 10}], 35];

Wolfram Language code: WatsonUSquareTest[data, DiscreteUniformDistribution[{-10, 10}]]

The continuity correction typically does a good job of preserving the size of the test:

Wolfram Language code: sim = RandomVariate[DiscreteUniformDistribution[{-10, 10}], {500, 35}];

Wolfram Language code: p = Quiet[WatsonUSquareTest[#, DiscreteUniformDistribution[{-10, 10}]]]& /@ sim;

Wolfram Language code:

Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> Dashed]]

This may not be the case in some situations:

Wolfram Language code: sim = RandomVariate[DiscreteUniformDistribution[{1, 3}], {500, 35}];

Wolfram Language code: p = Quiet[WatsonUSquareTest[#, DiscreteUniformDistribution[{1, 3}]]]& /@ sim;

Wolfram Language code:

Show[ListLinePlot[Table[{α, Probability[pv ≤ α, pvp]}, {α, .01, 1, .01}]], Plot[x, {x, 0, 1}, PlotStyle -> Dashed]]

Use Monte Carlo methods or PearsonChiSquareTest in these cases:

Wolfram Language code: WatsonUSquareTest[sim[[1]], DiscreteUniformDistribution[{1, 3}], Method -> "MonteCarlo"]

Wolfram Language code: PearsonChiSquareTest[sim[[1]], DiscreteUniformDistribution[{1, 3}]]

The Watson test is not valid for some distributions when parameters have been estimated from the data:

Wolfram Language code: data = RandomVariate[BetaDistribution[1, 2], 100];

Wolfram Language code: WatsonUSquareTest[data, BetaDistribution[1, b]]

Provide parameter values if they are known:

Wolfram Language code: WatsonUSquareTest[data, BetaDistribution[1, 2]]

Alternatively, use Monte Carlo methods to approximate the -value:

Wolfram Language code: WatsonUSquareTest[data, BetaDistribution[1, b], Method -> "MonteCarlo"]

Ties in the data are ignored:

Wolfram Language code: data = RandomVariate[NormalDistribution[], 1000];

Wolfram Language code: WatsonUSquareTest[Join[data, {First[data]}]]

Wolfram Language code: PearsonChiSquareTest[Join[data, {First[data]}]]

Differences may be more apparent with larger numbers of ties:

Wolfram Language code: WatsonUSquareTest[Join[data, data]]

Wolfram Language code: PearsonChiSquareTest[Join[data, data]]

Neat Examples (1)

Compute the statistic when the null hypothesis is true:

Wolfram Language code: data = RandomVariate[NormalDistribution[], {500, 100}];

Wolfram Language code: T1 = WatsonUSquareTest[#, NormalDistribution[], "TestStatistic"]& /@ data;

The test statistic given a particular alternative:

Wolfram Language code: T2 = WatsonUSquareTest[#, LaplaceDistribution[1, 2], "TestStatistic"]& /@ data;

Compare the distributions of the test statistics:

Wolfram Language code:

SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}, PlotRange -> All]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

WatsonUSquareTest

Details and Options

Examples

Basic Examples (4)

Scope (9)

Testing (6)

Reporting (3)

Options (3)

Method (3)

Applications (2)

Properties & Relations (8)

Possible Issues (3)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

	Method	Automatic	the method to use for computing -values
	SignificanceLevel	0.05	cutoff for diagnostics and reporting

WatsonUSquareTest

Details and Options

Examples

Basic Examples (4)

Scope (9)

Testing (6)

Reporting (3)

Options (3)

Method (3)

Applications (2)

Properties & Relations (8)

Possible Issues (3)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX