Wolfram Language & System Documentation Center

PascalBinomial

PascalBinomial[n,m]

gives the binomial coefficient that preserves Pascal's identity.

Details

Integer mathematical function, suitable for both symbolic and numerical manipulation.
PascalBinomial is also known as combinations and as choose function.
PascalBinomial gives the asymmetric coefficients that preserve Pascal's identity for all integer values. Use Binomial for coefficients that are symmetric for negative integer . PascalBinomial and Binomial agree except for negative integer .
In general, is defined by or suitable limits of this.
When is a negative integer, . »
The particular limit chosen preserves Pascal's identity for all complex and . »
The symmetry rule is satisfied for all and most but violated for negative integer . »
For integer arguments, PascalBinomial automatically evaluates to exact values.
PascalBinomial is automatically evaluated symbolically for simple cases; FunctionExpand gives results for other cases. »
PascalBinomial can be evaluated to arbitrary numerical precision.
PascalBinomial automatically threads over lists.
PascalBinomial can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples (5)

Evaluate numerically:

Wolfram Language code: PascalBinomial[10, 3]

Evaluate symbolically:

Wolfram Language code: Binomial[n, 3]

Construct Pascal's triangle:

Wolfram Language code: Column[Table[PascalBinomial[n, k], {n, 0, 5}, {k, 0, n}], Center]

Plot over a subset of the reals as a function of its first parameter:

Wolfram Language code: Plot[PascalBinomial[x, 3], {x, -2, 4}]

Plot over a subset of the reals as a function of its second parameter:

Wolfram Language code: Plot[PascalBinomial[3, x], {x, -2, 4}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[PascalBinomial[z, 1 / 5], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Scope (36)

Numerical Evaluation (7)

Evaluate numerically:

Wolfram Language code: PascalBinomial[8, 4]

Wolfram Language code: PascalBinomial[8.5, -4.2]

Evaluate for half-integer arguments:

Wolfram Language code: PascalBinomial[9 / 2, 7 / 2]

Evaluate to high precision:

Wolfram Language code: N[PascalBinomial[7 / 3, 1 / 5], 20]

The precision of the output tracks the precision of the input:

Wolfram Language code: PascalBinomial[8.2211111111115000000, 4]

Complex number inputs:

Wolfram Language code: PascalBinomial[1 + I, 5]

Wolfram Language code: PascalBinomial[2. + I, 7 - 3I]

Evaluate efficiently at high precision:

Wolfram Language code: PascalBinomial[17 / 2, -4.2`100]//Timing

Wolfram Language code: PascalBinomial[-88889 + (1/2), 4.2`1000];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: PascalBinomial[1 / 2, Interval[{0.5, 0.6}]]

Wolfram Language code: PascalBinomial[1, CenteredInterval[1 / 2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: PascalBinomial[Around[2, 0.01], 2]

Compute the elementwise values of an array:

Wolfram Language code: PascalBinomial[ {{5π / 6, 0}, {3π / 2, -π / 2}}, 2]

Or compute the matrix PascalBinomial function using MatrixFunction:

Wolfram Language code: MatrixFunction[PascalBinomial[#, 2]&, {{5π / 6, 0}, {3π / 2, -π / 2}}]

Specific Values (5)

Values of PascalBinomial at particular points:

Wolfram Language code: Table[PascalBinomial[n, 2], {n, 1, 5}]

PascalBinomial for symbolic n:

Wolfram Language code: PascalBinomial[n, 4]

Values at zero:

Wolfram Language code: PascalBinomial[n, 0]

Wolfram Language code: FunctionExpand[PascalBinomial[0, m]]

Note that this is zero on all integers away from :

Wolfram Language code: Simplify[%, m∈ℤ && m != 0]

PascalBinomial[n,m] is zero whenever n and m are both negative integers:

Wolfram Language code: FunctionExpand[PascalBinomial[n, m], n∈NegativeIntegers && m∈NegativeIntegers]

Find a value of n for which PascalBinomial[n,2]=15:

Wolfram Language code: nval = n /. FindRoot[PascalBinomial[ n , 2] == 15, {n, 5}]

Wolfram Language code:

Plot[PascalBinomial[n, 2], {n, 0, 10}, Epilog -> Style[Point[{nval, PascalBinomial[nval, 2]}], PointSize[Large], StandardMagenta]]

Visualization (3)

Plot the PascalBinomial as a function of its parameter n:

Wolfram Language code: Plot[{PascalBinomial[n, 1], PascalBinomial[n, 2], PascalBinomial[n, 3], PascalBinomial[n, 4]}, {n, -2, 4}]

Plot the PascalBinomial as a function of its parameter :

Wolfram Language code: Plot[{PascalBinomial[1, m], PascalBinomial[2, m], PascalBinomial[3, m], PascalBinomial[4, m]}, {m, -1, 5}]

Plot the real part of :

Wolfram Language code: ComplexContourPlot[Re[PascalBinomial[z, 5]], {z, -4 - 4I, 8 + 4I}, Contours -> 24]

Plot the imaginary part of :

Wolfram Language code: ComplexContourPlot[Im[PascalBinomial[z, 5]], {z, -4 - 4I, 8 + 4I}, Contours -> 24]

Function Properties (12)

Real domain of PascalBinomial as a function of its parameter n:

Wolfram Language code: FunctionDomain[PascalBinomial[n, 2], n]

Real domain of PascalBinomial as a function of its parameter m:

Wolfram Language code: FunctionDomain[PascalBinomial[2, m], m]

Complex domain:

Wolfram Language code: FunctionDomain[PascalBinomial[z, 2], z, Complexes]

Wolfram Language code: FunctionDomain[PascalBinomial[2, z], z, Complexes]

Function range of PascalBinomial:

Wolfram Language code: FunctionRange[PascalBinomial[x, 2], x, y]

PascalBinomial has the mirror property :

Wolfram Language code: FullSimplify[PascalBinomial[Conjugate[z], 2] == Conjugate[PascalBinomial[z, 2]]]

Compute sums involving PascalBinomial:

Wolfram Language code: Sum[PascalBinomial[n, k], {k, 0, n}]

Wolfram Language code: Sum[PascalBinomial[n, k] ^ 2, {k, 0, n}]

When is positive, is an analytic function of both variables:

Wolfram Language code: FunctionAnalytic[{PascalBinomial[x, y], x > 0}, {x, y}]

This is not true for negative :

Wolfram Language code: FunctionAnalytic[{PascalBinomial[x, y], x < 0}, {x, y}]

is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[PascalBinomial[x, 7], x]

is not injective:

Wolfram Language code: FunctionInjective[PascalBinomial[x, 7], x]

Wolfram Language code: Plot[{PascalBinomial[x, 7], .01}, {x, -2, 3}]

is surjective:

Wolfram Language code: FunctionSurjective[PascalBinomial[x, 7], x]

Wolfram Language code: Plot[{PascalBinomial[x, 7], 750}, {x, -10, 15}]

PascalBinomial is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[PascalBinomial[x, 1], x]

Wolfram Language code: FunctionSign[PascalBinomial[1, x], x]

has singularities and discontinuities where is a negative integer:

Wolfram Language code: FunctionSingularities[PascalBinomial[x, y], x]

Wolfram Language code: FunctionDiscontinuities[PascalBinomial[x, y], x]

is neither convex nor concave:

Wolfram Language code: FunctionConvexity[PascalBinomial[x, 7], x]

TraditionalForm formatting:

Wolfram Language code: PascalBinomial[n, k]//TraditionalForm

Differentiation (3)

First derivative with respect to :

Wolfram Language code: D[PascalBinomial[n, m], m]

Higher derivatives with respect to :

Wolfram Language code: Table[D[PascalBinomial[n, m], {m, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to for :

Wolfram Language code: Plot[Evaluate[% /. n -> 2], {m, -5, 5}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

First derivative with respect to :

Wolfram Language code: D[PascalBinomial[n, m], n]

Series Expansions (4)

Find the Taylor expansion using Series:

Wolfram Language code: Series[PascalBinomial[n, x], {x, 0, 3}]//Normal//FullSimplify

Plots of the first three approximations around :

Wolfram Language code:

terms = Normal@Table[Series[PascalBinomial[2, x], {x, 0, m}], {m, 1, 5, 2}];
Plot[{PascalBinomial[2, x], terms}, {x, -5, 5}]

Find the series expansion at Infinity:

Wolfram Language code: FullSimplify[Series[PascalBinomial[n, x], {x, Infinity, 1}]//Normal, x > n]

Find series expansion for an arbitrary symbolic direction :

Wolfram Language code: Series[PascalBinomial[2, x], {x, DirectedInfinity[z], 1}, Assumptions -> x > 0 ]//Normal// FullSimplify

Taylor expansion at a generic point:

Wolfram Language code: Series[PascalBinomial[n, x], {x, x0, 2}]// Normal//FullSimplify

Function Identities and Simplifications (2)

Functional identity:

Wolfram Language code: PascalBinomial[n, k] == (k + 1/n - k) PascalBinomial[n, k + 1]//FullSimplify

Recurrence relations:

Wolfram Language code: PascalBinomial[n, k] == (n/n - k) PascalBinomial[n - 1, k]//FullSimplify

Wolfram Language code: PascalBinomial[n, k] == (n - k + 1/n + 1) PascalBinomial[n + 1, k]//FullSimplify

Applications (9)

There are ways to choose elements without replacements from a set of elements:

Wolfram Language code: With[{n = 5, m = 2}, PascalBinomial[n, m]]

Check with direct enumeration:

Wolfram Language code: With[{n = 5, m = 2}, Subsets[Range[n], {m}]]

Wolfram Language code: Length[%]

There are ways to choose elements with replacement from a set of elements:

Wolfram Language code: With[{n = 5, m = 2}, PascalBinomial[n + m - 1, m]]

Check with direct enumeration:

Wolfram Language code: With[{n = 5, m = 2}, DeleteDuplicates[Sort /@ Tuples[Range[n], {m}]]]

Wolfram Language code: Length[%]

There are ways to arrange indistinguishable objects of one kind and indistinguishable objects of another kind:

Wolfram Language code: With[{n = 5, m = 2}, PascalBinomial[n + m, m]]

Wolfram Language code: With[{n = 5, m = 2}, Permutations[Join[ConstantArray[0, n], ConstantArray[1, m]]]]

Wolfram Language code: Length[%]

Illustrate the binomial theorem:

Wolfram Language code: Sum[PascalBinomial[n, k]x ^ k, {k, 0, n}]

Wolfram Language code: Expand[(1 + x) ^ 10]

Fractional binomial theorem:

Wolfram Language code: Series[(1 + x) ^ (1 / 3), {x, 0, 5}]

Wolfram Language code: Sum[PascalBinomial[1 / 3, k]x ^ k, {k, 0, 5}]

Binomial coefficients mod 2:

Wolfram Language code: ArrayPlot[Table[Mod[PascalBinomial[i, j], 2], {i, 50}, {j, i}], PlotTheme -> "Scientific"]

Plot PascalBinomial in the arguments' plane:

Wolfram Language code: Plot3D[PascalBinomial[n, k], {n, -10, 10}, {k, -10, 10}]

Plot the logarithm of the number of ways to pick elements out of :

Wolfram Language code: Plot3D[Log[PascalBinomial[n, k]], {n, 1, 12}, {k, 1, 12}, RegionFunction -> (#2 <= #1&)]

Compute higher derivatives of a product of two functions:

Wolfram Language code: Sum[PascalBinomial[4, k] D[f[z], {z, k}]D[g[z], {z, 4 - k}], {k, 0, 4}]

Wolfram Language code: D[f[z] g[z], {z, 4}]

Properties & Relations (8)

On the integers, PascalBinomial[n,m] equals :

Wolfram Language code:

And@@Flatten@Table[PascalBinomial[n, m] == Underscript[, νUnderscript[ -> , ℂ]n](Underscript[, μUnderscript[ -> , ℂ]m](Gamma[ν + 1]/Gamma[μ + 1] Gamma[-μ + ν + 1])), {n, -5, 5}, {m, -5, 5}]

This can be expressed as $(-1)^m TemplateBox[{{-, n}, m}, Pochhammer]/m!$ for and otherwise:

Wolfram Language code:

And@@Flatten@Table[PascalBinomial[``n``, ``m``] == Piecewise[{{((-1)^m*Pochhammer[-n, m])/m!, m >= 0}, {0, m <= n}}], {n, 5, -5, -1}, {m, 5, -5, -1}]

An alternative formula on the integers:

Wolfram Language code: Assuming[{n, m}∈ℤ, FullSimplify@FunctionExpand[PascalBinomial[n, m]]]

Pascal's identity is satisfied everywhere:

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n - 1, m] + PascalBinomial[n - 1, m - 1]]

In particular, it is true at the origin:

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n - 1, m] + PascalBinomial[n - 1, m - 1], n == 0 && m == 0]

The symmetry rule may not hold for negative integer :

Wolfram Language code: FullSimplify[PascalBinomial[n, m] == PascalBinomial[n, n - m], n∈NegativeIntegers && m∈ℤ]

It may hold for some values but will generally be violated for positive integer :

Wolfram Language code: PascalBinomial[n, m] == PascalBinomial[n, n - m] /. {{n -> -3, m -> 1}, {n -> -3, m -> -1}}

Binomial satisfies the symmetry rule everywhere:

Wolfram Language code: FullSimplify[Binomial[n, m] == Binomial[n, n - m]]

PascalBinomial performs simple evaluations for symbolic arguments:

Wolfram Language code: PascalBinomial[n, 2]

PascalBinomial typically does not evaluate when both arguments are symbolic:

Wolfram Language code: PascalBinomial[n + 1, n]

Use FunctionExpand with conditions to achieve appropriate simplifications:

Wolfram Language code: FunctionExpand[PascalBinomial[n + 1, n], n∈Integers]

PascalBinomial[n,m] is 0 whenever n and m are both negative integers:

Wolfram Language code: FunctionExpand[PascalBinomial[n, m], n∈NegativeIntegers && m∈NegativeIntegers]

Use FullSimplify to simplify expressions involving binomial coefficients:

Wolfram Language code: FullSimplify[PascalBinomial[n + 1, k + 1] / PascalBinomial[n, k]]

Use FunctionExpand to expand into Gamma functions:

Wolfram Language code: FunctionExpand[PascalBinomial[n, k]]

Sums involving PascalBinomial:

Wolfram Language code: Underoverscript[∑, k = 0, n](-1)^kPascalBinomial[n, k]

Wolfram Language code: Underoverscript[∑, k = 0, ∞]PascalBinomial[n, k] k

Wolfram Language code: Underoverscript[∑, k = 1, ∞](1/PascalBinomial[2 k, k])

Neat Examples (7)

Construct a graphical version of Pascal's triangle:

Wolfram Language code:

With[{n = 8}, 
Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, 0, n - 1}, {j, 0, i}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - i / 2 + j, -i}}, VertexLabels -> {b[i_, j_] :> Placed[PascalBinomial[i, j], Center]}, IconizedObject[«Style options»]]]

Extend the triangle to negative integers; unlabeled points indicate a zero value:

Wolfram Language code:

With[{n = 6}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, n - 1, -n - 1, -1}, {j, -n + i UnitStep[i] - UnitStep[-1 - i], n + i UnitStep[-i] + UnitStep[-1 - i]}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - (i/2) + j, -i}}, IconizedObject[«Style options»]]]

Binomial, by contrast, defines the top-left sector by reflecting the top-right sector:

Wolfram Language code:

With[{n = 6}, Graph[Flatten[Table[{b[i, j] <-> b[i + 1, j], b[i, j] <-> b[i + 1, j + 1], b[i + 1, j] <-> b[i + 1, j + 1]}, {i, n - 1, -n - 1, -1}, {j, -n + i UnitStep[i] - UnitStep[-1 - i], n + i UnitStep[-i] + UnitStep[-1 - i]}]], VertexCoordinates -> {b[i_, j_] :> {(n + 1/2) - (i/2) + j, -i}}, IconizedObject[«Style options»]]]

Binomial coefficient mod :

Wolfram Language code: ArrayPlot[Table[Mod[PascalBinomial[i, j], Pi], {i, 50}, {j, i}], PlotTheme -> "Scientific"]

Closed‐form inverse of Hilbert matrices:

Wolfram Language code:

Block[{n = 4}, Table[(-1) ^ (i + j)(i + j - 1)PascalBinomial[n + i - 1, n - j]PascalBinomial[n + j - 1, n - i]PascalBinomial[i + j - 2, i - 1] ^ 2, {i, n}, {j, n}]]//MatrixForm

Wolfram Language code: Inverse[%]

Nested binomials over the complex plane:

Wolfram Language code:

DensityPlot[Arg[Nest[PascalBinomial[#, # / 2]&, x + I y, 3]], {x, -1, -0.9}, {y, -0.06, 0.06}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

Plot PascalBinomial at infinity:

Wolfram Language code:

DensityPlot[Arg[PascalBinomial[(x + I y), 1 / (x + I y)]], {x, -1 / 2, 1 / 2}, {y, -1 / 2, 1 / 2}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

Plot PascalBinomial for complex arguments:

Wolfram Language code:

DensityPlot[Arg[PascalBinomial[4.1 Exp[I ϕ1], 2.2 Exp[I ϕ2]]], {ϕ1, -Pi, Pi}, {ϕ2, -Pi, Pi}, Exclusions -> {}, MaxRecursion -> 4, PlotPoints -> 50]

Plot PascalBinomial at Gaussian integers:

Wolfram Language code:

Block[{$MaxExtraPrecision = 1000}, ArrayPlot[Table[Mod[Im@Round[PascalBinomial[x  + I y, x ]], 2], {x, 0, 50}, {y, -25, 25}], PlotTheme -> "Scientific"]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

PascalBinomial

Details

Examples

Basic Examples (5)

Scope (36)

Numerical Evaluation (7)

Specific Values (5)

Visualization (3)

Function Properties (12)

Differentiation (3)

Series Expansions (4)

Function Identities and Simplifications (2)

Applications (9)

Properties & Relations (8)

Neat Examples (7)

Text

CMS

APA

BibTeX

BibLaTeX

PascalBinomial

Details

Examples

Basic Examples (5)

Scope (36)

Numerical Evaluation (7)

Specific Values (5)

Visualization (3)

Function Properties (12)

Differentiation (3)

Series Expansions (4)

Function Identities and Simplifications (2)

Applications (9)

Properties & Relations (8)

Neat Examples (7)

See Also

History

Text

CMS

APA

BibTeX

BibLaTeX