Wolfram Language & System Documentation Center

MarginalDistribution

MarginalDistribution[dist,k]

represents a univariate marginal distribution of the k coordinate from the multivariate distribution dist.

MarginalDistribution[dist,{k₁,k₂,…}]

represents a multivariate marginal distribution of the {k₁,k₂,…} coordinates.

Details

The distribution dist can be either a discrete or continuous multivariate distribution.
For a discrete multivariate distribution dist with PDF , the PDF of MarginalDistribution[dist,{k₁,…,k_m}] is given by where ξ={x_k₁,…,x_{k_m}}.
For a continuous multivariate distribution dist with PDF , the PDF of MarginalDistribution[dist,{k₁,…,k_m}] is given by where ξ={x_k₁,…,x_{k_m}}.
MarginalDistribution can be used with such functions as Mean, CDF, and RandomVariate, etc.

Examples

open all close all

Basic Examples (3)

One-dimensional marginal distributions:

Wolfram Language code: MarginalDistribution[BinormalDistribution[ρ], 1]

Wolfram Language code: MarginalDistribution[MultinomialDistribution[n, {p1, p2, p3}], 1]

Two-dimensional marginal distributions:

Wolfram Language code: MarginalDistribution[DirichletDistribution[{α1, α2, α3, α4}], {1, 2}]

Wolfram Language code: MarginalDistribution[MultivariatePoissonDistribution[μ, {μ1, μ2, μ3}], {2, 3}]

Marginal distributions can be used like any other distribution:

Wolfram Language code: ℳ = MarginalDistribution[NegativeMultinomialDistribution[10, {1 / 3, 1 / 3, 1 / 6}], 2]

Wolfram Language code: PDF[ℳ, x]

Wolfram Language code: DiscretePlot[%, {x, 0, 40}]

Scope (34)

Basic Uses (8)

Find the second univariate marginal distribution:

Wolfram Language code: 𝒟 = UniformDistribution[{{a, b}, {c, d}, {e, f}}];

Wolfram Language code: MarginalDistribution[𝒟, 2]

Multivariate marginals depend on the coordinate order given:

Wolfram Language code: {MarginalDistribution[𝒟, {3, 1}], MarginalDistribution[𝒟, {1, 3}]}

Univariate marginals behave as univariate distributions:

Wolfram Language code: 𝒟 = ProbabilityDistribution[ Exp[-x ^ 2y ], {x, 1, ∞}, {y, 0, ∞}];

Wolfram Language code: ℳ1 = MarginalDistribution[𝒟, 1]

Find distribution functions:

Wolfram Language code: {PDF[ℳ1, x], CDF[ℳ1, x]}

Wolfram Language code:

Table[Plot[df[ℳ1, x]//Evaluate, {x, 1, 10}, PlotLabel -> df, Filling -> Axis, AxesOrigin -> {0, 0}, PlotRange -> All], {df, {PDF, CDF, SurvivalFunction, HazardFunction}}]

Multivariate marginals behave like a multivariate distribution:

Wolfram Language code: 𝒟 = ProbabilityDistribution[3x y^2 E^-z, {x, 0, 1}, {y, -1, 1}, {z, 0, ∞}];

Wolfram Language code: ℳ12 = MarginalDistribution[𝒟, {1, 2}]

Find distribution functions:

Wolfram Language code: {PDF[ℳ12, {x, y}], CDF[ℳ12, {x, y}]}

Wolfram Language code:

Table[Plot3D[df[ℳ12, {x, y}]//Evaluate, {x, 0, 1}, {y, -1, 1}, PlotLabel -> df], {df, {PDF, CDF, SurvivalFunction, HazardFunction}}]

Special moments are computed for each univariate marginal distribution:

Wolfram Language code: 𝒟 = ProbabilityDistribution[6( x - y / 2) ^ 2, {x, 0, 1}, {y, 0, 1}];

Wolfram Language code:

ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Compare moments of marginal distributions with the moment of original distribution:

Wolfram Language code: {{Mean[ℳ1], Mean[ℳ2]}, Mean[𝒟]}

Wolfram Language code: {{Variance[ℳ1], Variance[ℳ2]}, Variance[𝒟]}

Wolfram Language code: {{Skewness[ℳ1], Skewness[ℳ2]}, Skewness[𝒟]}

Wolfram Language code: {{Kurtosis[ℳ1], Kurtosis[ℳ2]}, Kurtosis[𝒟]}

A general multivariate moment cannot typically be found from marginal moments:

Wolfram Language code: {Moment[𝒟, {1, 3}], Moment[ℳ1, 1]Moment[ℳ2, 3]}

Quantile functions can be computed for univariate marginal distributions:

Wolfram Language code:

𝒟 = ProbabilityDistribution[6 x ^ 2 y, {x, 0, 1}, {y, 0, 1}];
ℳ1 = MarginalDistribution[𝒟, 1]

Find the quantile functions:

Wolfram Language code: 𝒬1 = Quantile[ℳ1, q]

Wolfram Language code: Plot[𝒬1, {q, 0, 1}, Filling -> Axis]

Or special medians:

Wolfram Language code: Median[ℳ1]

Wolfram Language code: InterquartileRange[ℳ1]

Generate random variates from MarginalDistribution:

Wolfram Language code:

𝒟 = ProbabilityDistribution[6 x ^ 2 y, {x, 0, 1}, {y, 0, 1}];
ℳ1 = MarginalDistribution[𝒟, 1]

Wolfram Language code: sample = RandomVariate[ℳ1, 10 ^ 3];

Compare the histogram to the plot of the PDF of the marginal distribution:

Wolfram Language code: Show[Histogram[sample, {0, 1, .01}, "PDF"], Plot[PDF[ℳ1, x]//Evaluate, {x, 0, 1}, PlotStyle -> Thick]]

Estimate distribution parameters:

Wolfram Language code: data = RandomVariate[MarginalDistribution[NegativeMultinomialDistribution[10, {.2, .3, .1}], 1], 10 ^ 3];

Wolfram Language code: edist = EstimatedDistribution[data, MarginalDistribution[NegativeMultinomialDistribution[n, {.2, .3, .1}], 1]]

Define a trivariate probability distribution:

Wolfram Language code: 𝒟 = ProbabilityDistribution[ 1 / 10 x y^3 E^-z, {x, 0, 1}, {y, 1, 3}, {z, 0, ∞}];

Find marginal distributions:

Wolfram Language code:

ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];
ℳ3 = MarginalDistribution[𝒟, 3];

Wolfram Language code:

Plot[{PDF[ℳ1, u], PDF[ℳ2, u], PDF[ℳ3, u]}//Evaluate, {u, 0, 3}, Filling -> Axis, PlotLegends -> {"ℳ1", "ℳ2", "ℳ3"}]

Find the covariance matrix of :

Wolfram Language code: Covariance[𝒟]//MatrixForm

The variances of the marginals form the diagonal of the covariance matrix of :

Wolfram Language code: {Variance[ℳ1], Variance[ℳ2], Variance[ℳ3]}

Parametric Distributions (2)

The marginal distributions of many multivariate parametric distributions automatically simplify:

Wolfram Language code: 𝒟 = DirichletDistribution[{α1, α2, α3, α4}];

The univariate marginals follow BetaDistribution:

Wolfram Language code: MarginalDistribution[𝒟, 1]

The multivariate marginals follow DirichletDistribution:

Wolfram Language code: MarginalDistribution[𝒟, {1, 2}]

In some cases, marginal distributions will not automatically simplify:

Wolfram Language code: 𝒟 = MultinomialDistribution[100, {.3, .5, .2}];

Univariate marginals simplify to a BinomialDistribution:

Wolfram Language code: MarginalDistribution[𝒟, 1]

The multivariate marginals do not simplify:

Wolfram Language code: ℳ12 = MarginalDistribution[𝒟, {1, 2}]

The resulting marginal can still be used like any other distribution:

Wolfram Language code: DiscretePlot3D[PDF[ℳ12, {x, y}]//Evaluate, {x, 10, 50}, {y, 35, 60}, ExtentSize -> 1]

Nonparametric Distributions (3)

Find marginals of an EmpiricalDistribution:

Wolfram Language code:

data = RandomVariate[MultinomialDistribution[20, {.3, .4, .3}], 40];
𝒟 = EmpiricalDistribution[data];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Cumulative distribution function of the marginal distributions:

Wolfram Language code: Table[DiscretePlot[CDF[d, x], {x, data[[ ;; , 1]]}, ExtentSize -> Right], {d, {ℳ1, ℳ2}}]

Find marginals for a SmoothKernelDistribution:

Wolfram Language code:

data = RandomVariate[BinormalDistribution[.4], 30];
𝒟 = SmoothKernelDistribution[data];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Wolfram Language code: Table[Plot[PDF[d, x], {x, -2, 2}, Filling -> Axis], {d, {ℳ1, ℳ2}}]

Find marginals of a HistogramDistribution:

Wolfram Language code:

data = RandomVariate[MultivariatePoissonDistribution[10, {1, 8}], 100];
𝒟 = HistogramDistribution[data];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Wolfram Language code: Table[Plot[PDF[d, x], {x, 0, 30}, Filling -> Axis], {d, {ℳ1, ℳ2}}]

Compare to the histograms of the components:

Wolfram Language code: Table[Histogram[data[[All, i]], Automatic, "PDF"], {i, 2}]

Derived Distributions (9)

Find the marginal distribution of a MarginalDistribution:

Wolfram Language code:

𝒟 = NegativeMultinomialDistribution[n, {p1, p2, p3, p4}];
ℳ = MarginalDistribution[𝒟, {1, 3, 4}]

The second marginal of is the third marginal of :

Wolfram Language code: MarginalDistribution[ℳ, 2]

Find marginals of a CopulaDistribution:

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 3}, {NormalDistribution[μ, σ], ExponentialDistribution[λ]}];

Wolfram Language code: ℳ1 = MarginalDistribution[𝒟, 1]

Wolfram Language code: ℳ2 = MarginalDistribution[𝒟, 2]

Find marginals of a TruncatedDistribution:

Wolfram Language code:

𝒟 = TruncatedDistribution[{{1 / 2, 2 / 3}, {1 / 3, 4 / 5}}, DirichletDistribution[{1, 3, 6}]];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Probability density function:

Wolfram Language code: pdf1 = PDF[ℳ1, x]//FullSimplify

Wolfram Language code: pdf2 = PDF[ℳ2, x]//FullSimplify

Wolfram Language code: Plot[{pdf1, pdf2}, {x, 0.3, 0.6}, Filling -> Axis, PlotRange -> All]

Find marginals of a MixtureDistribution:

Wolfram Language code:

𝒞1 = BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ];
𝒞2 = MultivariateTDistribution[{{1, p}, {p, 1}}, ν];
𝒟 = MixtureDistribution[{a, b}, {𝒞1, 𝒞2}];

Each marginal distribution is the mixture of marginals:

Wolfram Language code: MarginalDistribution[𝒟, 1]

Wolfram Language code: MarginalDistribution[𝒟, 2]

Compare with the marginal distributions of the components:

Wolfram Language code: {MarginalDistribution[𝒞1, 1], MarginalDistribution[𝒞1, 2]}

Wolfram Language code: {MarginalDistribution[𝒞2, 1], MarginalDistribution[𝒞2, 2]}

Marginals of a MixtureDistribution are mixtures of marginals:

Wolfram Language code:

𝒟 = MixtureDistribution[{4, 1}, {MultivariatePoissonDistribution[1, {7, 12}], MultivariatePoissonDistribution[1, {1, 2}]}];

Wolfram Language code: ℳ1 = MarginalDistribution[𝒟, 1]

Wolfram Language code: ℳ2 = MarginalDistribution[𝒟, 2]

Plot a probability density function for both marginals:

Wolfram Language code: DiscretePlot[Evaluate[{PDF[ℳ1, x], PDF[ℳ2, x]}], {x, 0, 20}, PlotMarkers -> Automatic]

Create a bivariate distribution using marginal distributions:

Wolfram Language code: 𝒫 = ProductDistribution[ℳ1, ℳ2];

Compare a PDF of the original distribution with the ProductDistribution of marginals:

Wolfram Language code:

{DiscretePlot3D[PDF[𝒟, {x, y}], {x, 0, 15}, {y, 0, 25}, ExtentSize -> Full], DiscretePlot3D[PDF[𝒫, {x, y}], {x, 0, 15}, {y, 0, 25}, ExtentSize -> Full]}

Compare covariance matrices:

Wolfram Language code: MatrixForm /@ {Covariance[𝒟], Covariance[𝒫]}

Find marginal distributions of a TransformedDistribution:

Wolfram Language code:

𝒟 = TransformedDistribution[{u / 2, u + v / 3}, {u, v}BinormalDistribution[{2, 1}, {1 / 2, 1}, 0.4]];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Wolfram Language code: Plot[Evaluate[{PDF[ℳ1, x], PDF[ℳ2, x]}], {x, 0, 4}, Filling -> Axis]

Find marginal distributions of a ParameterMixtureDistribution:

Wolfram Language code:

𝒟 = ParameterMixtureDistribution[BinormalDistribution[ρ], ρBetaDistribution[2, 3]];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Visualize the probability density function:

Wolfram Language code:

{SmoothHistogram[RandomVariate[ℳ1, 10 ^ 3], Automatic, "PDF", Filling -> Axis], SmoothHistogram[RandomVariate[ℳ2, 10 ^ 3], Automatic, "PDF", Filling -> Axis]}

Find marginal distributions of an OrderDistribution:

Wolfram Language code:

𝒟 = OrderDistribution[{ErlangDistribution[2, 3.5], 4}, {1, 4}];
ℳ1 = MarginalDistribution[𝒟, 1];
ℳ2 = MarginalDistribution[𝒟, 2];

Probability density function:

Wolfram Language code: Table[Plot[Evaluate[PDF[m, x]], {x, 0, 2}, PlotRange -> {0, 3.2}, Filling -> Axis], {m, {ℳ1, ℳ2}}]

Mean:

Wolfram Language code: {Mean[ℳ1], Mean[ℳ2]}

Variance:

Wolfram Language code: {Variance[ℳ1], Variance[ℳ2]}

Marginals of a QuantityDistribution give QuantityDistribution:

Wolfram Language code:

𝒟 = QuantityDistribution[MultivariateTDistribution[{{1, 1 / 2, -1 / 3}, {1 / 2, 1, 0}, {-1 / 3, 0, 1}}, 7], {"Grams", "Meters", "Seconds"}]

Univariate marginal:

Wolfram Language code: MarginalDistribution[𝒟, 2]

Multivariate marginal:

Wolfram Language code: MarginalDistribution[𝒟, {1, 3}]

Automatic Simplifications (12)

Discrete Parametric Distributions (3)

Marginals of multivariate DiscreteUniformDistribution again follow a uniform distribution:

Wolfram Language code: 𝒟 = DiscreteUniformDistribution[{{a, b}, {c, d}, {e, f}}];

Wolfram Language code: MarginalDistribution[𝒟, 2]

Wolfram Language code: MarginalDistribution[𝒟, {1, 3}]

Univariate marginals of MultivariatePoissonDistribution follow PoissonDistribution:

Wolfram Language code: 𝒟 = MultivariatePoissonDistribution[μ, {μ1, μ2, μ3}];

Wolfram Language code: MarginalDistribution[𝒟, 1]

Multivariate marginals again follow multivariate Poisson distribution:

Wolfram Language code: MarginalDistribution[𝒟, {2, 3}]

Univariate marginals of MultinomialDistribution follow BinomialDistribution:

Wolfram Language code: 𝒟 = MultinomialDistribution[n, {p1, p2, p3}];

Wolfram Language code: MarginalDistribution[𝒟, 3]

Continuous Parametric Distributions (6)

Marginals of BinormalDistribution follow NormalDistribution:

Wolfram Language code: 𝒟 = BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ];

Wolfram Language code: {MarginalDistribution[𝒟, 1], MarginalDistribution[𝒟, 2]}

All univariate marginals of MultinormalDistribution follow NormalDistribution:

Wolfram Language code:

Σ = (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠);

Wolfram Language code: 𝒟 = MultinormalDistribution[{μ1, μ2, μ3}, Σ];

Wolfram Language code: MarginalDistribution[𝒟, 2]

Multivariate marginals of MultinormalDistribution are multivariate normal:

Wolfram Language code: MarginalDistribution[𝒟, {2, 3}]

Marginals of multivariate UniformDistribution follow uniform distribution:

Wolfram Language code: 𝒟 = UniformDistribution[{{a, b}, {c, d}, {e, f}}];

Wolfram Language code: MarginalDistribution[𝒟, 3]

Wolfram Language code: MarginalDistribution[𝒟, {1, 2}]

One-dimensional marginals of DirichletDistribution follow BetaDistribution:

Wolfram Language code: 𝒟 = DirichletDistribution[{α1, α2, α3, α4}];

Wolfram Language code: MarginalDistribution[𝒟, 2]

Multivariate marginals of DirichletDistribution again follow Dirichlet distribution:

Wolfram Language code: MarginalDistribution[𝒟, {1, 3}]

Univariate marginals of MultivariateTDistribution follow StudentTDistribution:

Wolfram Language code: 𝒟 = MultivariateTDistribution[{{1, 0}, {0, 1}}, ν];

Wolfram Language code: {MarginalDistribution[𝒟, 1], MarginalDistribution[𝒟, 2]}

Univariate marginals of LogMultinormalDistribution follow LogNormalDistribution:

Wolfram Language code:

Σ = (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠);

Wolfram Language code: 𝒟 = LogMultinormalDistribution[{Subscript[μ, 1], Subscript[μ, 2], Subscript[μ, 3]}, Σ];

Wolfram Language code: MarginalDistribution[𝒟, 2]

Multivariate marginals of LogMultinormalDistribution again follow log-multinormal distribution:

Wolfram Language code: MarginalDistribution[𝒟, {1, 3}]

Derived Distributions (3)

Marginals of ProductDistribution are the component distributions:

Wolfram Language code: 𝒟 = ProductDistribution[KDistribution[2, 4], GammaDistribution[3, 2], ExponentialDistribution[5]];

One-dimensional marginal:

Wolfram Language code: MarginalDistribution[𝒟, 3]

A two-dimensional marginal is also defined by ProductDistribution:

Wolfram Language code: MarginalDistribution[𝒟, {1, 2}]

Univariate marginals of a CopulaDistribution are the marginals used in the specification:

Wolfram Language code: 𝒟 = CopulaDistribution[{"Frank", 2}, {NormalDistribution[], ExponentialDistribution[λ]}];

Wolfram Language code: MarginalDistribution[𝒟, 2]

Marginal distributions of a MixtureDistribution are the mixtures of component marginals:

Wolfram Language code:

𝒟 = MixtureDistribution[{a, b}, {BinormalDistribution[{μ1, μ2}, {σ1, σ2}, ρ], MultivariateTDistribution[{{1, p}, {p, 1}}, ν]}];

Wolfram Language code: MarginalDistribution[𝒟, 1]

Applications (5)

Visualize univariate marginal distributions together with a bivariate distribution:

Wolfram Language code: 𝒟 = DirichletDistribution[{2, 3, 2}];

Wolfram Language code: gxy = Plot3D[PDF[𝒟, {x, y}], {x, 0, 1}, {y, 0, 1}, AxesLabel -> Automatic, Mesh -> None]

Plot the univariate marginals:

Wolfram Language code:

{gx, gy} = {Plot[Evaluate[PDF[MarginalDistribution[𝒟, 1], x]], {x, 0, 1}, Filling -> Axis, FillingStyle -> Red], Plot[Evaluate[PDF[MarginalDistribution[𝒟, 2], y]], {y, 0, 1}, Filling -> Axis, FillingStyle -> Green]}

Show the results together:

Wolfram Language code:

Graphics3D[{First[gxy], First[gx] /. GraphicsComplex[pts_, rest__] :> GraphicsComplex[pts /. {x_, y_} -> {x, 0., y}, rest], First[gy] /. GraphicsComplex[pts_, rest__] :> GraphicsComplex[pts /. {x_, y_} -> {0., x, y}, rest]}, BoxRatios -> {1, 1, 0.4}]

The city-highway mileage for a midsize car is given by a binormal distribution. Find the city mileage distribution:

Wolfram Language code:

ch𝒟 = QuantityDistribution[BinormalDistribution[{18.6, 26.3}, {5.02, 4.67}, 0.91], "Miles" / "Gallons"];
city = MarginalDistribution[ch𝒟, 1]

Plot the probability density function:

Wolfram Language code: Plot[PDF[city, Quantity[x, "Miles" / "Gallons"]], {x, 6, 33}, Filling -> Axis, AxesLabel -> {"mi/gal"}]

Find the average city mileage:

Wolfram Language code: Mean[city]

The male weight and height follow a binormal distribution. Find the height distribution:

Wolfram Language code:

maleWH = BinormalDistribution[{Quantity[195, "Pounds"], Quantity[70, "Inches"]}, {Quantity[64, "Pounds"], Quantity[2, "Inches"]}, 0.42];
height = MarginalDistribution[maleWH, 2];

Probability density function:

Wolfram Language code: Plot[PDF[height, Quantity[x, "Inches"]], {x, 64, 76}, Filling -> Axis, AxesLabel -> {"in"}]

Find the median height for males:

Wolfram Language code: Median[height]

Find the lower quartile:

Wolfram Language code: Quantile[height, .25]

Express the height distribution in meters:

Wolfram Language code: UnitConvert[height, "Meters"]

A fair coin is flipped three times with the objective of getting three tails. Find the join distribution of the number of failures in the form of getting a head on the second or on the third flip:

Wolfram Language code:

𝒟 = NegativeMultinomialDistribution[1, {1 / 2, 1 / 4, 1 / 8}];
ℳ = MarginalDistribution[𝒟, {2, 3}];

Probability density function:

Wolfram Language code: DiscretePlot3D[PDF[ℳ, {x, y}], {x, 0, 5}, {y, 0, 5}, ExtentSize -> 2 / 3]

Wolfram Language code: PDF[ℳ, {x, y}]

Find the average number of failures of each kind:

Wolfram Language code: Mean[ℳ]

Find the total number of failures of both kinds:

Wolfram Language code: Total[Mean[ℳ]]

Simulate the number of failures by getting a head on the second or on the third flip:

Wolfram Language code: sample = RandomVariate[ℳ, 10]

Wolfram Language code: BarChart[sample, ChartLayout -> "Stacked", ChartElementFunction -> "GlassRectangle"]

A university campus lies completely within twin cities and . On a day there are on average 10 car accidents on campus and the joint distribution of the number of accidents per day in both cities is:

Wolfram Language code: 𝒟 = MultivariatePoissonDistribution[10, {5, 10}];

Find the distribution of the number of accidents in each city:

Wolfram Language code: 𝒜 = MarginalDistribution[𝒟, 1]

Wolfram Language code: ℬ = MarginalDistribution[𝒟, 2]

Compare probability density functions:

Wolfram Language code:

DiscretePlot[PDF[ReleaseHold[#], x], {x, 0, 35}, PlotRange -> {0, 0.1}, ExtentSize -> 1 / 2, PlotLabel -> ToString[#]]& /@ {HoldForm[𝒜], HoldForm[ℬ]}

Simulate the number of accidents per day in city for 30 days:

Wolfram Language code: accidents = RandomVariate[𝒜, 30];

Wolfram Language code:

ListPlot[{accidents, {{0, Mean[𝒜]}, {30, Mean[𝒜]}}}, AxesOrigin -> {0, 0}, Filling -> {1 -> Axis}, Joined -> {False, True}]

Properties & Relations (5)

Use a marginal distribution if an event does not depend on all the variables:

Wolfram Language code:

𝒟 = BinormalDistribution[{1, 0}, {1, 1 / 2}, 0.4];
p[u_] = u ^ 2 > 2;

Calculate the event probability:

Wolfram Language code: Probability[p[y], {x, y}𝒟] == Probability[p[y], yMarginalDistribution[𝒟, 2]]//FullSimplify

Find expectations if the function does not involve all the variables:

Wolfram Language code: g[u_] = u ^ 3 + u;

Wolfram Language code: Expectation[g[x], {x, y}𝒟] == Expectation[g[x], xMarginalDistribution[𝒟, 1]]//FullSimplify

An -variable multivariate distribution has proper marginal distributions:

Wolfram Language code: Table[Length[Subsets[Range[n], {1, n - 1}]], {n, 2, 10}]

Wolfram Language code: Table[2^n - 2, {n, 2, 10}]

Obtain the marginal CDF by taking limits of complementary variables:

Wolfram Language code: 𝒟 = ProbabilityDistribution[(E^-(y^2/2)/ π^3 / 2 (1 + x^4)), {x, -∞, ∞}, {y, -∞, ∞}];

Wolfram Language code: cdf = Assuming[{x, y}∈Reals, Refine[CDF[𝒟, {x, y}]]];

Compute the marginal CDF as :

Wolfram Language code: Limit[cdf, y -> ∞]

Wolfram Language code: CDF[MarginalDistribution[𝒟, 1], x]

Wolfram Language code: Simplify[%% - %]

Compute the marginal CDF as :

Wolfram Language code: Limit[cdf, x -> ∞]

Wolfram Language code: CDF[MarginalDistribution[𝒟, 2], y]

Wolfram Language code: Simplify[%% - %]

Obtain the marginal PDF by integrating over complementary variables:

Wolfram Language code: 𝒟 = ProbabilityDistribution[(E^-(y^2/2)/ π^3 / 2 (1 + x^4)), {x, -∞, ∞}, {y, -∞, ∞}];

Wolfram Language code: pdf = PDF[𝒟, {x, y}];

Compute the marginal PDF as :

Wolfram Language code: Integrate[pdf, {y, -∞, ∞}]

Wolfram Language code: PDF[MarginalDistribution[𝒟, 1], x]

Wolfram Language code: Simplify[%% - %]

Compute the marginal PDF as :

Wolfram Language code: Integrate[pdf, {x, -∞, ∞}]

Wolfram Language code: PDF[MarginalDistribution[𝒟, 2], y]

Wolfram Language code: Simplify[%% - %]

Multivariate marginal distributions preserve the correlation between components:

Wolfram Language code:

Σ = (⁠|           |           |           |
| --------- | --------- | --------- |
| σ1^2      | ρ12 σ1 σ2 | ρ13 σ1 σ3 |
| ρ12 σ1 σ2 | σ2^2      | ρ23 σ2 σ3 |
| ρ13 σ1 σ3 | ρ23 σ2 σ3 | σ3^2      |⁠);

Wolfram Language code: 𝒟 = MultinormalDistribution[{μ1, μ2, μ3}, Σ];

Find the marginal distribution for the first and the third components:

Wolfram Language code: ℳ13 = MarginalDistribution[𝒟, {1, 3}]

The covariance of the marginal is a submatrix :

Wolfram Language code: Covariance[ℳ13]//MatrixForm

For a discrete distribution:

Wolfram Language code: 𝒫 = MultivariatePoissonDistribution[μ, {μ1, μ2, μ3}];

Covariance matrix for :

Wolfram Language code: Covariance[𝒫]//MatrixForm

Define the marginal for the second and the third components:

Wolfram Language code: ℳ𝒫23 = MarginalDistribution[𝒫, {2, 3}]

Covariance for is a submatrix of the covariance of :

Wolfram Language code: Covariance[ℳ𝒫23]//MatrixForm

Neat Examples (1)

All six proper marginal PDFs from a trivariate distribution:

Wolfram Language code: 𝒟 = ProductDistribution[UniformDistribution[{0, 1}], TriangularDistribution[{0, 1}], BetaDistribution[2, 4]];

Wolfram Language code: Table[Plot[PDF[MarginalDistribution[𝒟, i], x]//Evaluate, {x, 0, 1}, Filling -> Axis, PlotLabel -> {i}], {i, 1, 3}]

Wolfram Language code:

Table[
	ind = Complement[{1, 2, 3}, {i}];
	Plot3D[PDF[MarginalDistribution[𝒟, ind], {x, y}]//Evaluate, {x, 0, 1}, {y, 0, 1}, PlotRange -> All, Mesh -> None, Exclusions -> None, PlotPoints -> 35, PlotLabel -> ind], {i, 1, 3}]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

MarginalDistribution

Details

Examples

Basic Examples (3)

Scope (34)

Basic Uses (8)

Parametric Distributions (2)

Nonparametric Distributions (3)

Derived Distributions (9)

Automatic Simplifications (12)

Discrete Parametric Distributions (3)

Continuous Parametric Distributions (6)

Derived Distributions (3)

Applications (5)

Properties & Relations (5)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

MarginalDistribution

Details

Examples

Basic Examples (3)

Scope (34)

Basic Uses (8)

Parametric Distributions (2)

Nonparametric Distributions (3)

Derived Distributions (9)

Automatic Simplifications (12)

Discrete Parametric Distributions (3)

Continuous Parametric Distributions (6)

Derived Distributions (3)

Applications (5)

Properties & Relations (5)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX