WOLFRAM

Wolfram Language & System Documentation Center

Piecewise[{{val1,cond1},{val2,cond2},…}]

represents a piecewise function with values vali in the regions defined by the conditions condi.

Piecewise[{{val1,cond1},…},val]

uses default value val if none of the condi apply. The default for val is 0.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

Piecewise

Piecewise[{{val1,cond1},{val2,cond2},…}]

represents a piecewise function with values vali in the regions defined by the conditions condi.

Piecewise[{{val1,cond1},…},val]

uses default value val if none of the condi apply. The default for val is 0.

Details

  • The condi are typically inequalities such as .
  • The condi are evaluated in turn, until one of them is found to yield True.
  • If all preceding condi yield False, then the vali corresponding to the first condi that yields True is returned as the value of the piecewise function.
  • If any of the preceding condi do not literally yield False, the Piecewise function is returned in symbolic form.
  • Only those vali explicitly included in the returned form are evaluated.
  • Elements of the form {vali,False} are dropped, as are all elements after the first {vali,True}.
  • Piecewise[conds] automatically evaluates to Piecewise[conds,0].
  • Piecewise can be used in such functions as Integrate, Minimize, Reduce, DSolve, and Simplify, as well as their numeric analogs.
  • Piecewise[{{v1,c1},{v2,c2},…}] can be input in the form
    v1c1
    v2c2
    …
    . The piecewise operator can be entered as pw or \[Piecewise]. The grid of values and conditions can be constructed by first entering , then using and .
  • In StandardForm and TraditionalForm, Piecewise[{{v1,c1},{v2,c2},…}] is normally output using a brace, as in
    v1c1
    v2c2
    …
    .

Examples

open all close all

Basic Examples  (3)

Set up a piecewise function with different pieces below and above zero:

Wolfram Language code: Plot[Piecewise[{{x ^ 2, x < 0}, {x, x > 0}}], {x, -2, 2}]

Find the derivative of a piecewise function:

Wolfram Language code: D[Piecewise[{{x ^ 2, x < 0}, {x, x > 0}}], x]

Use pw to enter and and then TemplateBox[{ctrl, return}, Key1, BaseStyle -> {ExampleText, FontWeight -> Plain, FontFamily -> Source Sans Pro}] for each additional piecewise case:

Wolfram Language code: | | | | -- | -- | | v1 | d1 | | v2 | d2 | | v3 | d3 |//InputForm

Scope  (12)

Define a piecewise function:

Wolfram Language code: pw = Piecewise[{{Sin[x] / x, x < 0}, {1, x == 0}}, -x ^ 2 / 100 + 1]

Evaluate it at specific points:

Wolfram Language code: pw /. {{x -> -5}, {x -> 0}, {x -> 5}}

Plot it:

Wolfram Language code: Plot[pw, {x, -10, 10}]

Refine it under assumptions:

Wolfram Language code: Refine[pw, x < -2]

Automatic simplification of Piecewise functions:

Wolfram Language code: Piecewise[{{e1, True}, {e2, d2}, {e3, d3}}, e]

Remove unreachable cases:

Wolfram Language code: Piecewise[{{e1, d1}, {e2, d2}, {e3, True}, {e4, d4}, {e5, d5}}, e]
Wolfram Language code: Piecewise[{{e1, d1}, {e2, d2}, {e3, d2 && d3}, {e4, d4}}, e]

Remove False conditions:

Wolfram Language code: Piecewise[{{e1, d1}, {e2, d2}, {e3, False}, {e4, d4}, {e5, d5}}, e]

Merge cases with the same values:

Wolfram Language code: Piecewise[{{e1, d1}, {e23, d2}, {e23, d3}, {e4, d4}}, e]

If values are not specified in a region, they are assumed to be zero:

Wolfram Language code: Plot[Piecewise[{{Sqrt[x], x > 0}}], {x, -2, 2}]

This specifies that the default value should be 1:

Wolfram Language code: Plot[Piecewise[{{Sqrt[x], x > 0}}, 1], {x, -2, 2}]

Compute limits of piecewise functions:

Wolfram Language code: pw = Piecewise[{{1, Abs[z] ≤ 1}}];
Wolfram Language code: Limit[pw, z -> I]

Compute the limit in the direction of the positive imaginary axis:

Wolfram Language code: Limit[pw, z -> I, Direction -> I]

Compute the series of a piecewise function:

Wolfram Language code: Series[Piecewise[{{Cos[x], x ≤ 0}}, E ^ x], {x, a, 2}]

Integrate a piecewise function:

Wolfram Language code: int = Integrate[Piecewise[{{E ^ x, x ^ 2 ≤ 1}}, Sin[x]], x]

Integration constants are chosen to make the result continuous:

Wolfram Language code: Plot[int, {x, -2, 2}]

Compute a definite integral of a piecewise function:

Wolfram Language code: Integrate[Piecewise[{{1, x ^ 2 + y ^ 2 < 1}}], {x, -∞, ∞}, {y, -∞, ∞}]

Laplace transform of a piecewise function:

Wolfram Language code: LaplaceTransform[Piecewise[{{Sqrt[t], t > 0}}], t, s]

Solve a piecewise differential equation:

Wolfram Language code: DSolve[x''[t] + x[t] == Piecewise[{{Sqrt[t], t > 0}}], x[t], t]

Reduce a piecewise equation:

Wolfram Language code: Reduce[x ^ 2 + Piecewise[{{x, 0 < x < 1}, {x ^ 3, 1 < x < 2}}] == 1, x]
Wolfram Language code: Plot[x ^ 2 + Piecewise[{{x, 0 < x < 1}, {x ^ 3, 1 < x < 2}}], {x, -3, 3}]

Integrating an implicitly piecewise integrand can give an explicit Piecewise result:

Wolfram Language code: Integrate[Max[x, x ^ 2, x ^ 3], x]

Symbolic minimization can give piecewise functions:

Wolfram Language code: Minimize[a x ^ 2 + b, x]

Applications  (1)

Compute the volume of an ellipsoid:

Wolfram Language code: Integrate[Piecewise[{{1, x ^ 2 / a ^ 2 + y ^ 2 / b ^ 2 + z ^ 2 / c ^ 2 ≤ 1}}], {x, -∞, ∞}, {y, -∞, ∞}, {z, -∞, ∞}, Assumptions -> a > 0 && b > 0 && c > 0]

Properties & Relations  (11)

PiecewiseExpand converts nested piecewise functions into a single piecewise function:

Wolfram Language code: pw = Piecewise[{{Piecewise[{{1, x ≥ 0}}, 2], Piecewise[{{x, x ≤ 1}}, x / 2] ^ 2 ≥ 1 / 2}}, 3]
Wolfram Language code: PiecewiseExpand[pw]

Min, Max, UnitStep, and Clip are piecewise functions of real arguments:

Wolfram Language code: PiecewiseExpand /@ {Min[x, y], Max[x, y, z], UnitStep[x], Clip[x, {a, b}]}

Abs, Sign, and Arg are piecewise functions when their arguments are assumed to be real:

Wolfram Language code: Assuming[Element[x, Reals], PiecewiseExpand /@ {Abs[x], Sign[x], Arg[x]}]

KroneckerDelta and DiscreteDelta are piecewise functions of complex arguments:

Wolfram Language code: PiecewiseExpand /@ {KroneckerDelta[x, y], DiscreteDelta[x, y]}

Boole is a piecewise function of a Boolean argument:

Wolfram Language code: PiecewiseExpand[Boole[a]]

If, Which, and Switch can be interpreted as piecewise functions:

Wolfram Language code: PiecewiseExpand /@ {If[a, x, y], Which[a, x, b, y, c, z], Switch[u, v, x, w, y]}

Convert Floor, Ceiling, Round, IntegerPart, and FractionalPart for finite ranges:

Wolfram Language code: Assuming[{0 ≤ x ≤ 3}, PiecewiseExpand /@ {Floor[x], Ceiling[x], Round[x], IntegerPart[x], FractionalPart[x]}]

Convert Mod and Quotient when the number of cases is finite:

Wolfram Language code: Assuming[0 ≤ k ≤ 3m, PiecewiseExpand /@ {Mod[k, m], Quotient[k, m]}]

UnitBox and UnitTriangle are piecewise functions of real arguments:

Wolfram Language code: PiecewiseExpand /@ {UnitBox[x], UnitTriangle[x]}

Convert SquareWave, TriangleWave, and SawtoothWave for finite ranges:

Wolfram Language code: Assuming[{0 ≤ x ≤ 3}, PiecewiseExpand /@ {SquareWave[x], TriangleWave[x], SawtoothWave[x]}]

BernsteinBasis and BSplineBasis are piecewise functions of real arguments:

Wolfram Language code: PiecewiseExpand /@ {BernsteinBasis[3, 2, x], BSplineBasis[3, 2, x]}

Possible Issues  (1)

Derivatives are computed piece-by-piece, unless the function is univariate in a real variable:

Wolfram Language code: D[Piecewise[{{(x ^ 2 - 1) / (x - 1), x ≠ 1}}, 2], x]

To specify that is real, use inequalities in the first condition:

Wolfram Language code: D[Piecewise[{{(x ^ 2 - 1) / (x - 1), x < 1 || x > 1}}, 2], x]

This function is discontinuous at :

Wolfram Language code: D[Piecewise[{{(x ^ 2 - 1) / (x - 1), x < 1 || x > 1}}, 1], x]
Wolfram Research (2004), Piecewise, Wolfram Language function, https://reference.wolfram.com/language/ref/Piecewise.html (updated 2008).

Text

Wolfram Research (2004), Piecewise, Wolfram Language function, https://reference.wolfram.com/language/ref/Piecewise.html (updated 2008).

CMS

Wolfram Language. 2004. "Piecewise." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/Piecewise.html.

APA

Wolfram Language. (2004). Piecewise. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Piecewise.html

BibTeX

@misc{reference.wolfram_2026_piecewise, author="Wolfram Research", title="{Piecewise}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/Piecewise.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_piecewise, organization={Wolfram Research}, title={Piecewise}, year={2008}, url={https://reference.wolfram.com/language/ref/Piecewise.html}, note=[Accessed: 13-June-2026]}