Sqrt
Sqrt[z]
or 
gives the square root of z.
Details
- Mathematical function, suitable for both symbolic and numerical manipulation.
can be entered using 
or ∖(∖@z∖). - Sqrt[z] is converted to
. - Sqrt[z^2] is not automatically converted to z.
- Sqrt[a b] is not automatically converted to Sqrt[a]Sqrt[b].
- These conversions can be done using PowerExpand, but will typically be correct only for positive real arguments.
- For certain special arguments, Sqrt automatically evaluates to exact values.
- Sqrt can be evaluated to arbitrary numerical precision.
- Sqrt automatically threads over lists. »
- In StandardForm, Sqrt[z] is printed as
. - √z can also be used for input. The √ character is entered as
sqrt
or \[Sqrt].
Examples
open all close allBasic Examples (6)
Sqrt[3.]
:Sqrt[200]Negative numbers have imaginary square roots:
Sqrt[-25]Plot over a subset of the reals:
Plot[Sqrt[x], {x, 0, 10}]Plot over a subset of the complexes:
ComplexPlot3D[Sqrt[z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]
Sqrt[x^2] /. x -> -1It can be simplified to 
if one assumes 
:
Simplify[%, x > 0]Scope (39)
Numerical Evaluation (7)
Sqrt[7.]N[Sqrt[3], 50]The precision of the output tracks the precision of the input:
Sqrt[2.000444001111111110000]N[Sqrt[5 + I]]Evaluate efficiently at high precision:
Sqrt[15`100]//TimingSqrt[12`1000000];//TimingSqrt can deal with real‐valued intervals:
Sqrt[Interval[{1, 8}]]Compute the elementwise values of an array using automatic threading:
Sqrt[{{1 / 2, -1}, {0, 1 / 2}}]Or compute the matrix Sqrt function using MatrixFunction:
MatrixFunction[Sqrt, {{1 / 2, -1}, {0, 1 / 2}}]//FullSimplifyCompute average-case statistical intervals using Around:
Sqrt[ Around[2, 0.01]]Specific Values (4)
Values of Sqrt at fixed points:
Table[Sqrt[x], {x, {-4, -2, -1, 1, 2, 4}}]Sqrt[0]Sqrt[∞]Sqrt[ComplexInfinity]Find a value of 
for which 
using Solve:
Solve[Sqrt[x ] == 2.1 && 0 < x, x]//Quietxval = x /. First[%]Plot[Sqrt[x], {x, 0, 10}, Epilog -> Style[Point[{xval, Sqrt[xval ]}], PointSize[Large], Red]]Visualization (4)
Plot the real and imaginary parts of the Sqrt function:
ReImPlot[Sqrt[x], {x, -4, 4}, PlotLegends -> Automatic]Compare the real and imaginary parts of 
and 
(Surd[x,2]):
ReImPlot[{Sqrt[x], Sqrt[x]}, {x, -4, 4}, PlotLegends -> Automatic]//Quiet
ComplexContourPlot[Re[Sqrt[z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]
ComplexContourPlot[Im[Sqrt[z]], {z, -4 - 4 I, 4 + 4 I}, Contours -> 20]
PolarPlot[Sqrt[ϕ], {ϕ, 0, 6π}, Frame -> True]Function Properties (10)
The real domain of Sqrt:
FunctionDomain[Sqrt[x], x]It is defined for all complex values:
FunctionDomain[Sqrt[z], z, Complexes]Sqrt achieves all non-negative values on the reals:
FunctionRange[Sqrt[x], x, y]The range for complex values is the right half-plane, excluding the negative imaginary axis:
FunctionRange[Sqrt[x], x, y, Complexes]Limit[Sqrt[-2 + ε], ε -> 0, Direction -> I]Limit[Sqrt[-2 + ε], ε -> 0, Direction -> -I]Enter a √ character as 
sqrt
or \[Sqrt], followed by a number:
√-4
FunctionAnalytic[Sqrt[x], x]FunctionMeromorphic[Sqrt[x], x]
is neither non-decreasing nor non-increasing:
FunctionMonotonicity[Sqrt[x], x]However, it is increasing where it is real valued:
FunctionMonotonicity[Sqrt[x], x, NonNegativeReals, StrictInequalities -> True]
FunctionInjective[Sqrt[x], x]Plot[{Sqrt[x], 1}, {x, 0, 5}]FunctionSurjective[Sqrt[x], x]Plot[{Sqrt[x], -2}, {x, 0, 5}]
is non-negative on its domain of definition:
FunctionSign[Sqrt[x], x, NonNegativeReals]
has a branch cut singularity for 
:
FunctionSingularities[Sqrt[x], x]However, it is continuous at the origin:
FunctionContinuous[{Sqrt[x], x ≥ 0}, x]
is neither convex nor concave:
FunctionConvexity[Sqrt[x], x]However, it is concave where it is real valued:
FunctionConvexity[{Sqrt[x], x ≥ 0}, x]Differentiation (3)
The first derivative with respect to z:
D[Sqrt[z], z]Higher derivatives with respect to z:
Table[D[Sqrt[z], {z, k}], {k, 1, 4}]//FullSimplifyPlot the higher derivatives with respect to z:
Plot[%, {z, 0, 2}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative", "Fourth Derivative"}]Formula for the 
derivative with respect to z:
D[Sqrt[z], {z, k}]// FullSimplifyIntegration (3)
Compute the indefinite integral using Integrate:
Integrate[Sqrt[x], x]FullSimplify[D[%, x]]Integrate[Sqrt[x], {x, 0, 9}]Integrate[Sqrt[x] ^ a, x]Integrate[t ^ (α - 1)Sqrt[t + α], {t, 0, 1}, Assumptions -> Re[α] > 0]Series Expansions (4)
Find the Taylor expansion using Series:
Series[Sqrt[x], {x, 1, 4}]Plots of the first three approximations around 
:
terms = Normal@Table[Series[Sqrt[x], {x, 1, m}], {m, 1, 5, 2}];
Plot[{Sqrt[x], terms}, {x, -1, 3}]The general term in the series expansion using SeriesCoefficient:
SeriesCoefficient[Sqrt[x], {x, 1, n}]The first-order Fourier series:
FourierSeries[Sqrt[x], x, 1]// FullSimplifyThe Taylor expansion at a generic point:
Series[Sqrt[x], {x, x0, 2}]// FullSimplifyFunction Identities and Simplifications (4)
Sqrt[x] == Power[x, 1 / 2]Sqrt[x] == Exp[Log[x] / 2]
is not automatically replaced by 
:
Sqrt[x ^ 2]It can be simplified to 
if one assumes 
:
Simplify[Sqrt[x ^ 2], x > 0]It can be simplified to ![TemplateBox[{x}, Abs]](Files/Sqrt.en/49.png "TemplateBox[{x}, Abs]"){kind=small}
if one assumes ![x in TemplateBox[{}, Reals]](Files/Sqrt.en/50.png "x in TemplateBox[{}, Reals]"){kind=small}
:
Simplify[Sqrt[x ^ 2], x∈Reals]PowerExpand can be used to force cancellation without assumptions:
PowerExpand[Sqrt[x^2]]Expand assuming real variables x and y:
ComplexExpand[Sqrt[x + I y]]Applications (4)
Roots of a quadratic polynomial:
Reduce[a x ^ 2 + b x + c == 0, x]Generate periodic continued fractions:
ContinuedFraction[Sqrt[19]]ContinuedFraction[Sqrt[19], 20]ListPlot[%, Filling -> Axis]Solve a differential equation with Sqrt:
DSolve[ y[x] + (-1 + 2 x) Derivative[1][y][x] + 2 (-1 + x) x Derivative[2][y][x] == 1, y[x], x]Compute an elliptic integral from the Sqrt function:
Integrate[Sqrt[a x^3 + b], x]Properties & Relations (12)
Sqrt[x] and Surd[x,2] are the same for non-negative real values:
{Sqrt[4], Surd[4, 2]}For negative reals, Sqrt gives an imaginary result, whereas the real-valued Surd reports an error:
{Sqrt[-4], Surd[-4, 2]}
Reduce combinations of square roots:
RootReduce[Sqrt[2] + Sqrt[3]]Evaluate power series involving square roots:
Series[Sqrt[Sin[x]], {x, 0, 5}]Expand a complex square root assuming variables are real valued:
ComplexExpand[Sqrt[x + I y]]Factor polynomials with square roots in coefficients:
Expand[(x + Sqrt[2]) ^ 2]Factor[%, Extension -> Automatic]Simplify handles expressions involving square roots:
Simplify[Sqrt[1 + Sqrt[x ^ 2]], x > 0]There are many subtle issues in handling square roots for arbitrary complex arguments:
FunctionExpand[Sqrt[-z ^ 2]]PowerExpand expands forms involving square roots:
PowerExpand[Sqrt[x y], Assumptions -> True]It generically assumes that all variables are positive:
PowerExpand[Sqrt[x y]]Finite sums of integers and square roots of integers are algebraic numbers:
{1, Sqrt[2], 3 + Sqrt[5]}∈AlgebraicsTake limits accounting for branch cuts:
Limit[Sqrt[-1 + I x], x -> 0, Direction -> 1]Limit[Sqrt[-1 + I x], x -> 0, Direction -> -1]Sqrt can be represented as a DifferentialRoot:
DifferentialRootReduce[Sqrt[x], x]The generating function for Sqrt:
GeneratingFunction[Sqrt[n], n, x]Series[%, {x, 0, 10}]Possible Issues (3)
Square root is discontinuous across its branch cut along the negative real axis:
{Sqrt[-1 + 0.01I], Sqrt[-1 - 0.01I]}Plot3D[Im[Sqrt[x + I y]], {x, -1, 1}, {y, -1, 1}]Sqrt[x^2] cannot automatically be reduced to x:
Sqrt[x ^ 2]Sqrt[(-4) ^ 2]With x assumed positive, the simplification can be done:
Simplify[Sqrt[x ^ 2], x > 0]Use PowerExpand to do the formal reduction:
PowerExpand[Sqrt[x ^ 2]]Along the branch cut, these are not the same:
{1 / Sqrt[z], Sqrt[1 / z]} /. z -> -1Neat Examples (2)
Approximation to GoldenRatio:
Nest[Sqrt[1 + #]&, 1, 10]N[%]Riemann surface for square root:
ParametricPlot3D[{x ^ 2 - y ^ 2, 2x y, x}, {x, -1, 1}, {y, -1, 1}]
MathWorld
The Wolfram Functions Site
An Elementary Introduction to the Wolfram Language
NKS|OnlineText
Wolfram Research (1988), Sqrt, Wolfram Language function, https://reference.wolfram.com/language/ref/Sqrt.html (updated 1996).
CMS
Wolfram Language. 1988. "Sqrt." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 1996. https://reference.wolfram.com/language/ref/Sqrt.html.
APA
Wolfram Language. (1988). Sqrt. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Sqrt.html