WOLFRAM

Wolfram Language & System Documentation Center

MathieuSPrime[a,q,z]

gives the derivative with respect to z of the odd Mathieu function with characteristic value a and parameter q.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

MathieuSPrime

MathieuSPrime[a,q,z]

gives the derivative with respect to z of the odd Mathieu function with characteristic value a and parameter q.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For certain special arguments, MathieuSPrime automatically evaluates to exact values.
  • MathieuSPrime can be evaluated to arbitrary numerical precision.
  • MathieuSPrime automatically threads over lists.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: MathieuSPrime[2, 1, 3.2]

Plot over a subset of the reals:

Wolfram Language code: Plot[MathieuSPrime[3, 2, x], {x, -4, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[MathieuSPrime[3, 1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[MathieuSPrime[3, 2, z], {z, 0, 3}]

Scope  (19)

Numerical Evaluation  (5)

Evaluate numerically to high precision:

Wolfram Language code: N[MathieuSPrime[2, 1, 37 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: MathieuSPrime[2, 1, 3.70000000000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: MathieuSPrime[I, -2, 2.5 + I]

Evaluate MathieuSPrime efficiently at high precision:

Wolfram Language code: MathieuSPrime[2, 1, 3.7`500]//Timing
Wolfram Language code: MathieuSPrime[2, 1, 3.7`10000];//Timing

MathieuSPrime threads elementwise over lists:

Wolfram Language code: MathieuSPrime[a, q, {z1, z2, z3}]

Compute the elementwise values of an array:

Wolfram Language code: MathieuSPrime[1, 0, {{-π / 2, 0}, {0, π / 4}}]

Or compute the matrix MathieuSPrime function using MatrixFunction:

Wolfram Language code: MatrixFunction[MathieuSPrime[1, 0, #]&, {{-π / 2, 0}, {0, π / 4}}]

Specific Values  (3)

Simple exact values are generated automatically:

Wolfram Language code: MathieuSPrime[a, 0, z]

Find a zero of MathieuSPrime:

Wolfram Language code: xzero = FindRoot[MathieuSPrime[3, 2, x] == 0, {x, 1}][[1, 2]]
Wolfram Language code: Plot[MathieuSPrime[3, 2, x], {x, -2, 2}, Epilog -> Style[Point[{xzero, MathieuSPrime[3, 2, xzero]}], PointSize[Large], Red]]

MathieuSPrime is an even function:

Wolfram Language code: MathieuSPrime[a, q, -x]

Visualization  (2)

Plot the MathieuSPrime function:

Wolfram Language code: Plot[{MathieuSPrime[3, -2, x], MathieuSPrime[2, 1, x], MathieuSPrime[1, 0, x]}, {x, -7, 7}]

Plot the real part of MathieuSPrime for and :

Wolfram Language code: ComplexContourPlot[Re[MathieuSPrime[2, 1, z]], {z, -π - 2I, π + 2I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of MathieuSPrime for and :

Wolfram Language code: ComplexContourPlot[Im[MathieuSPrime[2, 1, z]], {z, -π - 2I, π + 2I}, IconizedObject[«PlotOptions»]]

Function Properties  (4)

MathieuSPrime has singularities and discontinuities when the characteristic exponent is an integer:

Wolfram Language code: FunctionSingularities[MathieuSPrime[a, q, z], {a, q, z}]//Quiet
Wolfram Language code: FunctionDiscontinuities[MathieuSPrime[a, q, z], {a, q, z}]//Quiet

is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[MathieuSPrime[3, 2, x], x]

MathieuSPrime is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[MathieuSPrime[a, q, x], {a, q, x}]

MathieuSPrime is neither convex nor concave:

Wolfram Language code: FunctionConvexity[MathieuSPrime[a, q, x], {a, q, x}]

Differentiation  (3)

First derivative:

Wolfram Language code: D[MathieuSPrime[a, q, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[MathieuSPrime[a, q, x], {x, n}], {n, 1, 4}]

Plot higher derivatives for and :

Wolfram Language code: Plot[Evaluate[derivs /. {a -> 3, q -> 2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Plot higher derivatives for and :

Wolfram Language code: Plot[Evaluate[derivs /. {a -> 3, q -> -2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

MathieuSPrime is the derivative of MathieuS:

Wolfram Language code: D[MathieuS[a, q, x], x]

Series Expansions  (2)

Taylor expansion:

Wolfram Language code: Series[MathieuSPrime[3, 2, x], {x, 0, 7}]

Plot the first three approximations for MathieuSPrime around :

Wolfram Language code: terms = Normal@Table[Series[MathieuSPrime[3, 2, x], {x, 0, m}], {m, 2, 6, 2}]; Plot[{MathieuSPrime[3, 2, x], terms}, {x, -0.9, 0.9}]

Taylor expansion of MathieuSPrime at a generic point:

Wolfram Language code: Series[MathieuSPrime[a, q, x], {x, x0, 2}]

Applications  (1)

Mathieu functions arise as solutions of the Laplace equation in an ellipse:

Wolfram Language code: ellipseψ[n_, z0_][r_, φ_] := I MathieuS[MathieuCharacteristicB[n, z0], z0, I r] MathieuS[MathieuCharacteristicB[n, z0], z0, φ]

This defines the square of the gradient (the local kinetic energy of a vibrating membrane):

Wolfram Language code: gradientSquareEllipseψ[n_, z0_][r_, φ_] = -2 / (Cos[2φ] - Cosh[2r])(D[ellipseψ[n, z0][r, φ], φ] ^ 2 + D[ellipseψ[n, z0][r, φ], r] ^ 2);

This finds a zero:

Wolfram Language code: FindRoot[MathieuS[MathieuCharacteristicB[3, q], q, I / 2], {q, 15}]

This plots the absolute value of the gradient of an eigenfunction:

Wolfram Language code: ParametricPlot3D[{Cosh[r] Cos[φ], Sinh[r] Sin[φ], 5Re[gradientSquareEllipseψ[3, q /. %][r, φ]]}, {r, 0, 1 / 2}, {φ, 0, 2Pi}, Mesh -> False]//Quiet

Neat Examples  (1)

Phase space plots of the Mathieu function:

Wolfram Language code: ParametricPlot[Evaluate[{MathieuSPrime[8, 5, t], D[MathieuSPrime[8, 5, t], t]}], {t, 0, 100}, AspectRatio -> 1]
Wolfram Research (1996), MathieuSPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuSPrime.html.

Text

Wolfram Research (1996), MathieuSPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuSPrime.html.

CMS

Wolfram Language. 1996. "MathieuSPrime." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MathieuSPrime.html.

APA

Wolfram Language. (1996). MathieuSPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MathieuSPrime.html

BibTeX

@misc{reference.wolfram_2026_mathieusprime, author="Wolfram Research", title="{MathieuSPrime}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/MathieuSPrime.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mathieusprime, organization={Wolfram Research}, title={MathieuSPrime}, year={1996}, url={https://reference.wolfram.com/language/ref/MathieuSPrime.html}, note=[Accessed: 13-June-2026]}