WOLFRAM

Wolfram Language & System Documentation Center

RarerProbability[dist,example]

computes the probability for distribution dist to generate a sample that has a lower or equal PDF than example.

RarerProbability[dist,{ex1,ex2,…}]

computes the rarer probability for each exi.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Outlier Detection  
Quality Control Monitoring  
Properties & Relations  
See Also
Related Guides
Related Links
History
Cite this Page

RarerProbability

RarerProbability[dist,example]

computes the probability for distribution dist to generate a sample that has a lower or equal PDF than example.

RarerProbability[dist,{ex1,ex2,…}]

computes the rarer probability for each exi.

Details

  • RarerProbability is a statistical function used to quantify how unusual or anomalous a given observation is within a probability distribution.
  • Typical application includes identifying outliers, anomalies and statistically significant deviations from expected patterns in data analysis and machine learning workflows.
  • RarerProbability[dist,x] computes Probability[PDF[dist,y]≤PDF[dist,x],ydist].
  • RarerProbability can be seen as a multivariate extension of the p-value used in statistics. If dist is univariate, continuous and symmetric, the rarer probability is equal to the "two-tailed" p-value.
  • RarerProbability is used to define anomalies in AnomalyDetection, FindAnomalies or DeleteAnomalies.

Examples

open all close all

Basic Examples  (2)

Compute the probability to obtain a rarer value than 3 from a normal distribution:

Wolfram Language code: RarerProbability[NormalDistribution[], 3]
Wolfram Language code: N[%]

Learn a distribution on color data:

Wolfram Language code: ld = LearnDistribution[{RGBColor[0.5172966964096541, 0.4435322033449375, 1.], RGBColor[0.3984626930847484, 0.5592892024442906, 1.], RGBColor[0.6149389612362844, 0.5648721294502163, 1.], RGBColor[0.4129156497559272, 0.9146065592632544, 1.], RGBColor[0.7907065846445507, 0.41054133291260947, 1.], RGBColor[0.4878854162550912, 0.9281119680196579, 1.], RGBColor[0.9884362181280959, 0.49025178842859785, 1.], RGBColor[0.633242503827218, 0.9880985331612835, 1.], RGBColor[0.9215182482568276, 0.8103084921468551, 1.], RGBColor[0.667469513641223, 0.46420827644204676, 1.]}]
Wolfram Language code: RarerProbability[ld, {RGBColor[0.6500379955252116, 0.8945809371196838, 1.000516202399788], RGBColor[0, 0, 1], RGBColor[0, 1, 0], RGBColor[1, 0, 0]}]

Scope  (5)

Compute the rarer probability numerically:

Wolfram Language code: RarerProbability[NormalDistribution[0, 1], 2.5]

Obtain exact numeric results:

Wolfram Language code: RarerProbability[NormalDistribution[0, 1], 5 / 2]
Wolfram Language code: N@%

Obtain a result at any precision for a continuous distribution:

Wolfram Language code: RarerProbability[WeibullDistribution[2, 5], N[4, 25]]

Obtain a result at any precision for a discrete distribution with inexact parameters:

Wolfram Language code: RarerProbability[NegativeBinomialDistribution[20, N[1 / 3, 30]], 5]

RarerProbability threads elementwise over lists:

Wolfram Language code: RarerProbability[NormalDistribution[0, 1], {-2., -1., 0., 1., 2.}]

Applications  (2)

Outlier Detection  (1)

Identify outliers in univariate data:

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 1], 50];

Add outliers:

Wolfram Language code: data = Join[data, {5, -4.5, 6}];

Estimate the data distribution:

Wolfram Language code: dist = EstimatedDistribution[data, NormalDistribution[μ, σ]]

Compute the rarer probability for each data point:

Wolfram Language code: rareness = RarerProbability[dist, data]

Select the low-probability points:

Wolfram Language code: outliers = Pick[data, rareness, _ ? (# < 0.01&)]

Plot the points together with the detected outliers:

Wolfram Language code: ListPlot[{Transpose[{data, rareness}], Pick[Transpose[{data, rareness}], rareness, _ ? (# < 0.01&)]}, ...]

Quality Control Monitoring  (1)

Monitor manufacturing process:

Wolfram Language code: measurements = {10.2, 9.8, 10.1, 11.5, 9.9, 10.3, 8.5, 10.0};

Define a target specification:

Wolfram Language code: specs = NormalDistribution[10, 0.5];

Compute the rarer probability:

Wolfram Language code: rareness = RarerProbability[specs, measurements]

Find the low-quality samples:

Wolfram Language code: bad = Select[rareness, LessThan[0.01] -> "Index"]

Make a control chart:

Wolfram Language code: ListLinePlot[measurements, Epilog -> {Red, InfiniteLine[{#, 0}, {0, 1}]& /@ bad}, ...]

Properties & Relations  (1)

For univariate, continuous and symmetric distributions, the rarer probability is equal to the "two-tailed" p-value:

Wolfram Language code: Integrate[PDF[NormalDistribution[], x], {x, 2, Infinity}] + Integrate[PDF[NormalDistribution[], x], {x, -Infinity, -2}]
Wolfram Language code: RarerProbability[NormalDistribution[], 2]
Wolfram Research (2019), RarerProbability, Wolfram Language function, https://reference.wolfram.com/language/ref/RarerProbability.html.

Text

Wolfram Research (2019), RarerProbability, Wolfram Language function, https://reference.wolfram.com/language/ref/RarerProbability.html.

CMS

Wolfram Language. 2019. "RarerProbability." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RarerProbability.html.

APA

Wolfram Language. (2019). RarerProbability. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RarerProbability.html

BibTeX

@misc{reference.wolfram_2026_rarerprobability, author="Wolfram Research", title="{RarerProbability}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/RarerProbability.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_rarerprobability, organization={Wolfram Research}, title={RarerProbability}, year={2019}, url={https://reference.wolfram.com/language/ref/RarerProbability.html}, note=[Accessed: 13-June-2026]}