MathieuS
MathieuS[a,q,z]
gives the odd Mathieu function with characteristic value a and parameter q.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
- The Mathieu functions satisfy the equation
. - For certain special arguments, MathieuS automatically evaluates to exact values.
- MathieuS can be evaluated to arbitrary numerical precision.
- MathieuS automatically threads over lists.
Examples
open all close allBasic Examples (4)
MathieuS[2, 1, 3.2]Plot over a subset of the reals:
Plot[MathieuS[3, 2, x], {x, -4, 4}]Plot over a subset of the complexes:
ComplexPlot3D[MathieuS[3, 1, z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]Series expansion at the origin:
Series[MathieuS[3, 2, z], {z, 0, 4}]Scope (19)
Numerical Evaluation (4)
Evaluate numerically to high precision:
N[MathieuS[2, 1, 37 / 10], 50]The precision of the output tracks the precision of the input:
MathieuS[2, 1, 3.70000000000000000000000000000000]Evaluate for complex arguments and parameters:
MathieuS[I, -2, 2.5 + I]Evaluate MathieuS efficiently at high precision:
MathieuS[2, 1, 3.7`500]//TimingMathieuS[2, 1, 3.7`10000];//TimingCompute the elementwise values of an array:
MathieuS[1, 0, {{-π / 2, 0}, {0, π / 4}}]Or compute the matrix MathieuS function using MatrixFunction:
MatrixFunction[MathieuS[1, 0, #]&, {{-π / 2, 0}, {0, π / 4}}]Specific Values (3)
Simple exact values are generated automatically:
MathieuS[a, 0, z]Find a local maximum as the root of 
in the maximum's neighborhood:
xmax = FindRoot[D[MathieuS[3, 2, x], x] == 0, {x, 1}][[1, 2]]Plot[MathieuS[3, 2, x], {x, -2, 2}, Epilog -> Style[Point[{xmax, MathieuS[3, 2, xmax]}], PointSize[Large], Red]]MathieuS is an odd function:
MathieuS[a, q, -x]Visualization (3)
Plot the MathieuS function:
Plot[{MathieuS[3, -2, x], MathieuS[2, 1, x], MathieuS[1, 0, x]}, {x, -5, 5}]Plot the real part of MathieuS for 
and 
:
ComplexContourPlot[Re[MathieuS[2, 1, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Plot the imaginary part of MathieuS for 
and 
:
ComplexContourPlot[Im[MathieuS[2, 1, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Plot the real part of MathieuS for 
and 
:
ComplexContourPlot[Re[MathieuS[3, -2, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Plot the imaginary part of MathieuS for 
and 
:
ComplexContourPlot[Im[MathieuS[3, -2, z]], {z, -π / 2 - 2I, π / 2 + 2I}, IconizedObject[«PlotOptions»]]Function Properties (4)
MathieuS has singularities and discontinuities when the characteristic exponent is an integer:
FunctionSingularities[MathieuS[a, q, z], {a, q, z}]//QuietFunctionDiscontinuities[MathieuS[a, q, z], {a, q, z}]//Quiet
is neither nondecreasing nor nonincreasing:
FunctionMonotonicity[MathieuS[3, 2, x], x]MathieuS is neither non-negative nor non-positive:
FunctionSign[MathieuS[a, q, x], {a, q, x}]MathieuS is neither convex nor concave:
FunctionConvexity[MathieuS[a, q, x], {a, q, x}]Differentiation (3)
D[MathieuS[a, q, x], x]derivs = Table[D[MathieuS[a, q, x], {x, n}], {n, 1, 4}]Plot higher derivatives for 
and 
:
Plot[Evaluate[derivs /. {a -> 3, q -> 2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]Plot higher derivatives for 
and 
:
Plot[Evaluate[derivs /. {a -> 3, q -> -2}], {x, -2, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]Mathieu functions are the solutions to the differential equation 
:
DSolve[D[y[x], {x, 2}] + (a - 2 q Cos[2 x]) y[x] == 0, y, x]Series Expansions (2)
Series[MathieuS[3, 2, x], {x, 0, 8}]Plot the first three approximations for MathieuS around 
:
terms = Normal@Table[Series[MathieuS[3, 2, x], {x, 0, m}], {m, 2, 6, 2}];
Plot[{MathieuS[3, 2, x], terms}, {x, -1.5, 1.5}]Taylor expansion of MathieuS at a generic point:
Series[MathieuS[a, q, x], {x, x0, 2}]Applications (3)
This differential equation is solved in terms of MathieuC and MathieuS functions:
DSolve[(b + a x) y[x] + (-1 + 2 x) Derivative[1][y][x] + 2 (-1 + x) x Derivative[2][y][x] == 0, y[x], x]Solve the Schrödinger equation with periodic potential:
DSolve[-y''[x] + Cos[x]y[x] == ℰ y[x], y[x], x]By the Bloch theorem, solutions are bounded provided 
is within an energy band. The energy gap corresponds to a range of 
where MathieuCharacteristicExponent has a non-vanishing imaginary part:
Plot[{ArcTan[Re[MathieuS[a, 2, 100]]], Im[MathieuCharacteristicExponent[a, 2]]}, {a, 2, 8}, WorkingPrecision -> 16, PlotStyle -> {{Dashing[Tiny]}, {Thick}}]Solve the Laplace equation in an ellipse using separation of variables:
ellipseψ[n_, z0_][r_, f_] := With[{ch = MathieuCharacteristicB[n, z0]}, I MathieuS[ch, z0, I r]MathieuS[ch, z0, f]]FindRoot[MathieuS[MathieuCharacteristicB[5, q], q, I / 2], {q, 30}, WorkingPrecision -> 25]This plots an eigenfunction. It vanishes at the ellipse boundary:
ParametricPlot3D[{Cosh[r] Cos[f], Sinh[r] Sin[f], 2ellipseψ[5, q /. %][r, f]}, {r, 0, 1 / 2}, {f, 0, 2Pi}, Mesh -> False]Possible Issues (1)
Related Links
MathWorld
The Wolfram Functions SiteText
Wolfram Research (1996), MathieuS, Wolfram Language function, https://reference.wolfram.com/language/ref/MathieuS.html.
CMS
Wolfram Language. 1996. "MathieuS." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MathieuS.html.
APA
Wolfram Language. (1996). MathieuS. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MathieuS.html