WOLFRAM

Wolfram Language & System Documentation Center

QuestionObject[q,assess]

represents the question q and the corresponding assessment assess.

QuestionObject[assess]

derives a question from the assessment.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Options  
EpilogFunction  
ImageSize  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

QuestionObject   

List of interface types »

QuestionObject[q,assess]

represents the question q and the corresponding assessment assess.

QuestionObject[assess]

derives a question from the assessment.

Details and Options

Examples

open all close all

Basic Examples  (2)

Define a multiple-choice question:

Wolfram Language code: QuestionObject["How many career home runs did Hank Aaron hit?", AssessmentFunction[{714 -> False, 755 -> True, 868 -> False}]]

Create a true/false question:

Wolfram Language code: QuestionObject["Is a whale a mammal?", AssessmentFunction[{True}]]

Scope  (17)

Create a categorization question:

Wolfram Language code: QuestionObject["Put an animal in the correct class:", AssessmentFunction[{ "Horse" -> <|"Category" -> "Mammal"|>, "Seahorse" -> <|"Category" -> "Fish"|>, "Platypus" -> <|"Category" -> "Mammal"|>, "Orca" -> <|"Category" -> "Mammal"|>, "Turtle" -> <|"Category" -> "Reptile"|> }]]

Specify a test function to assess the answer:

Wolfram Language code: QuestionObject["Give a prime number", PrimeQ]

Create a question where multiple answers may be chosen:

Wolfram Language code: QuestionObject["SqrtBox[4]", AssessmentFunction[{-2 -> True, 0 -> False, 2 -> True, 1 -> False}, <|"ListAssessment" -> "SeparatelyScoreElements"|>, MaxItems -> 2]]

Create a "ShortAnswer" question for assessing a free-form textual answer:

Wolfram Language code: QuestionObject[QuestionInterface["ShortAnswer", <|"Prompt" -> "What sort of animal is Eeyore?", "Interpreter" -> "Species"|>], AssessmentFunction[Entity["TaxonomicSpecies", "EquusAsinus::8c9y9"]]]

Create a "MultipleChoice" question for selecting a single correct answer from a list of choices:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoice", <|"Prompt" -> "Which function is linear?"|>], AssessmentFunction[{ x ^ 2 -> 0, Sin[x] -> 0, 5x -> 1}]]

Create a "MultipleShortAnswers" question to assess many free-form answers:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleShortAnswers", <|"Prompt" -> "Give divisors of 24?", "FieldType" -> Number|>], AssessmentFunction[{_ ? (Divisible[24, #]&)}, <|"ListAssessment" -> "SeparatelyScoreElements"|>]]

Create a "TextCompletion" question to assess free-form fill-in-the-blank answers:

Wolfram Language code: QuestionObject[QuestionInterface["TextCompletion", <|"Prompt" -> "Fill in the blanks", "Template" -> "The quick brown `` jumped over the lazy ``."|>], AssessmentFunction[{{"fox", "dog"}}]]

Create a "SelectCompletion" question to select from a set of predefined answers for each blank:

Wolfram Language code: QuestionObject[QuestionInterface["SelectCompletion", <|"Prompt" -> "Fill in the blanks", "Template" -> "The quick brown `` jumped over the lazy ``."|>], AssessmentFunction[{{"fox", "dog"} -> 1, {"horse", "child"} -> 0, {"hare", "turtle"} -> 0}]]

Create a "DragCompletion" question to fill blanks from a common pool of predefined answers:

Wolfram Language code: QuestionObject[QuestionInterface["DragCompletion", <|"Prompt" -> "Fill in the blanks", "Template" -> "The quick brown `` jumped over the lazy ``."|>], AssessmentFunction[{{"fox", "dog"} -> 1, {"horse", "child"} -> 0, {"hare", "turtle"} -> 0}]]

Create a "ClickLocations" question for locating items in a photo:

Wolfram Language code: stoplights = [image];
Wolfram Language code: QuestionObject[QuestionInterface["ClickLocations", <|"Prompt" -> "Locate the stoplights", "Background" -> stoplights|>], AssessmentFunction[{ImageCases[stoplights, Entity["Concept", "TrafficLight::b4966"] -> "Position"]}, <|"ComparisonMethod" -> "Vector", "ListAssessment" -> "AllElementsOrderless"|>, Tolerance -> 80]]

Create a "Sort" question for ordering items in a list:

Wolfram Language code: QuestionObject[QuestionInterface["Sort", "Order the countries from earliest independence to latest" ], AssessmentFunction[{SortBy[RandomEntity["Country", 4], #["IndependenceDate"]&]}]]

Create a "NumericRange" question for choosing a value within an interval:

Wolfram Language code: QuestionObject[QuestionInterface["NumericRange", <|"Prompt" -> "How many people live in New Zealand?", "Range" -> {5*^5, 30*^6}|>], AssessmentFunction[ QuantityMagnitude@Entity["Country", "NewZealand"][EntityProperty["Country", "Population"]], Tolerance -> 5*^5 ]]

Create a "SelectPair" question for matching one item with a category:

Wolfram Language code: QuestionObject[QuestionInterface["SelectPair", "Match an athelete with their sport:"], AssessmentFunction[{ "Tiger Woods" -> <|"Category" -> "Golf"|>, "Serena Williams" -> <|"Category" -> "Tennis"|>, "Lionel Messi" -> <|"Category" -> "Soccer"|>, "Usain Bolt" -> <|"Category" -> "Track"|> }]]

Create a "SelectColor" question for assessing a color choice:

Wolfram Language code: QuestionObject[QuestionInterface["SelectColor", "What color is a Cardinal"], AssessmentFunction[{ Interpreter["Color"]["Cardinal"] }, Tolerance -> 0.5]]

Create a "MultipleChoiceGrid" question for categorizing multiple items into common categories by selecting radio buttons:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoiceGrid", "Categorize the primates"], AssessmentFunction[{ "Chimpanzee" -> <|"Category" -> "Ape"|>, "Gibbon" -> <|"Category" -> "Ape"|>, "Baboon" -> <|"Category" -> "Monkey"|>, "Sifaka" -> <|"Category" -> "Lemur"|>}, <|"ListAssessment" -> "SeparatelyScoreElements"|>]]

Create a "DragCategorize" question for categorizing multiple items into common categories by dragging the items:

Wolfram Language code: QuestionObject[QuestionInterface["DragCategorize", "Categorize the primates"], AssessmentFunction[{ "Chimpanzee" -> <|"Category" -> "Ape"|>, "Gibbon" -> <|"Category" -> "Ape"|>, "Baboon" -> <|"Category" -> "Monkey"|>, "Sifaka" -> <|"Category" -> "Lemur"|>}, <|"ListAssessment" -> "SeparatelyScoreElements"|>]]

Create a "Code" question for assessing whether submitted code is equivalent to the code in the answer key:

Wolfram Language code: QuestionObject[QuestionInterface["Code", "Write code that flips the order of the string \"Hello World\""], AssessmentFunction[{ HoldPattern[StringReverse["Hello World"]]}, "CodeEquivalence"]]

Generalizations & Extensions  (1)

Create a test function that returns an AssessmentResultObject where the score is a function of the answer:

Wolfram Language code: isItGreen[color_] := With[{dist = ColorDistance[color, Green]}, AssessmentResultObject[<|"Score" -> (0.3 - dist) * 10, "AnswerCorrect" -> dist < 0.3|>] ]
Wolfram Language code: QuestionObject[QuestionInterface["SelectColor", "Choose a green color"], isItGreen]

Options  (2)

EpilogFunction  (1)

Use EpilogFunction in QuestionObject to record the results to a file:

Wolfram Language code: QuestionObject[QuestionInterface["MultipleChoice", <|"Prompt" -> "What is 4^3?"|>], AssessmentFunction[{16, -64, 64 -> 1}], EpilogFunction -> (PutAppend[#Assessment, "assessmentresults"]&)]

See the recorded assessments:

Wolfram Language code: ReadList["assessmentresults"]

Clean up the records:

Wolfram Language code: DeleteFile["assessmentresults"]

ImageSize  (1)

Use ImageSize to set the width of a QuestionObject:

Wolfram Language code: QuestionObject[QuestionInterface["TrueFalse", <|"Prompt" -> "Is it accurate to say that a whale belongs to the class of animals known as mammals? True or false?"|>], TrueQ, ImageSize -> 500]

Also set the height:

Wolfram Language code: QuestionObject[QuestionInterface["TrueFalse", <|"Prompt" -> "Is it accurate to say that a whale belongs to the class of animals known as mammals? True or false?"|>], TrueQ, ImageSize -> {300, 300}]

Applications  (1)

Define a function that generates random versions of a question:

Wolfram Language code: factorQuestion[] := With[{n = RandomInteger[{10, 100}]}, QuestionObject["What are the prime factors of " <> ToString[n, TraditionalForm], AssessmentFunction[RandomSample[{{2, 3, 5} -> 0, (First /@ FactorInteger[n]) -> 1, Prime /@ Sort[RandomInteger[{2, 10}, 3]] -> 0}]]] ]

Generate two versions of the question:

Wolfram Language code: factorQuestion[]
Wolfram Language code: factorQuestion[]

Create an equivalent QuestionGenerator:

Wolfram Language code: factorGenerator = QuestionGenerator[ {"n" :> RandomInteger[{10, 100}]}, QuestionObject["What are the prime factors of " <> ToString[#n, TraditionalForm], AssessmentFunction[RandomSample[{{2, 3, 5} -> 0, (First /@ FactorInteger[#n]) -> 1, Prime /@ Sort[RandomInteger[{2, 10}, 3]] -> 0}]]]& ]
Wolfram Language code: factorGenerator[2]

Properties & Relations  (2)

When an interface type cannot be inferred from the assessment, an input field is used:

Wolfram Language code: QuestionObject["Approximately how many asteroids are in the asteroid belt?", Between[{1100000, 2000000}]]

When no assessment is defined, the submit button is omitted:

Wolfram Language code: QuestionObject[ QuestionInterface["MultipleChoiceGrid", <|"Prompt" -> "Rate these foods:", "Choices" -> {"Ice cream", "Pizza", "Watermelon", "Popcorn"}, "Categories" -> {1, 2, 3, 4, 5}|>]]
Wolfram Research (2021), QuestionObject, Wolfram Language function, https://reference.wolfram.com/language/ref/QuestionObject.html (updated 2025).

Text

Wolfram Research (2021), QuestionObject, Wolfram Language function, https://reference.wolfram.com/language/ref/QuestionObject.html (updated 2025).

CMS

Wolfram Language. 2021. "QuestionObject." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/QuestionObject.html.

APA

Wolfram Language. (2021). QuestionObject. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/QuestionObject.html

BibTeX

@misc{reference.wolfram_2026_questionobject, author="Wolfram Research", title="{QuestionObject}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/QuestionObject.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_questionobject, organization={Wolfram Research}, title={QuestionObject}, year={2025}, url={https://reference.wolfram.com/language/ref/QuestionObject.html}, note=[Accessed: 13-June-2026]}