WOLFRAM

Wolfram Language & System Documentation Center

RudinShapiro[n]

gives the n^(th) term in the Rudin–Shapiro sequence.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

RudinShapiro

RudinShapiro[n]

gives the n^(th) term in the Rudin–Shapiro sequence.

Details

  • RudinShapiro[n] is 1 if n has an even number of possibly overlapping 11 sequences in its base-2 digits, and is -1 otherwise.
  • RudinShapiro automatically threads over lists.

Examples

open all close all

Basic Examples  (2)

The sixth element of the Rudin–Shapiro sequence:

Wolfram Language code: RudinShapiro[6]

The number 6 has an odd number of 11 sequences in its binary form:

Wolfram Language code: BaseForm[6, 2]

The first ten elements of the sequence:

Wolfram Language code: Table[RudinShapiro[n], {n, 0, 9}]

Display the values alongside the binary expansion:

Wolfram Language code: Table[{n, BaseForm[n, 2], RudinShapiro[n]}, {n, 0, 10}]//Grid

Scope  (2)

RudinShapiro threads over lists:

Wolfram Language code: RudinShapiro[{3, 5, 8, 11}]

Evaluate at large integers:

Wolfram Language code: RudinShapiro[999 ^ 999]

Applications  (2)

Generate an example of a first Shapiro polynomial:

Wolfram Language code: Sum[RudinShapiro[i]z ^ i, {i, 0, 2 ^ 5 - 1}]

Generate a Rudin–Shapiro curve:

Wolfram Language code: Graphics[Line[AnglePath[Pi / 2 * Table[(-1) ^ ((1 + RudinShapiro[n]RudinShapiro[n + 1]) / 2), {n, 0, 500}]]]]

Properties & Relations  (3)

The Rudin–Shapiro sequence has a nested structure:

Wolfram Language code: Grid[Partition[Table[ListLinePlot[Accumulate[Array[RudinShapiro, 2 ^ k, 0]]], {k, 12}], 4]]

The Rudin–Shapiro sequence satisfies a recurrence relation:

Wolfram Language code: Module[{f}, f[0] = 1;f[n_] := f[n] = (-1) ^ Mod[(1 - f[Quotient[n, 2]]) / 2 + Quotient[n, 2] * n, 2]; Array[f, 32, 0]]

The Rudin–Shapiro sequence is the result of a substitution system:

Wolfram Language code: Characters[Nest[StringReplace[#, {"AB" -> "ABAD", "AD" -> "ABCB", "CB" -> "CDAD", "CD" -> "CDCB"}]&, "AB", 4]] /. {"A" | "B" -> 1, "C" | "D" -> -1}

Neat Examples  (1)

Generate a path based on the Rudin–Shapiro sequence:

Wolfram Language code: Graphics[Line[AnglePath[Array[RudinShapiro, 4096]2 Pi / 5]]]
Wolfram Research (2015), RudinShapiro, Wolfram Language function, https://reference.wolfram.com/language/ref/RudinShapiro.html.

Text

Wolfram Research (2015), RudinShapiro, Wolfram Language function, https://reference.wolfram.com/language/ref/RudinShapiro.html.

CMS

Wolfram Language. 2015. "RudinShapiro." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/RudinShapiro.html.

APA

Wolfram Language. (2015). RudinShapiro. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/RudinShapiro.html

BibTeX

@misc{reference.wolfram_2026_rudinshapiro, author="Wolfram Research", title="{RudinShapiro}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/RudinShapiro.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_rudinshapiro, organization={Wolfram Research}, title={RudinShapiro}, year={2015}, url={https://reference.wolfram.com/language/ref/RudinShapiro.html}, note=[Accessed: 13-June-2026]}