WOLFRAM

Wolfram Language & System Documentation Center

ReflectionTransform[v]

gives a TransformationFunction that represents a reflection in a mirror through the origin, normal to the vector v.

ReflectionTransform[v,p]

gives a reflection in a mirror through the point p, normal to the vector v.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

ReflectionTransform

ReflectionTransform[v]

gives a TransformationFunction that represents a reflection in a mirror through the origin, normal to the vector v.

ReflectionTransform[v,p]

gives a reflection in a mirror through the point p, normal to the vector v.

Details

Examples

open all close all

Basic Examples  (2)

Reflection in the line:

Wolfram Language code: rt = ReflectionTransform[{1, -1}]
Wolfram Language code: rt[{x, y}]

Reflection in the plane:

Wolfram Language code: rt = ReflectionTransform[{0, 0, 1}]
Wolfram Language code: rt[{x, y, z}]

Scope  (3)

Reflection transform for symbolic unit vector {u, v, w}:

Wolfram Language code: rt = ReflectionTransform[{u, v, w}]//Simplify[#, {Element[{u, v, w}, Reals], u ^ 2 + v ^ 2 + w ^ 2 == 1}]&

Vectors normal to {u, v, w} remain unchanged:

Wolfram Language code: rt[NullSpace[{{u, v, w}}]] == NullSpace[{{u, v, w}}]//Simplify[#, u ^ 2 + v ^ 2 + w ^ 2 == 1]&

Transformation applied to a 2D shape:

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ReflectionTransform[{1, 1}, {-.2, -.2}]]}]

Transformation applied to a 3D shape:

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, ReflectionTransform[{2, 1, 0}, {-.1, -.1, 0}]]}, Boxed -> False]

Applications  (4)

Reflecting a graphic:

Wolfram Language code: gr = Plot[E ^ x, {x, -3, 2}];
Wolfram Language code: Show[gr, Plot[x, {x, -3, 7}, PlotStyle -> StandardGray], gr /. L_Line :> {Red, GeometricTransformation[L, ReflectionTransform[{-1, 1}]]}, PlotRange -> All]

Reflections of a sine wave:

Wolfram Language code: Plot[Sin[x], {x, -2Pi, 2Pi}, AspectRatio -> Automatic, Axes -> False, PlotRange -> All] /. L_Line :> Table[GeometricTransformation[L, ReflectionTransform[{Cos[u], Sin[u]}]], {u, Pi / 14Range[7]}]

Mirror an image:

Wolfram Language code: ImageTransformation[[image], ReflectionTransform[{1, 0}, {.5, 0}]]

Reflection transform of a 3D image with respect to the axis:

Wolfram Language code: ImageTransformation[\!\(\*Graphics3DBox[«8»]\), ReflectionTransform[{1, 0, 0}], DataRange -> {{-.5, .5}, Automatic, Automatic}]

Properties & Relations  (5)

The reflection transformation is an isometric transform, i.e. preserves distances:

Wolfram Language code: t = ReflectionTransform[{1, 2}, {3, 4}];
Wolfram Language code: {p1, p2} = {{10, 17}, {1, 2}}; {tp1, tp2} = t[{p1, p2}];
Wolfram Language code: EuclideanDistance[p1, p2] == EuclideanDistance[tp1, tp2]

The reflection transformation is its own inverse:

Wolfram Language code: t = ReflectionTransform[{1, 1, 1}];
Wolfram Language code: InverseFunction[t] == t

The determinant of the transformation matrix is :

Wolfram Language code: t = ReflectionTransform[{1, 2, 3}];
Wolfram Language code: Det[TransformationMatrix[t]]

ReflectionTransform can be represented as a scaling transform:

Wolfram Language code: t = ReflectionTransform[{1, 1, 1}];
Wolfram Language code: t == ScalingTransform[-1, {1, 1, 1}]

Top-bottom image reflection using ImageTransformation:

Wolfram Language code: i = [image]; ImageReflect[i] == ImageTransformation[i, ReflectionTransform[{0, 1}], PlotRange -> All]

Reflection across the main diagonal:

Wolfram Language code: ImageReflect[i, Left -> Top] == ImageTransformation[i, ReflectionTransform[{1, 1}], PlotRange -> All]

Reflection across the main antidiagonal:

Wolfram Language code: ImageReflect[i, Right -> Top] == ImageTransformation[i, ReflectionTransform[{-1, 1}], PlotRange -> All]

Possible Issues  (1)

Reflection changes the orientation of polygons:

Wolfram Language code: gr = {FaceForm[Red, Blue], Polygon[{{0, 0, 0}, {1, 0, 0}, {0, 1, 0}}]};
Wolfram Language code: {Graphics3D[gr, PlotRange -> {-.1, .1}], Graphics3D[GeometricTransformation[gr, ReflectionMatrix[{0, 0, 1}]], PlotRange -> {-.1, .1}]}

Neat Examples  (1)

Reflect a 3D object about a point p:

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: p = {0, 0, -0.251619};

Along the axis, about the plane:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Lighter[ColorData[1, 1], 0.5], cow, Lighter[ColorData[1, 2], 0.5], GeometricTransformation[cow, ReflectionTransform[{1, 0, 0}, p]]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

Along the axis, about the plane:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Lighter[ColorData[1, 1], 0.5], cow, Lighter[ColorData[1, 2], 0.5], GeometricTransformation[cow, ReflectionTransform[{0, 1, 0}, p]]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

Along the axis, about the plane:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Lighter[ColorData[1, 1], 0.5], cow, Lighter[ColorData[1, 2], 0.5], GeometricTransformation[cow, ReflectionTransform[{0, 0, 1}, p]]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]
Wolfram Research (2007), ReflectionTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/ReflectionTransform.html.

Text

Wolfram Research (2007), ReflectionTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/ReflectionTransform.html.

CMS

Wolfram Language. 2007. "ReflectionTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ReflectionTransform.html.

APA

Wolfram Language. (2007). ReflectionTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ReflectionTransform.html

BibTeX

@misc{reference.wolfram_2026_reflectiontransform, author="Wolfram Research", title="{ReflectionTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/ReflectionTransform.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_reflectiontransform, organization={Wolfram Research}, title={ReflectionTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/ReflectionTransform.html}, note=[Accessed: 12-June-2026]}