WOLFRAM

Wolfram Language & System Documentation Center

ScorerGi[z]

gives the Scorer function TemplateBox[{z}, ScorerGi].

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Show More Show More
Function Properties  
Differentiation and Integration  
Series Expansions  
Function Identities and Simplifications  
See Also
Related Guides
History
Cite this Page

ScorerGi

ScorerGi[z]

gives the Scorer function TemplateBox[{z}, ScorerGi].

Details

  • ScorerGi is also known as an inhomogeneous Airy function.
  • Mathematical function, suitable for both symbolic and numeric manipulation.
  • The Scorer function TemplateBox[{z}, ScorerGi] is a solution to the inhomogeneous Airy differential equation .
  • TemplateBox[{z}, ScorerGi] tends to zero as .
  • ScorerGi[z] is an entire function of z with no branch cut discontinuities.
  • For certain arguments, ScorerGi automatically evaluates to exact values.
  • ScorerGi can be evaluated to arbitrary numerical precision.
  • ScorerGi automatically threads over lists.
  • ScorerGi can be used with Interval and CenteredInterval objects. »

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: ScorerGi[5.]

Plot over a subset of the reals:

Wolfram Language code: Plot[ScorerGi[x], {x, -10, 10}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[ScorerGi[z], {z, -2 - 2I, 2 + 2I}, PlotLegends -> Automatic]

Series expansion at the origin:

Wolfram Language code: Series[ScorerGi[x], {x, 0, 4}]//FullSimplify

Scope  (32)

Numerical Evaluation  (6)

Evaluate numerically:

Wolfram Language code: ScorerGi[5.]
Wolfram Language code: N[ScorerGi[Pi / 2]]

Evaluate to high precision:

Wolfram Language code: N[ScorerGi[1 / 3], 50]

The precision of the output tracks the precision of the input:

Wolfram Language code: ScorerGi[0.312785550000555523000]

Complex number inputs:

Wolfram Language code: ScorerGi[0.2 + I]
Wolfram Language code: N[ScorerGi[I Pi / 3]]

Evaluate efficiently at high precision:

Wolfram Language code: N[ScorerGi[Pi / 3`100]]//Timing
Wolfram Language code: N[ScorerGi[Pi / 3`10000]];//Timing

Compute worst-case guaranteed intervals using Interval and CenteredInterval objects:

Wolfram Language code: ScorerGi[Interval[{0.5, 0.6}]]
Wolfram Language code: ScorerGi[CenteredInterval[2, 1 / 100]]

Or compute average-case statistical intervals using Around:

Wolfram Language code: ScorerGi[Around[.9, 0.1]]

Compute the elementwise values of an array:

Wolfram Language code: ScorerGi[{{1.3, .5}, {0, 0.2}}]

Or compute the matrix ScorerGi function using MatrixFunction:

Wolfram Language code: MatrixFunction[ScorerGi[#]&, {{1.3, .5}, {0, 0.2}}]

Specific Values  (3)

Simple exact values are generated automatically:

Wolfram Language code: ScorerGi[0]

Limiting values at infinity:

Wolfram Language code: {Limit[ScorerGi[x], x -> Infinity], Limit[ScorerGi[x], x -> -Infinity]}

Find positive maximum of ScorerGi[x ]:

Wolfram Language code: xmax = x /. FindRoot[D[ScorerGi[x ], x] == 0, {x, 1}]
Wolfram Language code: Plot[ScorerGi[x ], {x, -5, 5}, Epilog -> Style[Point[{xmax, ScorerGi[xmax ]}], PointSize[Large], Red]]

Visualization  (2)

Plot the ScorerGi function:

Wolfram Language code: Plot[ScorerGi[x], {x, -10, 10}]

Plot the real part of TemplateBox[{z}, ScorerGi]:

Wolfram Language code: ComplexContourPlot[Re[ScorerGi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 24]

Plot the imaginary part of TemplateBox[{z}, ScorerGi]:

Wolfram Language code: ComplexContourPlot[Im[ScorerGi[z]], {z, -4 - 4I, 4 + 4I}, Contours -> 24]

Function Properties  (11)

Real domain of ScorerGi:

Wolfram Language code: FunctionDomain[ScorerGi[x], x]

Complex domain:

Wolfram Language code: FunctionDomain[ScorerGi[z], z, Complexes]

Approximate function range of ScorerGi:

Wolfram Language code: FunctionRange[ScorerGi[x], x, y]//Quiet

ScorerGi threads elementwise over lists:

Wolfram Language code: ScorerGi[{-1., 1., 2.}]

ScorerGi is an analytic function of x:

Wolfram Language code: FunctionAnalytic[ScorerGi[x], x]

ScorerGi is neither nondecreasing nor nonincreasing:

Wolfram Language code: FunctionMonotonicity[ScorerGi[x], x]

ScorerGi is not injective:

Wolfram Language code: FunctionInjective[ScorerGi[x], x]
Wolfram Language code: Plot[{ScorerGi[x], 0.22}, {x, -10, 10}]

ScorerGi is not surjective:

Wolfram Language code: FunctionSurjective[ScorerGi[x], x]
Wolfram Language code: Plot[{ScorerGi[x], .5}, {x, -10, 10}]

ScorerGi is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[ScorerGi[x], x]

ScorerGi does not have singularity or discontinuity:

Wolfram Language code: FunctionSingularities[ScorerGi[x], x]
Wolfram Language code: FunctionDiscontinuities[ScorerGi[x], x]

ScorerGi is neither convex nor concave:

Wolfram Language code: FunctionConvexity[ScorerGi[x], x]

TraditionalForm typesetting:

Wolfram Language code: ScorerGi[z]//TraditionalForm

Differentiation and Integration  (5)

First derivative with respect to z:

Wolfram Language code: D[ScorerGi[z] , z]

Higher derivatives with respect to z

Wolfram Language code: Table[D[ScorerGi[z], {z, k}], {k, 1, 3}]//Simplify

Plot the higher derivatives with respect to z:

Wolfram Language code: Plot[%, {z, -10, 10}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Formula for the ^(th) derivative with respect to z:

Wolfram Language code: D[ScorerGi[z], {z, k}]// FullSimplify

Indefinite integral of ScorerGi:

Wolfram Language code: Integrate[ScorerGi[x], x]//FullSimplify

More integrals:

Wolfram Language code: ∫ z^αScorerGi[z^2]ⅆz//TraditionalForm
Wolfram Language code: ∫ ScorerGi[z]ScorerGiPrime[z]ⅆz//TraditionalForm

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[ScorerGi[x], {x, 0, 3}]

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[ScorerGi[x], {x, 0, m}], {m, 1, 5, 2}]; Plot[{ScorerGi[x], terms}, {x, -10, 10}, PlotRange -> {-2, 2}]

Taylor expansion at a generic point:

Wolfram Language code: Series[ScorerGi[x], {x, x0, 2}]// FullSimplify

Function Identities and Simplifications  (3)

FunctionExpand tries to simplify the argument of ScorerGi:

Wolfram Language code: FunctionExpand[ScorerGi[z E^2 π I]]//Simplify
Wolfram Language code: FunctionExpand[ScorerGi[(z^2)^1 / 2]]//Simplify

Functional identity:

Wolfram Language code: ScorerGi[z] + E^2 π I ScorerGi[z E^2 π I] + E^-2 π I ScorerGi[z E^-2 π I]//FullSimplify

ScorerGi can be represented as a DifferentialRoot:

Wolfram Language code: DifferentialRootReduce[ScorerGi[x], x]
Wolfram Research (2014), ScorerGi, Wolfram Language function, https://reference.wolfram.com/language/ref/ScorerGi.html.

Text

Wolfram Research (2014), ScorerGi, Wolfram Language function, https://reference.wolfram.com/language/ref/ScorerGi.html.

CMS

Wolfram Language. 2014. "ScorerGi." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ScorerGi.html.

APA

Wolfram Language. (2014). ScorerGi. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ScorerGi.html

BibTeX

@misc{reference.wolfram_2026_scorergi, author="Wolfram Research", title="{ScorerGi}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ScorerGi.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_scorergi, organization={Wolfram Research}, title={ScorerGi}, year={2014}, url={https://reference.wolfram.com/language/ref/ScorerGi.html}, note=[Accessed: 12-June-2026]}