WOLFRAM

Wolfram Language & System Documentation Center

RegularPolygon[n]

gives the regular polygon with n vertices equally spaced around the unit circle.

RegularPolygon[r,n]

gives the regular polygon of radius r.

RegularPolygon[{r,θ},n]

starts at angle θ with respect to the axis.

RegularPolygon[{x,y},rspec,n]

centers the polygon at {x,y}.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics  
Specification  
Styling  
Coordinate  
Regions  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
Related Links
History
Cite this Page

RegularPolygon

RegularPolygon[n]

gives the regular polygon with n vertices equally spaced around the unit circle.

RegularPolygon[r,n]

gives the regular polygon of radius r.

RegularPolygon[{r,θ},n]

starts at angle θ with respect to the axis.

RegularPolygon[{x,y},rspec,n]

centers the polygon at {x,y}.

Details and Options

Examples

open all close all

Basic Examples  (3)

A pentagon:

Wolfram Language code: Graphics[RegularPolygon[5]]

Different styles applied to RegularPolygon:

Wolfram Language code: ℛ = RegularPolygon[8]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

Area and centroid:

Wolfram Language code: Area[RegularPolygon[6]]
Wolfram Language code: RegionCentroid[RegularPolygon[6]]

Scope  (17)

Graphics  (7)

Specification  (4)

Generate an equilateral triangle, square, pentagon, hexagon, etc.:

Wolfram Language code: Table[Graphics[RegularPolygon[n]], {n, 3, 10}]

Generate pentagons of varying radii:

Wolfram Language code: rp = Table[RegularPolygon[r, 5], {r, 1, 4}];
Wolfram Language code: Graphics[{Opacity[0.2], rp}]

Generate triangles of varying starting angles:

Wolfram Language code: rp = Table[RegularPolygon[{1, t Pi / 6}, 3], {t, 4}];
Wolfram Language code: Graphics[{Opacity[0.2], rp}]

Place six hexagons equally spaced around the unit circle:

Wolfram Language code: cp = CirclePoints[2, 6];
Wolfram Language code: rp = Table[RegularPolygon[p, {1, 0}, 6], {p, cp}];
Wolfram Language code: Graphics[rp]

Styling  (2)

Color directives specify the face colors of regular polygons:

Wolfram Language code: Table[Graphics[{c, RegularPolygon[7]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary:

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], RegularPolygon[7]}]

Coordinate  (1)

Use Dynamic coordinates:

Wolfram Language code: Slider2D[Dynamic@a, {0, 3}] Graphics[RegularPolygon[Dynamic[a], 5, 5], Frame -> True, PlotRange -> 5]

And dynamic radii:

Wolfram Language code: Slider[Dynamic@b, {1, 3}] Graphics[RegularPolygon[{0, 0}, Dynamic[b], 5], Frame -> True, PlotRange -> 5]

Regions  (10)

Embedding dimension:

Wolfram Language code: RegionEmbeddingDimension[RegularPolygon[n]]

Geometric dimension:

Wolfram Language code: RegionDimension[RegularPolygon[n]]

Point membership test:

Wolfram Language code: {RegionMember[RegularPolygon[7], {0, 0}], RegionMember[RegularPolygon[7], {0, 2}]}

Get conditions for point membership:

Wolfram Language code: RegionMember[RegularPolygon[{0, 0}, {1, 0}, 4], {x, y}]

Area:

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {RegionDistance[ℛ, {1, 2}], RegionDistance[ℛ, {0, 0}]}

The distance to the nearest point in the unit disk:

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 3}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2}], SignedRegionDistance[ℛ, {0, 0}]}

Signed distance to the unit disk:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}, Exclusions -> Norm[{x, y}] == 1]

Nearest point in the region:

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

Nearest points:

Wolfram Language code: pts = Table[2{Cos[k ], Sin[k]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

A regular polygon is bounded:

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: BoundedRegionQ[ℛ]

Get its range:

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{StandardGreen, ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

Integrate over a hexagon:

Wolfram Language code: ℛ = RegularPolygon[{Subscript[x, 0], Subscript[y, 0]}, {r, 0}, 6];
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]//Simplify

Optimize over a hexagon:

Wolfram Language code: ℛ = RegularPolygon[6];
Wolfram Language code: {MinValue[{x y - x, {x, y}∈ℛ}, {x, y}], ArgMin[{x y - x, {x, y}∈ℛ}, {x, y}]}

Solve equations in a hexagon:

Wolfram Language code: ℛ = RegularPolygon[{1, 2}, {3, 0}, 6];
Wolfram Language code: Solve[x^2 + y^2 == 7 && x y == 1 && {x, y}∈ℛ, {x, y}]
Wolfram Language code: Show[{Graphics[{{StandardGreen, ℛ}, {Blue, Circle[{0, 0}, Sqrt[7]]}}], Plot[1 / x, {x, -3, 5}, PlotRange -> {{-3, 5}, {-3, 6}}], Graphics[{PointSize[Large], Red, Point[{x, y}] /. %}]}, Axes -> True]

Applications  (4)

Create a star region by taking the RegionUnion of rotated triangles about a common origin:

Wolfram Language code: ℛ = RegionUnion@@Table[RegularPolygon[{1, t Pi / 6}, 3], {t, 4}];
Wolfram Language code: Region[ℛ]

Create 3D extrusions with RegionProduct:

Wolfram Language code: ℛ = RegionProduct[RegularPolygon[5], Line[{{0}, {1}}]];
Wolfram Language code: Region[ℛ]

Plot a function over a hexagon:

Wolfram Language code: Plot3D[Sin[x + Cos[y]], {x, y}∈RegularPolygon[6]]

Some lattices will have regular polygons as their cells. Consider the lattice basis:

Wolfram Language code: b = {{-Sqrt[3], -1}, {-Sqrt[3], 1}};

Generate lattice points and tiles:

Wolfram Language code: pts = Tuples[Range[0, 4], 2].b;
Wolfram Language code: tiles = Table[RegularPolygon[p, {1, 0}, 6], {p, pts}];

Visualize the tiling and lattice points:

Wolfram Language code: Graphics[{Gray, tiles, Red, Point[pts]}]

Properties & Relations  (3)

A RegularPolygon is a Polygon whose vertices are equally spaced around the unit circle:

Wolfram Language code: n = 7;
Wolfram Language code: p = Polygon[CirclePoints[n]];
Wolfram Language code: rp = RegularPolygon[n];
Wolfram Language code: Graphics /@ {p, rp}

Use CirclePoints to generate points equally spaced around the unit circle:

Wolfram Language code: n = 7; {rp, cp} = {RegularPolygon[n], CirclePoints[n]};
Wolfram Language code: Graphics[{rp, PointSize[Large], Red, Point[cp]}]

The area of a regular polygon on the unit circle as is the area of a unit Disk:

Wolfram Language code: Limit[Area[RegularPolygon[n]], n -> Infinity]
Wolfram Language code: Area[Disk[]]

Neat Examples  (2)

A collection of random regular polygons:

Wolfram Language code: Graphics[{EdgeForm[Black], Table[{Opacity[0.2], Hue[RandomReal[]], RegularPolygon[RandomReal[9, 2], {RandomReal[], 0}, RandomInteger[{3, 7}]]}, {200}]}]

Overlap regular polygons of increasing radii and vertices:

Wolfram Language code: rp = Table[RegularPolygon[r, r + 2], {r, 9}];
Wolfram Language code: Graphics[{Opacity[0.15], rp}]
Wolfram Research (2015), RegularPolygon, Wolfram Language function, https://reference.wolfram.com/language/ref/RegularPolygon.html (updated 2019).

Text

Wolfram Research (2015), RegularPolygon, Wolfram Language function, https://reference.wolfram.com/language/ref/RegularPolygon.html (updated 2019).

CMS

Wolfram Language. 2015. "RegularPolygon." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2019. https://reference.wolfram.com/language/ref/RegularPolygon.html.

APA

Wolfram Language. (2015). RegularPolygon. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RegularPolygon.html

BibTeX

@misc{reference.wolfram_2026_regularpolygon, author="Wolfram Research", title="{RegularPolygon}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/RegularPolygon.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_regularpolygon, organization={Wolfram Research}, title={RegularPolygon}, year={2019}, url={https://reference.wolfram.com/language/ref/RegularPolygon.html}, note=[Accessed: 12-June-2026]}