WOLFRAM

Wolfram Language & System Documentation Center

TranslationTransform[v]

gives a TransformationFunction that represents translation of points by a vector v.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

TranslationTransform

TranslationTransform[v]

gives a TransformationFunction that represents translation of points by a vector v.

Details

Examples

open all close all

Basic Examples  (1)

Generate a function representing a translation by the vector {a,b}:

Wolfram Language code: TranslationTransform[{a, b}]

Apply the transformation function to a vector:

Wolfram Language code: %[{x, y}]

Scope  (3)

Translation in four dimensions:

Wolfram Language code: t = TranslationTransform[{x0, y0, z0, w0}]
Wolfram Language code: t[{x, y, z, w}]

The inverse transform:

Wolfram Language code: InverseFunction[t]
Wolfram Language code: InverseFunction[t][{x, y, z, w}]

Apply the transform five times:

Wolfram Language code: Nest[t, {x, y, z, w}, 5]

Use matrix operations and homogeneous coordinates:

Wolfram Language code: MatrixPower[TransformationMatrix[t], n].{x, y, z, w, 1}

Transformation applied to a 2D shape:

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, TranslationTransform[{.75, -.25}]]}]

Transformation applied to a 3D shape:

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, GeometricTransformation[{Opacity[.85], Red, gr}, TranslationTransform[{.75, -.25, -.5}]]}, Boxed -> False]

Applications  (2)

Transforming graphics primitives:

Wolfram Language code: Graphics[GeometricTransformation[Circle[], TranslationTransform[{1, 1}]], Axes -> True]

A random translation walk:

Wolfram Language code: Graphics3D[FoldList[Normal@GeometricTransformation[#, TranslationTransform[#2]]&, Cuboid[], RandomChoice[Permutations[{1, 0, 0}], 50]], Boxed -> False]

Properties & Relations  (4)

The translation transformation is an isometric transform, i.e. preserves distances:

Wolfram Language code: t = TranslationTransform[{1, 2}];
Wolfram Language code: {p1, p2} = {{10, 17}, {1, 2}}; {tp1, tp2} = t[{p1, p2}];
Wolfram Language code: EuclideanDistance[p1, p2] == EuclideanDistance[tp1, tp2]

Translating by and then by is the same as translating by :

Wolfram Language code: Composition[TranslationTransform[{px, py}], TranslationTransform[{qx, qy}]]

The inverse of translating by is the same as translating by :

Wolfram Language code: InverseFunction[TranslationTransform[{px, py}]]

For geometric transformations, use Translate directly:

Wolfram Language code: {Graphics[Translate[Circle[], {1, 1}], Frame -> True], Graphics[GeometricTransformation[Circle[], TranslationTransform[{1, 1}]], Frame -> True]}
Wolfram Language code: {Graphics3D[Translate[Sphere[], {1, 1, 1}], Axes -> True], Graphics3D[GeometricTransformation[Sphere[], TranslationTransform[{1, 1, 1}]], Axes -> True]}

Neat Examples  (1)

Scale a 3D object about a point :

Wolfram Language code: cow = ExampleData[{"Geometry3D", "Cow"}, "GraphicsComplex"];
Wolfram Language code: p = {0, 0, -0.251619};

Translate along the axis:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k], 0.5], GeometricTransformation[cow, TranslationTransform[k / 2{1, 0, 0}]]}, {k, 1, 3}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

Translate along the axis:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k], 0.5], GeometricTransformation[cow, TranslationTransform[k / 2{0, 1, 0}]]}, {k, 1, 3}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]

Translate along the axis:

Wolfram Language code: Graphics3D[{EdgeForm[None], Opacity[0.5], Table[{Lighter[ColorData[1, k], 0.5], GeometricTransformation[cow, TranslationTransform[k / 2{0, 0, 1}]]}, {k, 1, 3}]}, Lighting -> "Neutral", ImageSize -> Large, Boxed -> False]
Wolfram Research (2007), TranslationTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/TranslationTransform.html.

Text

Wolfram Research (2007), TranslationTransform, Wolfram Language function, https://reference.wolfram.com/language/ref/TranslationTransform.html.

CMS

Wolfram Language. 2007. "TranslationTransform." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TranslationTransform.html.

APA

Wolfram Language. (2007). TranslationTransform. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TranslationTransform.html

BibTeX

@misc{reference.wolfram_2026_translationtransform, author="Wolfram Research", title="{TranslationTransform}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/TranslationTransform.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_translationtransform, organization={Wolfram Research}, title={TranslationTransform}, year={2007}, url={https://reference.wolfram.com/language/ref/TranslationTransform.html}, note=[Accessed: 13-June-2026]}