WOLFRAM

Wolfram Language & System Documentation Center

PadeApproximant[expr,{x,x0,{m,n}}]

gives the Padé approximant to expr about the point x=x0, with numerator order m and denominator order n.

PadeApproximant[expr,{x,x0,n}]

gives the diagonal Padé approximant to expr about the point x=x0 of order n.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

PadeApproximant

PadeApproximant[expr,{x,x0,{m,n}}]

gives the Padé approximant to expr about the point x=x0, with numerator order m and denominator order n.

PadeApproximant[expr,{x,x0,n}]

gives the diagonal Padé approximant to expr about the point x=x0 of order n.

Details

  • The Wolfram Language can find the Padé approximant about the point x=x0 only when it can evaluate power series at that point.
  • PadeApproximant produces a ratio of ordinary polynomial expressions, not a special SeriesData object.

Examples

open all close all

Basic Examples  (2)

Order [2/3] Padé approximant for Exp[x]:

Wolfram Language code: PadeApproximant[Exp[x], {x, 0, {2, 3}}]

PadeApproximant can handle functions with poles:

Wolfram Language code: PadeApproximant[(Exp[x]/x), {x, 0, {2, 3}}]

Scope  (4)

Padé approximant of an arbitrary function:

Wolfram Language code: PadeApproximant[(f[x]/x), {x, 0, 2}]

Padé approximant with a complex-valued expansion point:

Wolfram Language code: PadeApproximant[Cos[x], {x, I, 2}]

Padé approximant with an expansion point at infinity:

Wolfram Language code: PadeApproximant[Log[1 + 1 / x], {x, Infinity, 2}]

Find a Padé approximant to a given series:

Wolfram Language code: Sum[BernoulliB[2n]x ^ n, {n, 0, 10}]
Wolfram Language code: PadeApproximant[%, {x, 0, 5}]

Generalizations & Extensions  (3)

Padé approximant centered at the point :

Wolfram Language code: PadeApproximant[Exp[x], {x, a, {2, 3}}]

Padé approximant in fractional powers:

Wolfram Language code: PadeApproximant[ Sin[Sqrt[x]], {x, 0, 3}]

Padé approximant of a function containing logarithmic terms:

Wolfram Language code: Hypergeometric2F1[2, 2, 4, 1 - x]
Wolfram Language code: PadeApproximant[Hypergeometric2F1[2, 2, 4, 1 - x], {x, 0, 5}]

Applications  (2)

Plot successive Padé approximants to :

Wolfram Language code: Plot[Evaluate[Table[PadeApproximant[Sin[x], {x, 0, n}], {n, 5}]], {x, 0, 2π}]

Construct discrete orthogonal polynomials with respect to a discrete weighted measure:

Wolfram Language code: ω[k_] = ((-1/2))^k (1/Sqrt[k]);
Wolfram Language code: moment[n_] = Sum[ω[k] / k ^ n, {k, 1, Infinity}]
Wolfram Language code: p[m_, x_] := 1 / x ^ m Denominator[PadeApproximant[Sum[x ^ k N[moment[k], 30], {k, 0, 10}], {x, 0, {m - 1, m}}]]

Plot the first few polynomials:

Wolfram Language code: Plot[Evaluate[Table[p[n, x], {n, 5}]], {x, 1, 4}]

Verify the orthogonality of the polynomials with respect to the measure:

Wolfram Language code: Table[Sum[ω[x]p[n, x] p[m, x], {x, 1, Infinity}], {n, 5}, {m, 5}]

Properties & Relations  (2)

The Padé approximant agrees with the ordinary series for terms:

Wolfram Language code: Series[PadeApproximant[Exp[x], {x, 0, {2, 3}}], {x, 0, 6}]
Wolfram Language code: Series[Exp[x], {x, 0, 6}]

For PadeApproximant gives an ordinary series:

Wolfram Language code: PadeApproximant[Exp[x], {x, 0, {5, 0}}]

Possible Issues  (2)

Padé approximants often have spurious poles not present in the original function:

Wolfram Language code: PadeApproximant[Exp[x], {x, 0, 3}]
Wolfram Language code: NSolve[Denominator[%] == 0, x]

Padé approximants of a given order may not exist:

Wolfram Language code: PadeApproximant[Cos[x], {x, 0, 1}]

Perturbing the order slightly is usually sufficient to produce an approximant:

Wolfram Language code: PadeApproximant[Cos[x], {x, 0, 2}]
Wolfram Research (2007), PadeApproximant, Wolfram Language function, https://reference.wolfram.com/language/ref/PadeApproximant.html.

Text

Wolfram Research (2007), PadeApproximant, Wolfram Language function, https://reference.wolfram.com/language/ref/PadeApproximant.html.

CMS

Wolfram Language. 2007. "PadeApproximant." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PadeApproximant.html.

APA

Wolfram Language. (2007). PadeApproximant. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PadeApproximant.html

BibTeX

@misc{reference.wolfram_2026_padeapproximant, author="Wolfram Research", title="{PadeApproximant}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/PadeApproximant.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_padeapproximant, organization={Wolfram Research}, title={PadeApproximant}, year={2007}, url={https://reference.wolfram.com/language/ref/PadeApproximant.html}, note=[Accessed: 12-June-2026]}