WOLFRAM

Wolfram Language & System Documentation Center

PolarGridLines

is an option for sector charts and polar plots that specifies polar grid lines.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
PolarGridLines Positions  
PolarGridLines Styling  
Generalizations & Extensions  
See Also
Related Guides
History
Cite this Page

PolarGridLines

PolarGridLines

is an option for sector charts and polar plots that specifies polar grid lines.

Details

  • Polar grid lines can be both radial and angular.
  • The following settings can be given for PolarGridLines:
  • Noneno grid lines drawn
    Automaticgrid lines placed automatically
    {radial,angular}grid lines specified separately in each direction
  • With the Automatic setting, grid lines are usually placed at points whose coordinates have the minimum number of digits in their decimal representation.
  • For each direction, the following grid line options can be given:
  • Noneno grid lines drawn
    Automaticgrid line positions chosen automatically
    {t1,t2,…}grid lines drawn at the specified positions
    {{t1,style1},…}grid lines with specified styles
    funca function to be applied to tmin, tmax to get the grid line option
  • The positions of radial grid lines are specified by angles in radians, measured counterclockwise from the positive axis.
  • Grid line styles can involve any graphics directives, such as RGBColor and Thickness.
  • The grid line function func[tmin,tmax] may return any other grid line option.
  • GridLinesStyle gives default styles to use for grid lines.

Examples

open all close all

Basic Examples  (4)

Use automatically chosen polar grid lines:

Wolfram Language code: SectorChart[RandomReal[1, {20, 2}], PolarGridLines -> Automatic, PolarAxes -> Automatic]

Draw grid lines at the specified positions:

Wolfram Language code: PolarPlot[Cos[θ]Sin[θ], {θ, 0, 2Pi}, PolarAxes -> Automatic, PolarGridLines -> {{0, Pi / 2, Pi, 3Pi / 2}, {0.2, 0.4, 0.6, 0.8}}, PolarTicks -> {"Degrees", Automatic}]

Specify polar grid styles:

Wolfram Language code: PolarPlot[Cos[θ]Sin[θ], {θ, 0, 2Pi}, PolarAxes -> Automatic, PolarGridLines -> {{0, {Pi / 2, Red}, Pi, {3Pi / 2, Directive[Blue, Dashed]}}, {{0.2, Red}, {0.4, Orange}, 0.6, 0.8}}, PolarTicks -> {"Degrees", Automatic}]

Specify overall grid line style, using GridLinesStyle:

Wolfram Language code: SectorChart[RandomReal[1, {10, 2}], PolarAxes -> Automatic, GridLinesStyle -> Directive[Dashed, Orange], PolarGridLines -> Automatic]

Scope  (7)

PolarGridLines Positions  (4)

Place the polar grids automatically:

Wolfram Language code: SectorChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PolarGridLines -> Automatic, PolarAxes -> Automatic]
Wolfram Language code: PolarPlot[Cos[θ]^2Sin[θ]^2, {θ, 0, 2Pi}, PolarAxes -> Automatic, PolarGridLines -> Automatic, PlotRange -> 0.3]

Place grid lines in angular direction:

Wolfram Language code: PolarPlot[Sin[θ]^2, {θ, 0, 2Pi}, PolarAxes -> Automatic, PolarGridLines -> {Automatic, None}, PolarTicks -> {"Degrees", Automatic}]

Place grid lines in radial direction:

Wolfram Language code: PolarPlot[Cos[θ]^2, {θ, 0, 2Pi}, PolarAxes -> Automatic, PolarGridLines -> {None, Automatic}, PlotRange -> 1.2]

For sector charts draw grid lines tangent to sector angles:

Wolfram Language code: SectorChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PolarGridLines -> {"AngularSection", None}, PolarAxes -> Automatic]

For sector charts draw grid lines tangent to sector radius:

Wolfram Language code: SectorChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PolarGridLines -> {None, "RadialSection"}, PolarAxes -> Automatic]

For sector charts draw grid lines tangent to sector boundaries:

Wolfram Language code: SectorChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PolarGridLines -> {"AngularSection", "RadialSection"}, PolarAxes -> Automatic]

PolarGridLines Styling  (3)

Specify the style of each grid line:

Wolfram Language code: ListPolarPlot[Table[Sin[2t]Cos[2t], {t, 0, 2Pi, 0.01}], PolarAxes -> Automatic, PolarGridLines -> {{{Pi / 6, Blue}, {Pi / 3, Red}, 3Pi / 2, {Pi, Dashed}}, {{0.2, Red}, {0.4, Cyan}, {0.6, Red}, 0.8}}, PolarTicks -> {"Degrees", Automatic}]

Specify overall grid line style, using GridLinesStyle:

Wolfram Language code: PolarPlot[Sin[2t]Cos[2t], {t, 0, 2Pi}, PolarGridLines -> Automatic, PolarAxes -> True, GridLinesStyle -> Directive[Dotted, Orange], PlotRange -> 1]

Individually styled polar grid lines can be used with GridLinesStyle, and have higher priority:

Wolfram Language code: PolarPlot[Sin[2t]Cos[2t], {t, 0, 2Pi}, PolarGridLines -> {{{Pi / 6, Dashing[{}]}, {3Pi / 2, Directive[Blue, Thick]}, {Pi, Blue}}, Automatic}, PolarAxes -> True, GridLinesStyle -> Directive[Dotted, Orange], PlotRange -> 1]

Generalizations & Extensions  (1)

Specify a grid function applied to tmin and tmax values in each direction:

Wolfram Language code: grids[min_, max_] := Block[{j = 0}, Table[j++;If[EvenQ[j], {i, Red}, {i, Blue}], {i, min, max, 0.2}]]
Wolfram Language code: SectorChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PolarGridLines -> {grids, Automatic}]
Wolfram Language code: PolarPlot[{1, 1 + 1 / 10 Sin[10t]}, {t, 0, 2Pi}, PolarGridLines -> {Automatic, grids}, Axes -> False]
Wolfram Language code: SectorChart[{{1, 1}, {1, 2}, {2, 3}, {3, 2}}, PolarGridLines -> grids]
Wolfram Research (2008), PolarGridLines, Wolfram Language function, https://reference.wolfram.com/language/ref/PolarGridLines.html.

Text

Wolfram Research (2008), PolarGridLines, Wolfram Language function, https://reference.wolfram.com/language/ref/PolarGridLines.html.

CMS

Wolfram Language. 2008. "PolarGridLines." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/PolarGridLines.html.

APA

Wolfram Language. (2008). PolarGridLines. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/PolarGridLines.html

BibTeX

@misc{reference.wolfram_2026_polargridlines, author="Wolfram Research", title="{PolarGridLines}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/PolarGridLines.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_polargridlines, organization={Wolfram Research}, title={PolarGridLines}, year={2008}, url={https://reference.wolfram.com/language/ref/PolarGridLines.html}, note=[Accessed: 13-June-2026]}