WOLFRAM

Wolfram Language & System Documentation Center

MeshCellIndex[mreg,d]

gives the cell indices for cells of dimension d in the mesh region mreg.

MeshCellIndex[mreg,cellspec]

gives the cell indices for the cells specified by cellspec.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

MeshCellIndex

MeshCellIndex[mreg,d]

gives the cell indices for cells of dimension d in the mesh region mreg.

MeshCellIndex[mreg,cellspec]

gives the cell indices for the cells specified by cellspec.

Details

  • MeshCellIndex is often used to get the cell index {d,i} from a symbolic cell h[{i1,…}].
  • The cell indices returned have the form {d,i}, where d is dimension and i a positive integer.
  • The mesh region mreg can be either MeshRegion or BoundaryMeshRegion.
  • The cell specification cellspec follows the standard form described for MeshRegion and BoundaryMeshRegion.
  • MeshCellCount can be used to find the maximum number of cell indices for each dimension.

Examples

open all close all

Basic Examples  (1)

Find the cell index for different symbolic cells:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Triangle[{1, 2, 3}]]

The 2D cell indices:

Wolfram Language code: MeshCellIndex[mr, {Triangle[{1, 2, 3}]}]

The 1D cell indices:

Wolfram Language code: MeshCellIndex[mr, {Line[{1, 2}], Line[{2, 3}], Line[{3, 1}]}]

The 0D cell indices:

Wolfram Language code: MeshCellIndex[mr, {Point[1], Point[2], Point[3]}]

Scope  (8)

Get the cell indices for a MeshRegion in 1D:

Wolfram Language code: ℛ = MeshRegion[{{0}, {1}, {2}}, {Line[{1, 2}], Point[3]}]

Indices of 0D cells:

Wolfram Language code: MeshCellIndex[ℛ, 0]

Index of the line segment:

Wolfram Language code: MeshCellIndex[ℛ, {Line[{1, 2}]}]

Get the cell indices for a MeshRegion in 2D:

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 3, 4}]]

Indices of 1D cells:

Wolfram Language code: MeshCellIndex[ℛ, 1]

Index of the top line segment:

Wolfram Language code: MeshCellIndex[ℛ, {Line[{3, 4}]}]

Use it to highlight just that segment:

Wolfram Language code: HighlightMesh[ℛ, %]

Get the cell indices for a MeshRegion in 3D:

Wolfram Language code: ℛ = MeshRegion[{{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}}, Tetrahedron[{{1, 2, 3, 5}, {1, 3, 4, 5}}], MeshCellStyle -> 2 -> Opacity[0.3]]

Indices of the 2D cells:

Wolfram Language code: MeshCellIndex[ℛ, 2]

Index of the top point:

Wolfram Language code: MeshCellIndex[ℛ, {Point[5]}]

Get the cell indices for a BoundaryMeshRegion in 1D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {5, 1}]]

Only the boundary points are cells:

Wolfram Language code: MeshCellIndex[ℛ, 0]

Get the cell indices for a BoundaryMeshRegion in 2D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {6, 2}]]

Indices of the 1D cells:

Wolfram Language code: MeshCellIndex[ℛ, 1]

Get the cell indices for a BoundaryMeshRegion in 3D:

Wolfram Language code: ℛ = ConvexHullMesh[RandomReal[1, {10, 3}]]

Indices of the 2D cells:

Wolfram Language code: MeshCellIndex[ℛ, 2]

Use All to get indices for cells of all dimensions:

Wolfram Language code: ℛ = MeshRegion[{{0, 0}, {1, 0}, {1, 1}}, Polygon[{1, 2, 3}]]
Wolfram Language code: MeshCellIndex[ℛ, All]

Works with large mesh regions:

Wolfram Language code: ℛ = DiscretizeRegion[Disk[], MaxCellMeasure -> 10 ^ -5]
Wolfram Language code: MeshCellCount[ℛ]
Wolfram Language code: Length[MeshCellIndex[ℛ, 0]] == MeshCellCount[ℛ, 0]

Properties & Relations  (4)

MeshCells gives the cells corresponding to cell indices:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Polygon[{1, 2, 3}]]
Wolfram Language code: mci = MeshCellIndex[mr, 1]

The corresponding mesh cells:

Wolfram Language code: MeshCells[mr, mci]

MeshCellIndex gives the cell indices corresponding to MeshCells:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Polygon[{1, 2, 3}]]
Wolfram Language code: mc = MeshCells[mr, 1]

The corresponding cell indices:

Wolfram Language code: MeshCellIndex[mr, mc]

HighlightMesh can use cell indices as input:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {0, 1}}, Polygon[{1, 2, 3}]]
Wolfram Language code: mc = MeshCellIndex[mr, {Line[{1, 2}], Point[{3}]}]
Wolfram Language code: HighlightMesh[mr, mc]

The length of a MeshCellIndex output is MeshCellCount evaluated with the same input:

Wolfram Language code: mr = DelaunayMesh[RandomReal[1, {10, 2}]]
Wolfram Language code: {Length[MeshCellIndex[mr, 1]], MeshCellCount[mr, 1]}

Possible Issues  (1)

When coordinates are unused, they are removed from the MeshRegion representation:

Wolfram Language code: mr = MeshRegion[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, Polygon[{1, 2, 4}]]
Wolfram Language code: MeshCellIndex[mr, Polygon[{1, 2, 4}]]

Use the indices as if the third coordinate was never given:

Wolfram Language code: MeshCellIndex[mr, Polygon[{1, 2, 3}]]
Wolfram Research (2014), MeshCellIndex, Wolfram Language function, https://reference.wolfram.com/language/ref/MeshCellIndex.html.

Text

Wolfram Research (2014), MeshCellIndex, Wolfram Language function, https://reference.wolfram.com/language/ref/MeshCellIndex.html.

CMS

Wolfram Language. 2014. "MeshCellIndex." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MeshCellIndex.html.

APA

Wolfram Language. (2014). MeshCellIndex. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MeshCellIndex.html

BibTeX

@misc{reference.wolfram_2026_meshcellindex, author="Wolfram Research", title="{MeshCellIndex}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/MeshCellIndex.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_meshcellindex, organization={Wolfram Research}, title={MeshCellIndex}, year={2014}, url={https://reference.wolfram.com/language/ref/MeshCellIndex.html}, note=[Accessed: 12-June-2026]}