WOLFRAM

Wolfram Language & System Documentation Center

PauliMatrix[k]

gives the k^(th) Pauli spin matrix .

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
TargetStructure  
WorkingPrecision  
Applications  
See Also
Related Guides
History
Cite this Page

PauliMatrix

PauliMatrix[k]

gives the k^(th) Pauli spin matrix .

Details and Options

  • PauliMatrix gives 2×2 constant matrices with the property .
  • PauliMatrix[0] and PauliMatrix[4] give the identity matrix.
  • The following options can be given:
  • TargetStructure Automaticthe structure of the returned matrix
    WorkingPrecision Infinityprecision at which to create entries
  • Possible settings for TargetStructure include:
  • Automaticautomatically choose the representation returned
    "Dense"represent the matrix as a dense matrix
    "Hermitian"represent the matrix as a Hermitian matrix
    "Sparse"represent the matrix as a sparse array
    "Unitary"represent the matrix as a unitary matrix
  • With the setting TargetStructureAutomatic, a dense matrix is returned.

Examples

open all close all

Basic Examples  (1)

Generate Pauli matrices:

Wolfram Language code: Table[PauliMatrix[k]//MatrixForm, {k, 3}]

Scope  (1)

PauliMatrix threads element-wise over lists:

Wolfram Language code: PauliMatrix[Range[3]]

Options  (6)

TargetStructure  (4)

Return the Pauli matrix as a dense matrix:

Wolfram Language code: PauliMatrix[3, TargetStructure -> "Dense"]

Return the Pauli matrix as a sparse array:

Wolfram Language code: PauliMatrix[3, TargetStructure -> "Sparse"]

Return the Pauli matrix as a Hermitian matrix:

Wolfram Language code: PauliMatrix[3, TargetStructure -> "Hermitian"]

Return the Pauli matrix as a unitary matrix:

Wolfram Language code: PauliMatrix[3, TargetStructure -> "Unitary"]

WorkingPrecision  (2)

Create a machine-precision Pauli matrix:

Wolfram Language code: PauliMatrix[3, WorkingPrecision -> MachinePrecision]

Create an arbitrary-precision Pauli matrix:

Wolfram Language code: PauliMatrix[3, WorkingPrecision -> 24]

Applications  (4)

Pauli's differential equation:

Wolfram Language code: Sum[PauliMatrix[k].(D[#, Subscript[x, k]]) , {k, 0, 3}]&[ {f[Subscript[x, 0], Subscript[x, 1]], g[Subscript[x, 0], Subscript[x, 1]]}]

Pauli matrices' algebra:

Wolfram Language code: Table[PauliMatrix[n].PauliMatrix[n]//MatrixForm, {n, 3}]
Wolfram Language code: PauliMatrix[1].PauliMatrix[2] == I PauliMatrix[3]

Build a unitary matrix representing the rotation of the spinor around the axis through angle :

Wolfram Language code: MatrixExp[I (ϕ/2)PauliMatrix[3]]

Rotation by 360° changes the spinor's direction:

Wolfram Language code: % /. ϕ -> 2π

In quantum mechanics, systems with finitely many states are represented by unit vectors and physical quantities by matrices that act on them. Consider a spin-1/2 particle such as an electron in the following state:

Wolfram Language code: s = {(1/Sqrt[5]), (2I/Sqrt[5])};

The operator for the component of angular momentum is given by the following matrix:

Wolfram Language code: jz = (ℏ/2)PauliMatrix[3]

Compute the expected angular momentum in this state as :

Wolfram Language code: Conjugate[s].jz.s

The uncertainty in the angular momentum is :

Wolfram Language code: σz = Simplify[Sqrt[Conjugate[s].jz.jz.s - (Conjugate[s].jz.s)^2], ℏ > 0]

The uncertainty in the component of angular momentum is computed analogously:

Wolfram Language code: jy = (ℏ/2)PauliMatrix[2]
Wolfram Language code: σy = Simplify[Sqrt[Conjugate[s].jy.jy.s - (Conjugate[s].jy.s)^2], ℏ > 0]

The uncertainty principle gives a lower bound on the product of uncertainties, :

Wolfram Language code: Simplify[σy σz > (ℏ/2)Abs[ Conjugate[s].(jy.jz - jz.jy).s] , ℏ > 0]
Wolfram Research (2008), PauliMatrix, Wolfram Language function, https://reference.wolfram.com/language/ref/PauliMatrix.html (updated 2024).

Text

Wolfram Research (2008), PauliMatrix, Wolfram Language function, https://reference.wolfram.com/language/ref/PauliMatrix.html (updated 2024).

CMS

Wolfram Language. 2008. "PauliMatrix." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/PauliMatrix.html.

APA

Wolfram Language. (2008). PauliMatrix. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PauliMatrix.html

BibTeX

@misc{reference.wolfram_2026_paulimatrix, author="Wolfram Research", title="{PauliMatrix}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/PauliMatrix.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_paulimatrix, organization={Wolfram Research}, title={PauliMatrix}, year={2024}, url={https://reference.wolfram.com/language/ref/PauliMatrix.html}, note=[Accessed: 12-June-2026]}