WOLFRAM

Wolfram Language & System Documentation Center

MathieuCPrime[a,q,z]

gives the derivative with respect to z of the even Mathieu function with characteristic value a and parameter q.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Neat Examples  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

MathieuCPrime

MathieuCPrime[a,q,z]

gives the derivative with respect to z of the even Mathieu function with characteristic value a and parameter q.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • For certain special arguments, MathieuCPrime automatically evaluates to exact values.
  • MathieuCPrime can be evaluated to arbitrary numerical precision.
  • MathieuCPrime automatically threads over lists.

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: MathieuCPrime[2, 1, 3.2]

Plot over a subset of the reals:

Wolfram Language code: Plot[MathieuCPrime[3, 2, x], {x, -4, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[MathieuCPrime[3, 1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion about the origin:

Wolfram Language code: Series[MathieuCPrime[3, 2, z], {z, 0, 4}]

Scope  (19)

Numerical Evaluation  (5)

Evaluate numerically to high precision:

Wolfram Language code: N[MathieuCPrime[2, 1, 37 / 10], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: MathieuCPrime[2, 1, 3.70000000000000000000000000000000]

Evaluate for complex arguments and parameters:

Wolfram Language code: MathieuCPrime[I, -2, 2.5 + I]

Evaluate MathieuCPrime efficiently at high precision:

Wolfram Language code: MathieuCPrime[2, 1, 3.7`500]//Timing
Wolfram Language code: MathieuCPrime[2, 1, 3.7`10000];//Timing

MathieuCPrime threads elementwise over lists:

Wolfram Language code: MathieuCPrime[a, q, {z1, z2, z3}]

Compute the elementwise values of an array:

Wolfram Language code: MathieuCPrime[1, 0, {{-π / 2, 0}, {0, π / 4}}]

Or compute the matrix MathieuCPrime function using MatrixFunction:

Wolfram Language code: MatrixFunction[MathieuCPrime[1, 0, #]&, {{-π / 2, 0}, {0, π / 4}}]

Specific Values  (3)

Simple exact values are generated automatically:

Wolfram Language code: MathieuCPrime[a, 0, z]

Find a zero of MathieuCPrime:

Wolfram Language code: xzero = FindRoot[MathieuCPrime[3, 2, x] == 0, {x, 0.5}][[1, 2]]
Wolfram Language code: Plot[MathieuCPrime[3, 2, x], {x, -2, 2}, Epilog -> Style[Point[{xzero, MathieuCPrime[3, 2, xzero]}], PointSize[Large], Red]]

MathieuCPrime is an odd function:

Wolfram Language code: MathieuCPrime[a, q, -x]

Visualization  (2)

Plot the MathieuCPrime function:

Wolfram Language code: Plot[{MathieuCPrime[3, -2, x], MathieuCPrime[2, 1, x], MathieuCPrime[1, 0, x]}, {x, -5, 5}]

Plot the real part of MathieuCPrime for and :

Wolfram Language code: ComplexContourPlot[Re[MathieuCPrime[2, 1, z]], {z, -π - 2I, π + 2I}, IconizedObject[«PlotOptions»]]

Plot the imaginary part of MathieuCPrime for and :

Wolfram Language code: ComplexContourPlot[Im[MathieuCPrime[2, 1, z]], {z, -π - 2I, π + 2I}, IconizedObject[«PlotOptions»]]

Function Properties  (4)

MathieuCPrime has singularities and discontinuities when the characteristic exponent is an integer:

Wolfram Language code: FunctionSingularities[MathieuCPrime[a, q, z], {a, q, z}]//Quiet
Wolfram Language code: FunctionDiscontinuities[MathieuCPrime[a, q, z], {a, q, z}]//Quiet

is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[MathieuCPrime[3, 2, x], x]

MathieuCPrime is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[MathieuCPrime[a, q, x], {a, q, x}]

MathieuCPrime is neither convex nor concave:

Wolfram Language code: FunctionConvexity[MathieuCPrime[a, q, x], {a, q, x}]

Differentiation  (3)

First derivative:

Wolfram Language code: D[MathieuCPrime[a, q, x], x]

Higher derivatives:

Wolfram Language code: derivs = Table[D[MathieuCPrime[a, q, x], {x, n}], {n, 1, 4}]

Plot higher derivatives for and :

Wolfram Language code: Plot[Evaluate[derivs /. {a -> 3, q -> 2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

Plot higher derivatives for and :

Wolfram Language code: Plot[Evaluate[derivs /. {a -> 3, q -> -2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]

MathieuCPrime is the derivative of MathieuC:

Wolfram Language code: D[MathieuC[a, q, x], x]

Series Expansions  (2)

Taylor expansion:

Wolfram Language code: Series[MathieuCPrime[3, 2, x], {x, 0, 8}]

Plot the first three approximations for MathieuCPrime around :

Wolfram Language code: terms = Normal@Table[Series[MathieuCPrime[3, 2, x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{MathieuCPrime[3, 2, x], terms}, {x, -1, 1}]

Taylor expansion of MathieuCPrime at a generic point:

Wolfram Language code: Series[MathieuCPrime[a, q, x], {x, x0, 2}]

Applications  (1)

Mathieu functions arise as solutions of the Laplace equation in an ellipse:

Wolfram Language code: ellipseψ[n_, z0_][r_, φ_] := MathieuC[MathieuCharacteristicA[n, z0], z0, I r] MathieuC[MathieuCharacteristicA[n, z0], z0, φ]

This defines the square of the gradient (the local kinetic energy of a vibrating membrane):

Wolfram Language code: gradientSquareEllipseψ[n_, z0_][r_, φ_] = -2 / (Cos[2φ] - Cosh[2r])(D[ellipseψ[n, z0][r, φ], φ] ^ 2 + D[ellipseψ[n, z0][r, φ], r] ^ 2);

This finds a zero:

Wolfram Language code: FindRoot[MathieuC[MathieuCharacteristicA[1, q], q, I / 2], {q, 5}]

This plots the absolute value of the gradient of an eigenfunction:

Wolfram Language code: ParametricPlot3D[{Cosh[r] Cos[φ], Sinh[r] Sin[φ], Re[gradientSquareEllipseψ[1, q /. %][r, φ]]}, {r, 0, 1 / 2}, {φ, 0, 2Pi}, Mesh -> False, Exclusions -> {φ == π}]//Quiet

Neat Examples  (1)

Phase space plots of the Mathieu function:

Wolfram Language code: ParametricPlot[Evaluate[{MathieuCPrime[8, 5, t], D[MathieuCPrime[8, 5, t], t]}], {t, 0, 100}, AspectRatio -> 1]
Wolfram Research (1996), MathieuCPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuCPrime.html.

Text

Wolfram Research (1996), MathieuCPrime, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuCPrime.html.

CMS

Wolfram Language. 1996. "MathieuCPrime." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MathieuCPrime.html.

APA

Wolfram Language. (1996). MathieuCPrime. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MathieuCPrime.html

BibTeX

@misc{reference.wolfram_2026_mathieucprime, author="Wolfram Research", title="{MathieuCPrime}", year="1996", howpublished="\url{https://reference.wolfram.com/language/ref/MathieuCPrime.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_mathieucprime, organization={Wolfram Research}, title={MathieuCPrime}, year={1996}, url={https://reference.wolfram.com/language/ref/MathieuCPrime.html}, note=[Accessed: 13-June-2026]}