WOLFRAM

Wolfram Language & System Documentation Center

ThueMorse[n]

gives the n^(th) term in the Thue–Morse sequence.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

ThueMorse

ThueMorse[n]

gives the n^(th) term in the Thue–Morse sequence.

Details

  • ThueMorse[n] is 1 exactly when n has an odd number of 1s in its binary expansion.
  • ThueMorse gives the sequence generated by the substitution starting from .
  • ThueMorse[0] is the beginning of the Thue–Morse sequence.
  • ThueMorse automatically threads over lists.

Examples

open all close all

Basic Examples  (2)

The fifth element of the Thue–Morse sequence:

Wolfram Language code: ThueMorse[5]

Five has an even number of ones in its binary expansion:

Wolfram Language code: BaseForm[5, 2]

The first 10 elements of the sequence:

Wolfram Language code: Table[ThueMorse[n], {n, 0, 9}]

Display the values alongside the binary expansion:

Wolfram Language code: Table[{n, ThueMorse[n], BaseForm[n, 2]}, {n, 0, 9}]//Grid

Scope  (2)

ThueMorse threads over lists:

Wolfram Language code: ThueMorse[{12, 8, 55, 2}]

Evaluate at large integers:

Wolfram Language code: ThueMorse[1000!]

Applications  (1)

The Koch snowflake:

Wolfram Language code: Graphics[Line[AnglePath[Array[ThueMorse, 4096]2 Pi / 3]]]

Properties & Relations  (8)

ThueMorse[n] is 1 if and only if n has an odd number of 1s in its binary form:

Wolfram Language code: Table[{n, ThueMorse[n], BaseForm[n, 2]}, {n, 0, 10}]//Grid

The Thue–Morse sequence can arise from a nested list:

Wolfram Language code: Nest[Join[#, 1 - #]&, {0}, 4]

The Thue–Morse sequence can arise from the center column of a cellular automaton:

Wolfram Language code: 1 - CellularAutomaton[{69540422, 2, 2}, {{1}, 0}, {15, {{0}}}]

The Thue–Morse sequence has a closed form as a hypergeometric function:

Wolfram Language code: Mod[1 + Table[1 / 2(-1) ^ n + (-3) ^ n Sqrt[Pi] * Hypergeometric2F1[3 / 2, -n, 3 / 2 - n, -1 / 3] / (4n! Gamma[3 / 2 - n]), {n, 0, 15}], 2]

Solution to a recurrence relation:

Wolfram Language code: Module[{f}, f[0] = 0;f[n_] := f[n] = Mod[1 + f[Quotient[n, 2]] + n, 2]; Array[f, 16, 0]]

Cube-free sequence:

Wolfram Language code: CubeQ[s_] := Mod[Length[s], 3] == 0 && With[{x = s[[ ;; Length[s] / 3]]}, s == Join[x, x, x]]
Wolfram Language code: Subwords[list_] := Union@@Table[list[[i ;; j]], {i, Length[list]}, {j, i + 1, Length[list]}]
Wolfram Language code: Select[Subwords[Array[ThueMorse, 16, 0]], CubeQ]

Overlap-free sequence:

Wolfram Language code: ASelfOverlapQ[s_] := Apply[Or, Table[With[{x = s[[ ;; i]], y = s[[i + 1 ;; i + Quotient[Length[s] - 3i, 2]]]}, s == Join[x, y, x, y, x]], {i, Quotient[Length[s], 3]}]]
Wolfram Language code: Subwords[list_] := Union@@Table[list[[i ;; j]], {i, Length[list]}, {j, i + 1, Length[list]}]
Wolfram Language code: Select[Subwords[Array[ThueMorse, 16, 0]], ASelfOverlapQ]

The Thue–Morse sequence has a nested structure:

Wolfram Language code: Grid[Partition[Table[ListLinePlot[FoldList[Plus, 0, (-1) ^ Array[ThueMorse, 2 ^ k, 0]]], {k, 6}], 2], Dividers -> All]

Neat Examples  (1)

Paths at different angles based on Thue–Morse sequences:

Wolfram Language code: Table[Graphics[Line[AnglePath[Array[ThueMorse, 1024]θ]]], {θ, 0, 2Pi, .5}]
Wolfram Research (2015), ThueMorse, Wolfram Language function, https://reference.wolfram.com/language/ref/ThueMorse.html.

Text

Wolfram Research (2015), ThueMorse, Wolfram Language function, https://reference.wolfram.com/language/ref/ThueMorse.html.

CMS

Wolfram Language. 2015. "ThueMorse." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ThueMorse.html.

APA

Wolfram Language. (2015). ThueMorse. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ThueMorse.html

BibTeX

@misc{reference.wolfram_2026_thuemorse, author="Wolfram Research", title="{ThueMorse}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/ThueMorse.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_thuemorse, organization={Wolfram Research}, title={ThueMorse}, year={2015}, url={https://reference.wolfram.com/language/ref/ThueMorse.html}, note=[Accessed: 13-June-2026]}