Wolfram Language & System Documentation Center

RegionUnion

RegionUnion[reg₁,reg₂,…]

gives the union of the regions reg₁, reg₂, ….

Details and Options

A point p belongs to RegionUnion[reg₁,reg₂,…] if it belongs to some reg_i.

RegionUnion takes the same options as Region.

Examples

open all close all

Basic Examples (2)

Union of two disks:

Wolfram Language code: RegionUnion[Disk[{0, 0}, 2], Disk[{3, 0}, 2]];

Visualize it:

Wolfram Language code: Region[%]

Union of two MeshRegion objects:

Wolfram Language code: RegionUnion[[image], [image]]

Scope (14)

Special Regions (6)

For some regions, the union is computed explicitly:

Wolfram Language code:

Subscript[ℛ, 1] = Triangle[{{0, 0}, {0, 1}, {1, 0}}];
Subscript[ℛ, 2] = Disk[];

Wolfram Language code: Subscript[ℛ, 3] = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Visualize the union:

Wolfram Language code: Graphics[{Opacity[0.3], {Blue, Subscript[ℛ, 1]}, {Yellow, Subscript[ℛ, 2]}, {Red, Subscript[ℛ, 3]}}]

A union of Line regions:

Wolfram Language code: Subscript[ℛ, 1] = RegionUnion[Line[{{1}, {2}}], Line[{{3}, {4}}]];

Visualize it:

Wolfram Language code: Region[Subscript[ℛ, 1]]

With overlap:

Wolfram Language code: Subscript[ℛ, 2] = RegionUnion[Line[{{1}, {3}}], Line[{{2}, {4}}]];

Visualize it:

Wolfram Language code: Region[Subscript[ℛ, 2]]

A union of Polygon regions:

Wolfram Language code:

Subscript[ℛ, 1] = Polygon[{{0, 0}, {3, -1}, {2, 0}, {3, 1}}];
Subscript[ℛ, 2] = Polygon[{{5, 0}, {2, 1}, {3, 0}, {2, -1}}];

Wolfram Language code: ℛ = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

A union of two Disk regions:

Wolfram Language code: ℛ = RegionUnion[Disk[{0, 0}, 1], Disk[{1, 0}, 1]];

Visualize it:

Wolfram Language code: Region[ℛ]

A union of two Cuboid regions:

Wolfram Language code: ℛ = RegionUnion[Cuboid[], Cuboid[{0.5, 0.5, 0.5}]];

Visualize it:

Wolfram Language code: Region[ℛ]

A union of regions with different RegionDimension:

Wolfram Language code: ℛ = RegionUnion[Disk[{0, 0}, 1], Circle[{1, 0}, 1]];

Visualize it:

Wolfram Language code: Region[ℛ]

Formula Regions (2)

A union of ImplicitRegion objects is an ImplicitRegion:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x ≤ -1, {x}];
Subscript[ℛ, 2] = ImplicitRegion[x ≥ 1, {x}];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

2D:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 ≤ 1, {x, y}];
Subscript[ℛ, 2] = ImplicitRegion[x^2 + (y - 1)^2 ≤ 1, {x, y}];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 ≤ 1, {x, y, z}];
Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 ≤ 1, {x, y, z}];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

nD:

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[x^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];
Subscript[ℛ, 2] = ImplicitRegion[(x - 1)^2 + y^2 + z^2 + u^2 + v^2 ≤ 1, {x, y, z, u, v}];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

A union of ParametricRegion objects:

Wolfram Language code:

Subscript[ℛ, 1] = ParametricRegion[{u, v}, {{u, 0, 2}, {v, 0, 2}}];
Subscript[ℛ, 2] = ParametricRegion[{u + 1, v + 1}, {{u, 0, 2}, {v, 0, 2}}];

Wolfram Language code: ℛ = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

Mesh Regions (2)

A union of BoundaryMeshRegion objects is a BoundaryMeshRegion:

Wolfram Language code: RegionUnion[[image], [image]]

Wolfram Language code: BoundedRegionQ[%]

2D:

Wolfram Language code: RegionUnion[[image], [image]]

Wolfram Language code: BoundedRegionQ[%]

3D:

Wolfram Language code: RegionUnion[[image], [image]]

Wolfram Language code: BoundedRegionQ[%]

A union of full-dimensional MeshRegion objects is a MeshRegion:

Wolfram Language code: RegionUnion[[image], [image]]

Wolfram Language code: MeshRegionQ[%]

2D:

Wolfram Language code: RegionUnion[[image], [image]]

Wolfram Language code: MeshRegionQ[%]

3D:

Wolfram Language code: RegionUnion[[image], [image]]

Wolfram Language code: MeshRegionQ[%]

Derived Regions (2)

A union of BooleanRegion objects:

Wolfram Language code:

Subscript[ℛ, 1] = BooleanRegion[Or, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, -1}}]}];
Subscript[ℛ, 2] = BooleanRegion[And, {Triangle[{{0, 0}, {2, 3}, {-2, 3}}], Triangle[{{0, 2}, {2, -1}, {-2, 2}}]}];

Wolfram Language code: ℛ = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

A union of TransformedRegion objects:

Wolfram Language code:

Subscript[ℛ, 1] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {1, 0, 0}]];
Subscript[ℛ, 2] = TransformedRegion[Cuboid[], RotationTransform[Pi / 8, {0, 1, 0}]];

Wolfram Language code: ℛ = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Visualize it:

Wolfram Language code: Region[ℛ]

CSG Regions (1)

A union of CSGRegion objects in 2D:

Wolfram Language code:

Subscript[ℛ, 1] = CSGRegion["Difference", {Disk[{0, 0}, 6], Disk[{0, 0}, 3]}];
Subscript[ℛ, 2] = CSGRegion["Difference", {Rotate[Rectangle[{-8, -8}, {8, 8}], 45Degree], Rotate[Rectangle[{-6, -6}, {6, 6}], 45Degree]}];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code:

Subscript[ℛ, 1] = CSGRegion["Difference", {Ball[{-1, 0, 0}, 2], Cuboid[{-1, -5, -5}, {5, 5, 5}]}];
Subscript[ℛ, 2] = CSGRegion["Difference", {Ball[{1, 0, 0}, 2], Cuboid[{1, -5, -5}, {-5, 5, 5}]}];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Subdivision Regions (1)

A union of SubdivisionRegion objects in 2D:

Wolfram Language code:

Subscript[ℛ, 1] = SubdivisionRegion[Rectangle[{-2, -1 / 2}]];
Subscript[ℛ, 2] = SubdivisionRegion[RegularPolygon[3]];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

3D:

Wolfram Language code:

Subscript[ℛ, 1] = SubdivisionRegion[Cube[{-1, 0, 0}]];
Subscript[ℛ, 2] = SubdivisionRegion[Tetrahedron[3]];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Applications (6)

Union of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};

Wolfram Language code:

Multicolumn[Table[RegionUnion[Subscript[ℛ, 1], TransformedRegion[Subscript[ℛ, 2], TranslationTransform[{0, 0, t}]]], {t, 0, 2.5, 0.5}], 3, Appearance -> "Horizontal" ]

Union of all South America countries to get the map:

Wolfram Language code: countries = CountryData["SouthAmerica"]

Country regions:

Wolfram Language code: regs = Table[BoundaryDiscretizeGraphics[Polygon[First[c["Polygon"]][[1, 1]]]], {c, countries}]

South America map:

Wolfram Language code: RegionUnion@@regs

Define a stadium as the union of disks and a rectangle:

Wolfram Language code: stadium = RegionUnion[Disk[{0, 0}, 1], Rectangle[{0, -1}, {2, 1}], Disk[{2, 0}, 1]];

Wolfram Language code: Region[stadium]

The area is the sum of disk and quadrilateral areas:

Wolfram Language code: Area[stadium]

Wolfram Language code: Area[Disk[{0, 0}, 1]] + Area[Rectangle[{0, -1}, {2, 1}]]

Define a capsule as the union of balls and a cylinder:

Wolfram Language code: capsule = RegionUnion[Ball[{0, 0, 0}, 1], Cylinder[{{0, 0, 0}, {2, 0, 0}}, 1], Ball[{2, 0, 0}, 1]];

Wolfram Language code: Region[capsule]

The volume is the sum of the ball and cylinder volumes:

Wolfram Language code: Volume[capsule]

Wolfram Language code: Volume[Ball[{0, 0, 0}, 1]] + Volume[Cylinder[{{0, 0, 0}, {2, 0, 0}}, 1]]

By taking a RegionUnion of many disks, dilation of a mesh can be approximated:

Wolfram Language code: mr = BoundaryDiscretizeGraphics[Graphics[Text[""]], _Text]

Create disks of the dilation radius around the mesh boundary:

Wolfram Language code:

rad = 0.25;
pts = MeshCoordinates[mr];
disks = BoundaryDiscretizeRegion[Disk[#, rad]]& /@ pts;

Then simply take the union of all disks plus the original mesh:

Wolfram Language code: RegionUnion[RegionUnion@@disks, mr]

By removing a RegionUnion of many disks, erosion of a mesh can be approximated:

Wolfram Language code: mr = BoundaryDiscretizeGraphics[Graphics[Text[""]], _Text]

Create disks of the erosion radius around the mesh boundary:

Wolfram Language code:

rad = 0.1;
pts = MeshCoordinates[mr];
disks = BoundaryDiscretizeRegion[Disk[#, rad]]& /@ pts;

Then subtract the union of the disks from the original mesh:

Wolfram Language code: RegionDifference[mr, RegionUnion@@disks]

Properties & Relations (5)

A point p belongs to RegionUnion[reg₁,reg₂,…] if it belongs to some reg_i:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 2];
Subscript[ℛ, 2] = Disk[{0, 3}, 2];
Subscript[ℛ, 3] = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Use RegionMember to test membership:

Wolfram Language code: p = {0, 1};

Wolfram Language code: RegionMember[Subscript[ℛ, 3], p] == RegionMember[Subscript[ℛ, 1], p]∨ RegionMember[Subscript[ℛ, 2], p]

RegionUnion is a Boolean combination Or of regions:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]] == BooleanRegion[Or, {Subscript[ℛ, 1], Subscript[ℛ, 2]}]

RegionSymmetricDifference can be found using RegionUnion and RegionDifference:

Wolfram Language code: {Subscript[ℛ, 1], Subscript[ℛ, 2]} = {[image], [image]};

Wolfram Language code:

RegionSymmetricDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]] == RegionUnion[RegionDifference[Subscript[ℛ, 1], Subscript[ℛ, 2]], RegionDifference[Subscript[ℛ, 2], Subscript[ℛ, 1]]]

The RegionDimension of a union is the max of all input dimensions:

Wolfram Language code:

Subscript[ℛ, 1] = Point[{0, 0}];
Subscript[ℛ, 2] = Line[{{1, 0}, {1, 1}}];
Subscript[ℛ, 3] = Disk[{2, 0}, 1];

Wolfram Language code:

RegionDimension[RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3]]] == Max[RegionDimension /@ {Subscript[ℛ, 1], Subscript[ℛ, 2], Subscript[ℛ, 3]}]

If two regions are disjoint, the RegionMeasure of their union is a sum:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Subscript[ℛ, 2] = Disk[{3, 0}, 1];
Subscript[ℛ, 3] = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Wolfram Language code: RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] + RegionMeasure[Subscript[ℛ, 2]]

If they overlap, you must subtract the measure of the RegionIntersection:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[{0, 0}, 1];
Subscript[ℛ, 2] = Disk[{1, 0}, 1];
Subscript[ℛ, 3] = RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]];

Wolfram Language code:

RegionMeasure[Subscript[ℛ, 3]] == RegionMeasure[Subscript[ℛ, 1]] + RegionMeasure[Subscript[ℛ, 2]] - RegionMeasure[RegionIntersection[Subscript[ℛ, 1], Subscript[ℛ, 2]]]

Possible Issues (2)

RegionUnion is defined only for regions with the same RegionEmbeddingDimension:

Wolfram Language code:

Subscript[ℛ, 1] = Disk[];
Subscript[ℛ, 2] = Ball[{0, 0, 1}, 1];

Wolfram Language code: RegionUnion[Subscript[ℛ, 1], Subscript[ℛ, 2]]

RegionUnion may include overlapping lower-dimensional components:

Wolfram Language code:

Subscript[ℛ, 1] = Sphere[];
Subscript[ℛ, 2] = Ball[{1 / 2, 0, 0}];

Wolfram Language code: Graphics3D[{Yellow, Subscript[ℛ, 1], Green, Opacity@.5, Subscript[ℛ, 2]}]

Wolfram Language code: Subscript[ℛ, 3] = RegionUnion[DiscretizeGraphics[Subscript[ℛ, 1]], BoundaryDiscretizeGraphics[Subscript[ℛ, 2]]]

The connected mesh components:

Wolfram Language code: ConnectedMeshComponents[Subscript[ℛ, 3]]

Neat Examples (1)

The union of two spiral polygons:

Wolfram Language code: RegionUnion[[image], [image]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

RegionUnion

Details and Options

Examples

Basic Examples (2)

Scope (14)

Special Regions (6)

Formula Regions (2)

Mesh Regions (2)

Derived Regions (2)

CSG Regions (1)

Subdivision Regions (1)

Applications (6)

Properties & Relations (5)

Possible Issues (2)

Neat Examples (1)

Text

CMS

APA

BibTeX

BibLaTeX

RegionUnion

Details and Options

Examples

Basic Examples (2)

Scope (14)

Special Regions (6)

Formula Regions (2)

Mesh Regions (2)

Derived Regions (2)

CSG Regions (1)

Subdivision Regions (1)

Applications (6)

Properties & Relations (5)

Possible Issues (2)

Neat Examples (1)

See Also

Related Guides

History

Text

CMS

APA

BibTeX

BibLaTeX