WOLFRAM

Wolfram Language & System Documentation Center

SemanticSearch[index,query]

finds the items similar to query inside index.

SemanticSearch[index,query->f]

filters the results using the function f.

SemanticSearch[index,query,prop]

returns the specified property prop.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Options  
MaxItems  
RerankingMethod  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

SemanticSearch

SemanticSearch[index,query]

finds the items similar to query inside index.

SemanticSearch[index,query->f]

filters the results using the function f.

SemanticSearch[index,query,prop]

returns the specified property prop.

Details and Options

  • SemanticSearch performs a search on the semantic index using a query to find and retrieve similar text items.
  • Valid index specifications are:
  • "name"a string matching a named semantic search index
    SemanticSearchIndex[…]a valid SemanticSearchIndex object
  • The input to the function f is the same annotation specified when the index was created.
  • Possible values for prop include:
  • "Distance"distance between the encoded query and item
    "Item"item that matches "query" (default)
    "ItemEmbedding"encoded item
    "Label"item label
    "Query"specified query
    "QueryEmbedding"encoded query
    "Tags"item tags
    "Tags""tag"a single item tag
    "Tags"{"tag1",…}multiple item tags
    {prop1,…}a list of properties
    Allan Association with all the properties
  • The following options can be given:
  • MaxItems 10how many items are returned
    ProgressReporting$ProgressReportingwhether to display progress information
    RerankingMethod Automatichow to reorder items once retrieved
  • Values for the RerankingMethod include:
  • Automaticdefault reranking
    Noneno reranking
    Tiny, Small, Medium, Largepredefined model sizes
    "string"a generic SemanticRanking model
    {"string",size}a specific-sized SemanticRanking model
    fa custom reranking function
    <|opt1 val1,…|>detailed options specifying reranking parameters
  • A custom ranker f must operate on the reference string and a list of strings to produce a vector of the same length.
  • Detailed options for the RerankingMethod include:
  • "Function"SemanticRankingfunction ranking the candidate items
    "MaxItemMultiplier"2multiple of MaxItems provided as candidates
    "MinItems"10minimum number of candidate items
    "Query"Automaticquery string used for ranking
    "Target""Item"which property prop the function operates on
  • With "Query"Automatic, the input query is used for the reranking as well.
  • When reranking with "MinItems"min, "MaxItemMultiplier"k and MaxItemsmax, the initial number of candidate items is Max[min,k*max].

Examples

open all close all

Basic Examples  (1)

Create a SemanticSearchIndex:

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"]]

Extract the most relevant quote from Alice in Wonderland:

Wolfram Language code: SemanticSearch[index, "Off with their heads", MaxItems -> 1]

Scope  (3)

Create a SemanticSearchIndex with a single source:

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"]]

Find index items closest to a given query:

Wolfram Language code: Snippet /@ SemanticSearch[index, "Talking insects", MaxItems -> 3]

Get a list of available result properties:

Wolfram Language code: SemanticSearch[index, "Talking insects", "Properties"]

Extract a specific item property:

Wolfram Language code: SemanticSearch[index, "Talking insects", "Distance"]

Get multiple properties:

Wolfram Language code: SemanticSearch[index, "Talking insects", {"Item", "Distance"}, MaxItems -> 2]//Short

Retrieve all available properties:

Wolfram Language code: Short@SemanticSearch[index, "Talking insects", All, MaxItems -> 2]

Define an index with labeled sources:

Wolfram Language code: index = CreateSemanticSearchIndex[{WikipediaData["cat"] -> "cat", WikipediaData["dog"] -> "dog"}]

The label is automatically returned when searching:

Wolfram Language code: SemanticSearch[index, "sense of smell"]

Return the item instead:

Wolfram Language code: Snippet /@ SemanticSearch[index, "sense of smell", "Item"]

Return the item and the label:

Wolfram Language code: Short /@ SemanticSearch[index, "sense of smell", {"Label", "Item"}, MaxItems -> 2]

Filter to only search items with a specific label:

Wolfram Language code: SemanticSearch[index, "sense of smell" -> MatchQ["dog"]]

Define an index with tagged sources:

Wolfram Language code: index = CreateSemanticSearchIndex[{WikipediaData["wolfram"] -> <|"Website" -> "Wikipedia", "Date" -> DateObject[{2024, 7, 25}, "Day"]|>, URL["https://www.wolfram.com"] -> <|"Website" -> "Wolfram", "Date" -> DateObject[{2024, 6, 12}, "Day"]|>}]

The tags are automatically returned when searching:

Wolfram Language code: SemanticSearch[index, "wolfram language"]

Return a specific tag value:

Wolfram Language code: SemanticSearch[index, "wolfram language", "Tags" -> "Website"]

Return multiple tags:

Wolfram Language code: SemanticSearch[index, "wolfram language", "Tags" -> {"Website", "Date"}]

Return tags and other properties:

Wolfram Language code: SemanticSearch[index, "wolfram language", {"Distance", "Tags" -> "Website"}]

Filter for a specific tag value:

Wolfram Language code: SemanticSearch[index, "wolfram language" -> Function[#Website == "Wolfram"]]

Options  (5)

MaxItems  (1)

By default, up to 10 items are returned:

Wolfram Language code: index = CreateSemanticSearchIndex@ResourceData["Alice in Wonderland"]
Wolfram Language code: SemanticSearch[index, "cat"]//Length

Set a custom number of items:

Wolfram Language code: SemanticSearch[index, "cat", MaxItems -> 2]//Length

RerankingMethod  (4)

Search with automatic reranking:

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"]]
Wolfram Language code: AbsoluteTiming@First@SemanticSearch[index, "Why was Alice falling?"]

Disabling reranking can make the results faster but may degrade results:

Wolfram Language code: AbsoluteTiming@First@SemanticSearch[index, "Why was Alice falling?", RerankingMethod -> None]

Specify a custom reranking method as a function of the items:

Wolfram Language code: First@SemanticSearch[index, "Talking animals", RerankingMethod -> (-StringLength[#1]&)]

Specify the reranker as a function of the items and the query:

Wolfram Language code: First@SemanticSearch[index, "Caterpillar", RerankingMethod -> (StringCount[#1, #2, IgnoreCase -> True]&)]

Reranking defaults to a minimum of 10 candidate items retrieved from the database, then returns the requested number of MaxItems:

Wolfram Language code: index = CreateSemanticSearchIndex[{ "Jellyfish drift with ocean currents.", "Starfish regenerate lost body parts.", "Crayfish dig burrows in mud.", "Cuttlefish change color for camouflage.", "Silverfish infest homes, eating paper.", "Salmon migrate upstream to spawn.", "Starfish live on ocean floors.", "Shellfish create shells from calcium." }]
Wolfram Language code: SemanticSearch[index, "Fish", MaxItems -> 1]

Disabling reranking will give the first result from the initial search:

Wolfram Language code: SemanticSearch[index, "Fish", RerankingMethod -> None, MaxItems -> 1]

Reduce the minimum number of candidate items provided to the reranker:

Wolfram Language code: SemanticSearch[index, "Fish", RerankingMethod -> <|"MinItems" -> 2|>, MaxItems -> 1]

The number of candidates is calculated by taking the larger of "MinItems" and the product of the "MaxItemMultiplier" method option and the specified number of MaxItems:

Wolfram Language code: SemanticSearch[index, "Fish", RerankingMethod -> <|"MinItems" -> 2, "MaxItemMultiplier" -> 4|>, MaxItems -> 1]

Create an index with tags corresponding to the frequency of words in the text:

Wolfram Language code: words = KeyValueMap[#1 -> <|"Count" -> #2 /. _Missing -> 0|>&, WordCounts[ResourceData["Alice in Wonderland"]]]; Short[words]
Wolfram Language code: index = CreateSemanticSearchIndex[words]

Default sorting gives close matches, but the first match may be obscure or only mentioned a few times in the text:

Wolfram Language code: SemanticSearch[index, "Rabbits", "Items", RerankingMethod -> Automatic]

Rerank based on the most prevalent words:

Wolfram Language code: SemanticSearch[index, "Rabbits", "Items", RerankingMethod -> <|"Function" -> (#[[All, "Count"]]&), "Target" -> "Tags"|>]

Create an index:

Wolfram Language code: index = CreateSemanticSearchIndex[ResourceData["Alice in Wonderland"]]

Use a custom question when reranking to further refine the results:

Wolfram Language code: First@SemanticSearch[index, "Talking animals", "RerankingMethod" -> <|"Query" -> "A cat that grins"|>]

Applications  (4)

Search Shakespeare's sonnets using partial quotes. Use a manual splitting of the text to group each sonnet together with its number:

Wolfram Language code: sonnets = StringSplit[ResourceData["Shakespeare's Sonnets"], WordBoundary ~~ ("I" | "V" | "X" | "L" | "C").. ~~ " "]; Short[sonnets]

Then label each sonnet with its number:

Wolfram Language code: sonnets = MapIndexed[#1 -> First[#2] &, sonnets];

Create a index using the labeled sonnets:

Wolfram Language code: index = CreateSemanticSearchIndex[sonnets, "Sonnets", "Method" -> {"SplitPattern" -> None, "MaximumItemLength" -> Infinity}]

Retrieve sonnets and their number using a partial quote:

Wolfram Language code: SemanticSearch[index, "summer's day", {"Item", "Label"}, MaxItems -> 1]

Look for a vaguely remembered sonnet:

Wolfram Language code: SemanticSearch[index, "About marriage and inspiration", {"Item", "Label"}, MaxItems -> 1]

Retrieve the index of the Wolfram Function Repository:

Wolfram Language code: index = ResourceData["Semantic Index of Wolfram Function Repository Documentation"]

Search for custom functions that can generate a graphic of the solar system:

Wolfram Language code: DeleteDuplicates[SemanticSearch[index, "Generate a graphic of the solar system"]]

Search for a specific example in the given function:

Wolfram Language code: SemanticSearch[index, "The position of a comet" -> MatchQ["SolarSystemPlot3D"], "Items", MaxItems -> 1]

Run the example function from the given item:

Wolfram Language code: ResourceFunction["SolarSystemPlot3D"][{Red, Sphere[Entity["Comet", "Comet1PHalley"], 1]}]

Create an index from a set of books:

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"] -> "Alice in Wonderland", ResourceData["The Wind in the Willows"] -> "The Wind in the Willows", ResourceData["The Jungle Book"] -> "The Jungle Book"}]

Find some examples on a topic of interest:

Wolfram Language code: passages = SemanticSearch[index, "Talking animals", {"Label", "Item"}]; Short[passages]

Use LLMSynthesize to give a summary contrasting the differences:

Wolfram Language code: LLMSynthesize[StringJoin["Write a short paragraph contrasting the differences between talking animals in these passages. Use direct quotes when possible: ", ToString[passages]]]

Create an index containing German and English text:

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Death in Venice"], ResourceData["Alice in Wonderland"]}]

The embeddings of the same meanings are similar across languages. Search in English for information in the German source:

Wolfram Language code: result = SemanticSearch[index, "What does Gustav von Aschenbach look like?", MaxItems -> 1]

Translate the result into English:

Wolfram Language code: LLMSynthesize[LLMPrompt["Translate"]["English", result]]

Properties & Relations  (3)

When performing a search, the distance function specified in CreateSemanticSearchIndex is used:

Wolfram Language code: index = CreateSemanticSearchIndex[{ResourceData["Alice in Wonderland"]}, "DistanceFunction" -> CosineDistance]
Wolfram Language code: SemanticSearch[index, "What did the rabbit wear?", "MaxItems" -> 1]

The distance function setting can be retrieved from the VectorDatabaseObject backing the index:

Wolfram Language code: index["Database"]["DistanceFunction"]

Create a index with labels:

Wolfram Language code: index = CreateSemanticSearchIndex[{WikipediaData["cat"] -> "cat", WikipediaData["dog"] -> "dog"}]

Items will always share the tag of their source:

Wolfram Language code: SemanticSearch[index, "wolfram language", "Label"]

To get list of source tags, use unique tags and DeleteDuplicates:

Wolfram Language code: DeleteDuplicates[SemanticSearch[index, "wolfram language", "Label"]]

SemanticSearch automatically reranks the results using SemanticRanking:

Wolfram Language code: index = CreateSemanticSearchIndex[{ "Jellyfish drift with ocean currents.", "Starfish regenerate lost body parts.", "Crayfish dig burrows in mud.", "Cuttlefish change color for camouflage.", "Silverfish infest homes, eating paper.", "Salmon migrate upstream to spawn.", "Starfish live on ocean floors.", "Shellfish create shells from calcium." }]
Wolfram Language code: query = "Fish" semanticSearchReranked = SemanticSearch[index, query, MaxItems -> 5]

This is the equivalent of retrieving 10 results without reranking (the default "MinItems" for reranking):

Wolfram Language code: extendedResults = SemanticSearch[index, query, MaxItems -> 10, RerankingMethod -> None]

Then taking the first five results of the results after using SemanticRanking:

Wolfram Language code: rankingResults = SemanticRanking[extendedResults, query][[1 ;; 5]]
Wolfram Language code: semanticSearchReranked === rankingResults
Wolfram Research (2024), SemanticSearch, Wolfram Language function, https://reference.wolfram.com/language/ref/SemanticSearch.html (updated 2025).

Text

Wolfram Research (2024), SemanticSearch, Wolfram Language function, https://reference.wolfram.com/language/ref/SemanticSearch.html (updated 2025).

CMS

Wolfram Language. 2024. "SemanticSearch." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2025. https://reference.wolfram.com/language/ref/SemanticSearch.html.

APA

Wolfram Language. (2024). SemanticSearch. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SemanticSearch.html

BibTeX

@misc{reference.wolfram_2026_semanticsearch, author="Wolfram Research", title="{SemanticSearch}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/SemanticSearch.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_semanticsearch, organization={Wolfram Research}, title={SemanticSearch}, year={2025}, url={https://reference.wolfram.com/language/ref/SemanticSearch.html}, note=[Accessed: 13-June-2026]}