WOLFRAM

Wolfram Language & System Documentation Center

Parallelepiped[p,{v1,…,vk}]

represents a parallelepiped with origin p and directions vi.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

Parallelepiped

Parallelepiped[p,{v1,…,vk}]

represents a parallelepiped with origin p and directions vi.

Details and Options

Examples

open all close all

Basic Examples  (3)

A Parallelepiped in 3D:

Wolfram Language code: Graphics3D[Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}]]

And in 2D:

Wolfram Language code: Graphics[Parallelepiped[{0, 0}, {{1, 0}, {1, 1}}]]

Different styles applied to a parallelepiped:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{Opacity[0.25], Blue, ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dotted]], FaceForm[None], ℛ}]}

Volume and centroid:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Wolfram Language code: Volume[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

Scope  (16)

Graphics  (6)

Specification  (2)

A parallelepiped in dimensions is specified by a base point and up to vectors:

Wolfram Language code: Graphics[Parallelepiped[{0, 0}, {{1, 0}, {1, 1}}]]
Wolfram Language code: Graphics3D[Parallelepiped[{0, 0, 0}, {{1, 1, 0}, {1, 2, 3}}]]

A parallelepiped with specified origin and directions:

Wolfram Language code: p = {0, 0, 0}; {v1, v2, v3} = {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}};
Wolfram Language code: ill = {Opacity[1, Black], PointSize[Large], Point[p], Arrowheads[Medium], Thick, Arrow[{p, v1}], Arrow[{p, v2}], Arrow[{p, v3}]};
Wolfram Language code: Graphics3D[{Opacity[0.2], Parallelepiped[p, {v1, v2, v3}], ill}, Axes -> True, Boxed -> False]

Styling  (2)

Color directives specify the face color:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Wolfram Language code: Table[Graphics3D[{c, ℛ}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the faces and edges:

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}]}]

Coordinates  (2)

In 2D and 3D, a parallelepiped can be specified with Scaled coordinates:

Wolfram Language code: Graphics[Parallelepiped[Scaled[{0, 0}], {Scaled[{1 / 2, 0}], Scaled[{1 / 2, 1 / 2}]}], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]

Use Offset coordinates:

Wolfram Language code: Graphics[Parallelepiped[Offset[{10, 10}, {0, 0}], {Offset[{-10, 10}, {1, 0}], Offset[{-10, -10}, {1, 1}]}], Frame -> True]

Regions  (10)

Embedding dimension is the dimension of the space in which the parallelepiped lives:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {0, 1, 1}}];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

Geometric dimension is the dimension of the shape itself:

Wolfram Language code: RegionDimension[ℛ]

Membership testing:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}];
Wolfram Language code: {RegionMember[ℛ, {1 / 2, 1 / 2, 1 / 2}], RegionMember[ℛ, {1, 2, 3}]}

Conditions for membership:

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

Measure:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {0, 1, 1}}];
Wolfram Language code: RegionMeasure[ℛ]

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = Parallelepiped[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: RegionDistance[ℛ, {2, 2}]

Visualize it:

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = Parallelepiped[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]

Plot it:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Wolfram Language code: RegionNearest[ℛ, {2, 2, 2}]

Visualize it:

Wolfram Language code: pts = Flatten[Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 8]Cos[j 2 π / 8], Sin[k 2 π / 8]Cos[j 2 π / 8], Sin[j 2 π / 8]}, {k, 0, 7}, {j, -3, 3}], 1]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics3D[{{Opacity[0.5], Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A parallelepiped is bounded:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0, 0}, {{1, 0, 0, 0}, {1, 1, 0, 0}, {0, 1, 1, 0}, {0, 0, 1, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

Compute a bounding box for the region:

Wolfram Language code: RegionBounds[ℛ]

Integrate over a Parallelepiped:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Wolfram Language code: Integrate[1, {x, y, z}∈ℛ]
Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

Optimize over it:

Wolfram Language code: ℛ = Parallelepiped[{0, 0, 0}, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}];
Wolfram Language code: Minimize[{(x - 1)^2(2y - 1)^2(3z - 1)^2 + 1, {x, y, z}∈ℛ}, {x, y, z}]

Solve equations over a Parallelepiped:

Wolfram Language code: ℛ = Parallelepiped[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

Applications  (3)

For a full-dimensional Parallelepiped, the measure is easily computed from the vectors:

Wolfram Language code: v = {v1, v2} = {{1, 1}, {1, 3}};
Wolfram Language code: Area[Parallelepiped[{p1, p2}, v]]

The volume is equal to the absolute value of the determinant of the matrix :

Wolfram Language code: Abs[Det[v]]

For a lower-dimensional Parallelepiped, the square root of the Gram determinant is used:

Wolfram Language code: v = {v1, v2} = {{1, 1, 1}, {2, 3, 4}};
Wolfram Language code: Area[Parallelepiped[{p1, p2, p3}, v]]

The Gram determinant is the determinant of dotted with its Transpose:

Wolfram Language code: Sqrt[Abs[Det[v.Transpose[v]]]]

Any full-dimensional Parallelepiped can tile space:

Wolfram Language code: Graphics[{EdgeForm[Gray], FaceForm[LightBlue], Table[Parallelepiped[{1, 0}i + {1, 1}j, {{1, 0}, {1, 1}}], {i, 1, 5}, {j, 1, 5}]}]
Wolfram Language code: Graphics3D[{EdgeForm[Directive[Thin, Gray]], FaceForm[Opacity[0.3]], Table[Parallelepiped[{1, 0, 0}i + {1, 1, 0}j + {0, 1, 1}k, {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}}], {i, 1, 5}, {j, 1, 5}, {k, 1, 5}]}]

Properties & Relations  (5)

Parallelogram is the 2D full-dimensional case of Parallelepiped:

Wolfram Language code: Subscript[ℛ, 1] = Parallelogram[{1, 2}, {{3, 4}, {5, 6}}];
Wolfram Language code: Subscript[ℛ, 2] = Parallelepiped[{1, 2}, {{3, 4}, {5, 6}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Rectangle is a 2D Parallelepiped with axis-aligned edges:

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{1, 2}, {3, 5}];
Wolfram Language code: Subscript[ℛ, 2] = Parallelepiped[{1, 2}, {{2, 0}, {0, 3}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Cuboid is a 3D Parallelepiped with axis-aligned edges:

Wolfram Language code: Subscript[ℛ, 1] = Cuboid[{1, 2, 3}, {4, 4, 8}];
Wolfram Language code: Subscript[ℛ, 2] = Parallelepiped[{1, 2, 3}, {{3, 0, 0}, {0, 2, 0}, {0, 0, 5}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Any Parallelepiped is an AffineTransform of a Cuboid:

Wolfram Language code: p = {1, 2, 3}; {v1, v2, v3} = {{1, 0, 0}, {1, 2, 0}, {0, 3, 4}};
Wolfram Language code: Subscript[ℛ, 1] = Parallelepiped[p, {v1, v2, v3}]; Subscript[ℛ, 2] = TransformedRegion[Cuboid[], AffineTransform[{{v1, v2, v3}, p}]];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Hexahedron is a generalization of a 3D Parallelepiped:

Wolfram Language code: p = {1, 2, 3}; {v1, v2, v3} = {{1, 0, 0}, {1, 1, 0}, {0, 1, 1}};
Wolfram Language code: Subscript[ℛ, 1] = Parallelepiped[p, {v1, v2, v3}]; Subscript[ℛ, 2] = Hexahedron[{p, p + v1, p + v1 + v2, p + v2, p + v3, p + v3 + v1, p + v3 + v1 + v2, p + v3 + v2}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Research (2014), Parallelepiped, Wolfram Language function, https://reference.wolfram.com/language/ref/Parallelepiped.html.

Text

Wolfram Research (2014), Parallelepiped, Wolfram Language function, https://reference.wolfram.com/language/ref/Parallelepiped.html.

CMS

Wolfram Language. 2014. "Parallelepiped." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Parallelepiped.html.

APA

Wolfram Language. (2014). Parallelepiped. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Parallelepiped.html

BibTeX

@misc{reference.wolfram_2026_parallelepiped, author="Wolfram Research", title="{Parallelepiped}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/Parallelepiped.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_parallelepiped, organization={Wolfram Research}, title={Parallelepiped}, year={2014}, url={https://reference.wolfram.com/language/ref/Parallelepiped.html}, note=[Accessed: 12-June-2026]}