WOLFRAM

Wolfram Language & System Documentation Center

Parallelogram[p,{v1,v2}]

represents a parallelogram with origin p and directions v1 and v2.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinates  
Regions  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

Parallelogram

Parallelogram[p,{v1,v2}]

represents a parallelogram with origin p and directions v1 and v2.

Details and Options

Examples

open all close all

Basic Examples  (3)

A standard parallelogram:

Wolfram Language code: Graphics[Parallelogram[]]

Different styles applied to a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Compute the Area of a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: Area[ℛ]

Centroid:

Wolfram Language code: RegionCentroid[ℛ]

Scope  (16)

Graphics  (6)

Specification  (2)

A standard parallelogram:

Wolfram Language code: Graphics[Parallelogram[]]

A parallelogram with specified origin and directions:

Wolfram Language code: p = {0, 0}; v1 = {1, 2}; v2 = {1, 0};
Wolfram Language code: ill = {PointSize[Large], Point[p], Arrowheads[Medium], Thick, Arrow[{p, v1}], Arrow[{p, v2}]};
Wolfram Language code: Graphics[{{StandardGray, Parallelogram[p, {v1, v2}]}, ill}, Frame -> True]

Styling  (2)

Color directives specify the face color:

Wolfram Language code: Table[Graphics[{c, Parallelogram[]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], Parallelogram[]}]

Coordinates  (2)

Use Scaled coordinates:

Wolfram Language code: Graphics[Parallelogram[Scaled[{0.1, 0.1}], {Scaled[{0.2, 0.5}], Scaled[{0.6, 0.3}]}], Frame -> True, PlotRange -> {{0, 10}, {0, 10}}]

Use Offset coordinates:

Wolfram Language code: Graphics[Triangle[{Offset[{10, 10}, {0, 0}], Offset[{-10, 10}, {1, 0}], Offset[{10, -10}, {0, 1}]}], Frame -> True]

Regions  (10)

Embedding dimension is the dimension of the space in which the vertices exist:

Wolfram Language code: RegionEmbeddingDimension[Parallelogram[{0, 0}, {{1, 0}, {1, 1}}]]

Geometric dimension is the dimensionality of the region itself:

Wolfram Language code: RegionDimension[Parallelogram[{0, 0}, {{1, 0}, {1, 1}}]]

Point membership test:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {-1, -1}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[ℛ, {x, y}]

Measure and centroid:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: RegionMeasure[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

Distance from a point to a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: RegionDistance[ℛ, {2, 3}]

Visualizing:

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance to a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 2}]

Visualizing:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

Nearest point:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: RegionNearest[ℛ, {3, 4}]

Visualizing:

Wolfram Language code: pts = Table[{1, 1 / 2} + 2{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0, 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A parallelogram is bounded and convex:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: BoundedRegionQ[ℛ]

Compute a bounding box:

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.2, Yellow], Cuboid@@Transpose[rr]}}]

Integrate over a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

Optimize over a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: Minimize[{(x - 1 / 2)^2(y - 1 / 4)^2 + 1, {x, y}∈ℛ}, {x, y}]

Solve equations in a parallelogram:

Wolfram Language code: ℛ = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

Applications  (5)

A rhombus is a parallelogram in which all edges are the same length:

Wolfram Language code: RhombusQ[p_Parallelogram] := Equal@@(Norm[#]& /@ Last[p])
Wolfram Language code: p1 = Parallelogram[{0, 0}, {{1, 0}, {2, 1}}]; p2 = Parallelogram[{0, 0}, {{1, 0}, {2 / Sqrt[5], 1 / Sqrt[5]}}];
Wolfram Language code: RhombusQ[#]& /@ {p1, p2}

Visualize:

Wolfram Language code: {Show[Region[p1], PlotLabel -> "Non ‐ rhombus"], Show[Region[p2], PlotLabel -> "Rhombus"]}

A parallelogram with sides that form right angles is a rectangle:

Wolfram Language code: p = {2, 1}; {v1, v2} = {{1, 2}, {4, -2}}; para = Parallelogram[p, {v1, v2}];
Wolfram Language code: Dot[v1, v2] == 0

Visualize:

Wolfram Language code: Region[para]

Any rectangle can easily be converted to a parallelogram:

Wolfram Language code: RectangleToParallelogram[r_Rectangle] := Parallelogram[First[r], (Last[r] - First[r]) * IdentityMatrix[2]]
Wolfram Language code: r = Rectangle[{2, 3}, {5, 7}]; p = RectangleToParallelogram[r]
Wolfram Language code: {Region[r], Region[p]}

The area of a parallelogram can easily be computed from the direction vectors:

Wolfram Language code: point = {Subscript[x, 0], Subscript[y, 0]}; vecs = {{Subscript[x, 1], Subscript[y, 1]}, {Subscript[x, 2], Subscript[y, 2]}}; para = Parallelogram[point, vecs];

Simply treat the vectors as a matrix and take the absolute value of the determinant:

Wolfram Language code: Abs[Det[vecs]]

Compare with Area:

Wolfram Language code: Area[para]

A Parallelogram can tile the plane:

Wolfram Language code: Graphics[{EdgeForm[Gray], FaceForm[LightBlue], Table[Parallelogram[{1, 0}i + {1, 1}j, {{1, 0}, {1, 1}}], {i, 1, 5}, {j, 1, 5}]}]

Properties & Relations  (6)

Rectangle is a special case of Parallelogram:

Wolfram Language code: Subscript[ℛ, 1] = Rectangle[{0, 0}, {1, 1}]; Subscript[ℛ, 2] = Parallelogram[{0, 0}, {{0, 1}, {1, 0}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Polygon is a generalization of Parallelogram:

Wolfram Language code: Subscript[ℛ, 1] = Polygon[{{0, 0}, {0, 1}, {1, 2}, {1, 1}}]; Subscript[ℛ, 2] = Parallelogram[{0, 0}, {{0, 1}, {1, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Parallelepiped generalizes Parallelogram to any dimension:

Wolfram Language code: Subscript[ℛ, 1] = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}]; Subscript[ℛ, 2] = Parallelepiped[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion can represent any parallelogram:

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[0 ≤ y ≤ 1 && x ≥ y && x ≤ y + 1, {x, y}]; Subscript[ℛ, 2] = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion can represent any parallelogram:

Wolfram Language code: p = {1, 2}; {Subscript[v, 1], Subscript[v, 2]} = {{1, 0}, {1, 1}}; Subscript[ℛ, 1] = ParametricRegion[{p + Subscript[t, 1]Subscript[v, 1] + Subscript[t, 2]Subscript[v, 2], 0 ≤ Subscript[t, 1] ≤ 1 && 0 ≤ Subscript[t, 2] ≤ 1}, {Subscript[t, 1], Subscript[t, 2]}]; Subscript[ℛ, 2] = Parallelogram[p, {Subscript[v, 1], Subscript[v, 2]}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A parallelogram can be represented as the union of two triangles:

Wolfram Language code: Subscript[ℛ, 1] = Parallelogram[{0, 0}, {{1, 0}, {1, 1}}]; Subscript[ℛ, 2] = RegionUnion[Triangle[{{0, 0}, {1, 0}, {2, 1}}], Triangle[{{2, 1}, {1, 1}, {0, 0}}]];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]
Wolfram Research (2014), Parallelogram, Wolfram Language function, https://reference.wolfram.com/language/ref/Parallelogram.html (updated 2019).

Text

Wolfram Research (2014), Parallelogram, Wolfram Language function, https://reference.wolfram.com/language/ref/Parallelogram.html (updated 2019).

CMS

Wolfram Language. 2014. "Parallelogram." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/Parallelogram.html.

APA

Wolfram Language. (2014). Parallelogram. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Parallelogram.html

BibTeX

@misc{reference.wolfram_2026_parallelogram, author="Wolfram Research", title="{Parallelogram}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Parallelogram.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_parallelogram, organization={Wolfram Research}, title={Parallelogram}, year={2019}, url={https://reference.wolfram.com/language/ref/Parallelogram.html}, note=[Accessed: 12-June-2026]}