WOLFRAM

Wolfram Language & System Documentation Center

MissingDataMethod

is an option to TimeSeries, EventSeries and other functions that controls how to process missing data.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Possible Issues  
See Also
History
Cite this Page

MissingDataMethod

MissingDataMethod

is an option to TimeSeries, EventSeries and other functions that controls how to process missing data.

Details

  • A missing data method typically provides methods for how to fill in values that are missing.
  • Typical settings include:
  • Nonedo no processing
    Automaticpick a method automatically
    "name"use a specified method
    {"name",opt1->val1,…}use a specified method with particular options
  • Possible settings for "name" include "Interpolation" and "Constant".
  • The missing data methods for individual functions are documented on the corresponding reference pages.

Examples

open all close all

Basic Examples  (2)

Fill in missing data values using linear interpolation:

Wolfram Language code: data = {-1, -2, -1, 0, Missing[], 2, 1, 2, 1, 0, 1, 2, 1, 2, 3};
Wolfram Language code: ListLinePlot[data]

Use TimeSeries to complete the data using interpolation:

Wolfram Language code: TimeSeries[data, {1}, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}];
Wolfram Language code: ListLinePlot[%]

Fill in missing data values with the mean of the available data:

Wolfram Language code: ts = TimeSeries[{-1, 0, -1, 0, Missing[], Missing[], Missing[], 2, 1, 3, 1}]
Wolfram Language code: ListLinePlot[ts]
Wolfram Language code: TimeSeries[ts, MissingDataMethod -> {"Constant", Echo@Mean[ts]}]
Wolfram Language code: ListLinePlot[%]

Scope  (3)

Use a custom interpolation for filling in missing values:

Wolfram Language code: missd = {2, 1, 3, Missing[], 2, 1, 2, Missing[], 6, 2, 5};
Wolfram Language code: ts = TimeSeries[missd, Automatic, MissingDataMethod -> {"Interpolation", Method -> "Spline", InterpolationOrder -> 3}]
Wolfram Language code: ListLinePlot[ts]

Fill missing values by keeping the value from the left:

Wolfram Language code: data = {0, -2, -1, 0, Missing[], 2, 1, 2, Missing[], 0, 1, Missing[], 3, 2, 3};
Wolfram Language code: tsL = TimeSeries[data, {1}, MissingDataMethod -> "PreviousElement"]

Fill missing values by keeping the value from the right:

Wolfram Language code: tsR = TimeSeries[data, {1}, MissingDataMethod -> "NextElement"]

Compare the time series:

Wolfram Language code: {ListPlot[{data, tsL}, Joined -> {False, True}], ListPlot[{data, tsR}, Joined -> {False, True}]}

Fill missing values with an arbitrary constant:

Wolfram Language code: data = {-1, -2, -1, 0, Missing[], 2, 1, 2, 1, 0, Missing[], 2, 1, 2, 3};
Wolfram Language code: ts = TimeSeries[data, MissingDataMethod -> {"Constant", 3}]
Wolfram Language code: {ListLinePlot[data, DataRange -> {0, 14}], ListLinePlot[ts, Epilog -> {Red, PointSize[Medium], Point[{4, 3}], Point[{10, 3}]}]}

Properties & Relations  (4)

The setting Automatic will use the ResamplingMethod setting:

Wolfram Language code: missd = {2, 1, 3, Missing[], 2, 1, 2, Missing[], 6, 2, 5};
Wolfram Language code: p1 = ListPlot[missd, DataRange -> {0, Length[missd] - 1}, PlotStyle -> {StandardGray, PointSize[Large]}]
Wolfram Language code: ts1 = TimeSeries[missd, {0}, MissingDataMethod -> Automatic]
Wolfram Language code: Show[Plot[ts1[t], {t, 0, 10}, PlotRange -> {{0, 11}, All}], p1]

The method for handling missing data does not need to match the ResamplingMethod:

Wolfram Language code: ts2 = TimeSeries[missd, {0}, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 0}, ResamplingMethod -> {"Interpolation", InterpolationOrder -> 1}]
Wolfram Language code: Show[Plot[ts2[t], {t, 0, 10}, PlotRange -> All], p1]

The default missing data method for EventSeries is interpolation of order 0:

Wolfram Language code: data = {-1, -2, -1, 4, Missing[], 2, 1, 2, 1};
Wolfram Language code: es = EventSeries[data, MissingDataMethod -> Automatic]
Wolfram Language code: es//Normal
Wolfram Language code: ListPlot[{data, es}, DataRange -> {0, 8}, PlotStyle -> PointSize[Large], Filling -> {1 -> Axis}, PlotLegends -> {"data", "es"}]

The default missing data method for TimeSeries is interpolation of order 1:

Wolfram Language code: data = {-1, -2, -1, 4, Missing[], 2, 1, 2, 1};
Wolfram Language code: ts = TimeSeries[data, MissingDataMethod -> Automatic]
Wolfram Language code: ts//Normal
Wolfram Language code: ListPlot[{data, ts}, DataRange -> {0, 8}, PlotStyle -> PointSize[Large], Joined -> {False, True}, Filling -> {1 -> Axis}, PlotLegends -> {"data", "ts"}]

The default missing data method for TemporalData is interpolation of order 0:

Wolfram Language code: data = {-1, -2, -1, 4, Missing[], 2, 1, 2, 1};
Wolfram Language code: td = TemporalData[data, MissingDataMethod -> Automatic]
Wolfram Language code: td//Normal
Wolfram Language code: ListPlot[{data, td}, DataRange -> {0, 8}, PlotStyle -> PointSize[Large], Filling -> {1 -> Axis}, Joined -> {False, True}, InterpolationOrder -> 0, PlotLegends -> {"data", "td"}]

Possible Issues  (1)

Different choices of MissingDataMethod will produce different results:

Wolfram Language code: data = {-1, -2, -1, 0, Missing[], 2, 1, 2, 1, 0, 1, 2, 1, 2, 3};

Do not specify missing values:

Wolfram Language code: ts1 = TimeSeries[data, MissingDataMethod -> None]

Accumulate:

Wolfram Language code: res1 = Accumulate[ts1];

Fill missing values with a constant:

Wolfram Language code: ts2 = TimeSeries[data, MissingDataMethod -> {"Constant", 5}];
Wolfram Language code: res2 = Accumulate[ts2];

Use interpolation to fill in missing values:

Wolfram Language code: ts3 = TimeSeries[data, MissingDataMethod -> {"Interpolation", InterpolationOrder -> 1}];
Wolfram Language code: res3 = Accumulate[ts3];

Compare the results:

Wolfram Language code: ListLinePlot /@ {res1, res2, res3}
Wolfram Research (2012), MissingDataMethod, Wolfram Language function, https://reference.wolfram.com/language/ref/MissingDataMethod.html.

Text

Wolfram Research (2012), MissingDataMethod, Wolfram Language function, https://reference.wolfram.com/language/ref/MissingDataMethod.html.

CMS

Wolfram Language. 2012. "MissingDataMethod." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/MissingDataMethod.html.

APA

Wolfram Language. (2012). MissingDataMethod. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/MissingDataMethod.html

BibTeX

@misc{reference.wolfram_2026_missingdatamethod, author="Wolfram Research", title="{MissingDataMethod}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/MissingDataMethod.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_missingdatamethod, organization={Wolfram Research}, title={MissingDataMethod}, year={2012}, url={https://reference.wolfram.com/language/ref/MissingDataMethod.html}, note=[Accessed: 13-June-2026]}