WOLFRAM

Wolfram Language & System Documentation Center

QPolyGamma[z,q]

gives the -digamma function TemplateBox[{z, q}, QPolyGamma].

QPolyGamma[n,z,q]

gives the ^(th) derivative of the -digamma function TemplateBox[{n, z, q}, QPolyGamma3].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Properties & Relations  
See Also
Related Guides
Related Links
History
Cite this Page

QPolyGamma

QPolyGamma[z,q]

gives the -digamma function TemplateBox[{z, q}, QPolyGamma].

QPolyGamma[n,z,q]

gives the ^(th) derivative of the -digamma function TemplateBox[{n, z, q}, QPolyGamma3].

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • TemplateBox[{z, q}, QPolyGamma]=partial_z TemplateBox[{z, q}, QGamma]/TemplateBox[{z, q}, QGamma]⩵-log(1-q)+log(q)sum_(n=0)^inftyq^(n+z)/(1-q^(n+z)).
  • TemplateBox[{n, z, q}, QPolyGamma3]=d^nTemplateBox[{z, q}, QPolyGamma]/d z^n.
  • QPolyGamma automatically threads over lists.

Examples

open all close all

Basic Examples  (6)

Evaluate numerically:

Wolfram Language code: QPolyGamma[2., 3]

Plot over a subset of the reals:

Wolfram Language code: Plot[QPolyGamma[x, 2 / 3], {x, -2, 2}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[QPolyGamma[z, 1 / 2], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[QPolyGamma[x, 1 / 2], {x, 0, 2}]

Series expansion at Infinity:

Wolfram Language code: Series[QPolyGamma[x, 1 / 2], {x, ∞, 2}]//Normal

Series expansion at a singular point:

Wolfram Language code: Series[QPolyGamma[x, 1 / 2], {x, -1, 2}, Assumptions -> x > 0]//FullSimplify

Scope  (26)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: QPolyGamma[.5, 9]
Wolfram Language code: QPolyGamma[0, .9, 5.0]

Evaluate to high precision:

Wolfram Language code: N[QPolyGamma[1, 1 / 7, 1 / 3], 25]

The precision of the output tracks the precision of the input:

Wolfram Language code: QPolyGamma[1, .300000000000000000]

Complex number input:

Wolfram Language code: QPolyGamma[.3 + I, .5 - I]

Evaluate efficiently at high precision:

Wolfram Language code: QPolyGamma[1 / 8, 122`100]//Timing
Wolfram Language code: QPolyGamma[1 / 5, 122`10000];//Timing

Compute average-case statistical intervals using Around:

Wolfram Language code: QPolyGamma[Around[3, 0.01], .5]

Compute the elementwise values of an array:

Wolfram Language code: QPolyGamma[{{3, 2}, {2, 3}}, 1]

Or compute the matrix QPolyGamma function using MatrixFunction:

Wolfram Language code: MatrixFunction[QPolyGamma[#, 1]&, {{3, 2}, {2, 3}}]//FullSimplify

Specific Values  (5)

Evaluate at exact arguments:

Wolfram Language code: QPolyGamma[2, 2, 1]//FunctionExpand
Wolfram Language code: QPolyGamma[3, 2, 1]//FunctionExpand
Wolfram Language code: QPolyGamma[1, 1]

Evaluate symbolically:

Wolfram Language code: QPolyGamma[2, x, 1]//FunctionExpand

Some singular points of QPolyGamma:

Wolfram Language code: {QPolyGamma[0, 0], QPolyGamma[-1, 1], QPolyGamma[-2, -2]}

Values at infinity:

Wolfram Language code: QPolyGamma[ComplexInfinity, 1]

Find a value of x for which QPolyGamma[x,6]=3:

Wolfram Language code: xval = x /. N@Solve[QPolyGamma[x, 6] == 3 && 1 < x < 5, x, Reals][[1]]//Quiet
Wolfram Language code: Plot[QPolyGamma[x, 6], {x, -2, 4}, Epilog -> Style[Point[{xval, QPolyGamma[xval, 6]}], PointSize[Large], Red]]

Visualization  (3)

Plot the QPolyGamma function:

Wolfram Language code: Plot[QPolyGamma[x, 1 / 2], {x, -2, 2}]

Plot the QPolyGamma as a function of its second parameter q:

Wolfram Language code: Plot[{QPolyGamma[1 / 4, q], QPolyGamma[1 / 3, q], QPolyGamma[1 / 2, q]}, {q, 0, 2}]

Plot the real part of TemplateBox[{0, z, {1, /, 2}}, QPolyGamma3]:

Wolfram Language code: ComplexContourPlot[Re[QPolyGamma[z, 1 / 2]], {z, -2 - 4I, 2 + 4I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{0, z, {1, /, 2}}, QPolyGamma3]:

Wolfram Language code: ComplexContourPlot[Im[QPolyGamma[z, 1 / 2]], {z, -2 - 4I, 2 + 4I}, Contours -> 20]

Function Properties  (7)

The real domain of QPolyGamma:

Wolfram Language code: FunctionDomain[QPolyGamma[n, x, q], {n, x, q}]//FullSimplify

The complex domain:

Wolfram Language code: FunctionDomain[QPolyGamma[n, z, q], {n, z, q}, Complexes]

QPolyGamma threads elementwise over lists:

Wolfram Language code: QPolyGamma[0, {1, 2, 3}, 0.5]

TemplateBox[{x, {2, /, 3}}, QPolyGamma] is neither nonincreasing nor nondecreasing:

Wolfram Language code: FunctionMonotonicity[QPolyGamma[x, 2 / 3], x]

QPochhammer is not injective:

Wolfram Language code: FunctionInjective[QPolyGamma[x, 2 / 3], x]
Wolfram Language code: Plot[{QPolyGamma[x, 2 / 3], 5}, {x, -2, 2}]

QPolyGamma is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[QPolyGamma[x, 2 / 3], x]

QPolyGamma is neither convex nor concave:

Wolfram Language code: FunctionConvexity[QPolyGamma[x, 2 / 3], x]

TraditionalForm formatting:

Wolfram Language code: QPolyGamma[x, q]//HoldForm//TraditionalForm
Wolfram Language code: QPolyGamma[n, x, q]//TraditionalForm

Differentiation  (3)

First derivative with respect to z:

Wolfram Language code: D[QPolyGamma[z, q], z]

Higher derivatives with respect to z:

Wolfram Language code: Table[D[QPolyGamma[z, q], {z, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z when q=3:

Wolfram Language code: Plot[Evaluate[% /. { q -> 3}], {z, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to z:

Wolfram Language code: D[QPolyGamma[z, q], {z, k}]// FullSimplify

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[QPolyGamma[x, q], {x, 0, 3}]//Normal

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[QPolyGamma[x, 1 / 3], {x, 0, m}], {m, 1, 3}]; Plot[{QPolyGamma[x, 1 / 3], terms}, {x, 0, 5}, PlotRange -> {-10, 10}]

The Taylor expansion at a generic point:

Wolfram Language code: Series[QPolyGamma[x, q], {x, x0, 2}]// Normal//FullSimplify

Applications  (3)

Express certain sums in closed form:

Wolfram Language code: Sum[(1/Cosh[k] + 1), {k, 0, Infinity}]

In general, all basic -rational sums can be computed using QPolyGamma:

Wolfram Language code: Sum[(1/(q ^ k - 1)(q ^ k - 2)), k]
Wolfram Language code: Sum[(1/q ^ (3k) + 3 q ^ (2k) + 1), k]

Use DifferenceDelta to verify:

Wolfram Language code: DifferenceDelta[%, k]

Compute an approximation for a finite sum:

Wolfram Language code: AsymptoticSum[1 / (2 ^ k + 1), {k, 0, n}, {n, ∞, 1}]

Compute the numerical approximation for increasing values of n:

Wolfram Language code: Table[%, {n, {5, 10, 300}}]//N[#, 20]&//N//Chop

Compare with the exact results given by Sum:

Wolfram Language code: Table[Sum[1 / (2 ^ k + 1), {k, 0, n}], {n, {5, 10, 300}}]//N[#, 20]&//N//Chop

The Lambert series can be expressed in terms of the -digamma function:

Wolfram Language code: lambert[q_] := (QPolyGamma[1, q] + Log[1 - q]/Log[q])

Verify the identity through series expansion:

Wolfram Language code: With[{n = 14}, Series[lambert[q] - Underoverscript[∑, k = 1, n](q^k/1 - q^k), {q, 0, n}]]

The Lambert series is related to the generating function for the number of divisors:

Wolfram Language code: CoefficientList[Series[lambert[q] / q, {q, 0, 11}], q]
Wolfram Language code: Table[DivisorSigma[0, n], {n, 12}]

Properties & Relations  (2)

Differences of QPolyGamma are -rational functions:

Wolfram Language code: DifferenceDelta[QPolyGamma[0, k, q], k]
Wolfram Language code: FunctionExpand[%]
Wolfram Language code: DifferenceDelta[QPolyGamma[2, k, q], k]//FunctionExpand

Derivatives of QGamma involve QPolyGamma:

Wolfram Language code: D[QGamma[x, q], x]
Wolfram Research (2008), QPolyGamma, Wolfram Language function, https://reference.wolfram.com/language/ref/QPolyGamma.html.

Text

Wolfram Research (2008), QPolyGamma, Wolfram Language function, https://reference.wolfram.com/language/ref/QPolyGamma.html.

CMS

Wolfram Language. 2008. "QPolyGamma." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/QPolyGamma.html.

APA

Wolfram Language. (2008). QPolyGamma. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QPolyGamma.html

BibTeX

@misc{reference.wolfram_2026_qpolygamma, author="Wolfram Research", title="{QPolyGamma}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/QPolyGamma.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_qpolygamma, organization={Wolfram Research}, title={QPolyGamma}, year={2008}, url={https://reference.wolfram.com/language/ref/QPolyGamma.html}, note=[Accessed: 13-June-2026]}