WOLFRAM

Wolfram Language & System Documentation Center

SpheroidalS1[n,m,γ,z]

gives the radial spheroidal function of the first kind.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Numerical Evaluation  
Specific Values  
Visualization  
Function Properties  
Differentiation  
Series Expansions  
Applications  
Possible Issues  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

SpheroidalS1

SpheroidalS1[n,m,γ,z]

gives the radial spheroidal function of the first kind.

Details

  • Mathematical function, suitable for both symbolic and numerical manipulation.
  • The radial spheroidal functions satisfy the differential equation with the spheroidal eigenvalue given by SpheroidalEigenvalue[n,m,γ].
  • The are normalized according to the Meixner–Schäfke scheme.
  • SpheroidalS1 can be evaluated to arbitrary numerical precision.
  • SpheroidalS1 automatically threads over lists. »

Examples

open all close all

Basic Examples  (4)

Evaluate numerically:

Wolfram Language code: SpheroidalS1[1, 0, 2.5, 1]

Plot over a subset of the reals:

Wolfram Language code: Plot[SpheroidalS1[1, 0, 2, x], {x, -6, 6}]

Plot over a subset of the complexes:

Wolfram Language code: ComplexPlot3D[SpheroidalS1[1, 0, 2, z], {z, -1 - I, 1 + I}, PlotLegends -> Automatic]

Series expansion at a singular point:

Wolfram Language code: Series[SpheroidalS1[1, 1, π / 2, x], {x, 1, 6}]//Normal//FullSimplify

Scope  (21)

Numerical Evaluation  (5)

Evaluate numerically:

Wolfram Language code: SpheroidalS1[5, 1, .1, .3]
Wolfram Language code: SpheroidalS1[1, 0, 1.5, 2]

Evaluate to high precision:

Wolfram Language code: N[SpheroidalS1[7, 5, 1, 2], 50]//Chop
Wolfram Language code: N[SpheroidalS1[2, 1, 1 / 3, -11], 20]

The precision of the output tracks the precision of the input:

Wolfram Language code: SpheroidalS1[2, 2, 1 / 3, 0.211111111111111111]//Chop
Wolfram Language code: SpheroidalS1[2, 0.211111111111111000111, 5, 6]

Complex number inputs:

Wolfram Language code: N[SpheroidalS1[23, 5 - I, 2, I]]

Evaluate efficiently at high precision:

Wolfram Language code: SpheroidalS1[31, 5, 1, 2`100]//Timing
Wolfram Language code: SpheroidalS1[15, 5, 1, 5`1000];//Timing

Compute the elementwise values of an array using automatic threading:

Wolfram Language code: SpheroidalS1[1, 0, .2, {{1.3, .5}, {0, 0.2}}]

Or compute the matrix SpheroidalS1 function using MatrixFunction:

Wolfram Language code: MatrixFunction[SpheroidalS1[1, 0, .2, #]&, {{1.3, .5}, {0, 0.2}}]

Specific Values  (4)

Simple exact values are generated automatically:

Wolfram Language code: Table[SpheroidalS1[1, 1, π / 2, x], {x, -1 / 2, 3 / 2}]

Find the first positive maximum of SpheroidalS1[2,0,5,x]:

Wolfram Language code: xmax = x /. FindRoot[D[SpheroidalS1[2, 0, 5, x], x] == 0, {x, .5}]//Chop
Wolfram Language code: Plot[SpheroidalS1[2, 0, 5, x], {x, 0, 3}, Epilog -> Style[Point[{xmax, SpheroidalS1[2, 0, 5, xmax ]}], PointSize[Large], Red]]

SpheroidalS1 functions become elementary if m=1 and γ=n π/2 :

Wolfram Language code: Table[SpheroidalS1[n, 1, n π / 2, x], {n, 1, 3}]//FullSimplify

TraditionalForm typesetting:

Wolfram Language code: SpheroidalS1[n, m, c, η]//TraditionalForm

Visualization  (3)

Plot the SpheroidalS1 function for integer orders:

Wolfram Language code: Plot[{SpheroidalS1[1, 0, 2, x], SpheroidalS1[2, 0, 2, x], SpheroidalS1[3, 0, 2, x]}, {x, -10, 10}]

Plot the SpheroidalS1 function for noninteger parameters:

Wolfram Language code: Plot[{SpheroidalS1[1, 0, 1 / 2, x], SpheroidalS1[2, 0, 1 / 2, x], SpheroidalS1[3, 0, 1 / 2, x]}, {x, -10, 10}]

Plot the real part of TemplateBox[{2, 0, 1, z}, SpheroidalS1]:

Wolfram Language code: ComplexContourPlot[Re[SpheroidalS1[2, 0, 1, z]], {z, -4 - 6 I, 4 + 6 I}, Contours -> 20]

Plot the imaginary part of TemplateBox[{2, 0, 1, z}, SpheroidalS1]:

Wolfram Language code: ComplexContourPlot[Im[SpheroidalS1[2, 0, 1, z]], {z, -4 - 6 I, 4 + 6 I}, Contours -> 20]

Function Properties  (5)

SpheroidalS1 is not an analytic function:

Wolfram Language code: FunctionAnalytic[SpheroidalS1[1, 1, π / 2, x], x]

TemplateBox[{1, 2, {pi, /, 2}, x}, SpheroidalS1] has both singularities and discontinuities for :

Wolfram Language code: FunctionSingularities[SpheroidalS1[1, 2, π / 2, x], x]//Quiet
Wolfram Language code: FunctionDiscontinuities[SpheroidalS1[1, 2, π / 2, x], x]//Quiet

TemplateBox[{1, 2, {pi, /, 2}, x}, SpheroidalS1] is neither non-decreasing nor non-increasing:

Wolfram Language code: FunctionMonotonicity[SpheroidalS1[1, 1, π / 2, x], x]

TemplateBox[{1, 2, {pi, /, 2}, x}, SpheroidalS1] is not injective:

Wolfram Language code: FunctionInjective[SpheroidalS1[1, 1, π / 2, x], x]
Wolfram Language code: Plot[{SpheroidalS1[1, 1, π / 2, x], .3}, {x, -6, 6}]

SpheroidalS1 is neither non-negative nor non-positive:

Wolfram Language code: FunctionSign[SpheroidalS1[1, 1, π / 2, x], x]

SpheroidalS1 is neither convex nor concave:

Wolfram Language code: FunctionConvexity[SpheroidalS1[1, 1, π / 2, x], x]

Differentiation  (2)

First derivative with respect to z:

Wolfram Language code: D[SpheroidalS1[n, m, γ, z], z]

Higher derivatives with respect to z:

Wolfram Language code: Table[D[SpheroidalS1[n, m, γ, z], {z, k}], {k, 1, 3}]//FullSimplify

Plot the higher derivatives with respect to z when n=10, m=2 and γ=1/3:

Wolfram Language code: Plot[Evaluate[% /. { n -> 10, m -> 2, γ -> 1 / 3}], {z, -3, 3}, PlotLegends -> {"First Derivative", "Second Derivative", "Third Derivative"}]

Series Expansions  (2)

Find the Taylor expansion using Series:

Wolfram Language code: Series[SpheroidalS1[n, m, γ, x], {x, 0, 3}]//Normal

Plots of the first three approximations around :

Wolfram Language code: terms = Normal@Table[Series[SpheroidalS1[2, 0, 1, x], {x, 0, m}], {m, 1, 5, 2}]//N; Plot[{SpheroidalS1[2, 0, 1, x], terms}, {x, 0, 4}, MaxRecursion -> 1]//Quiet

Taylor expansion at a generic point:

Wolfram Language code: Series[SpheroidalS1[n, m, γ, x], {x, x0, 2}]// Normal//FullSimplify

Applications  (4)

Spheroidal angular harmonics are eigenfunctions of the Sinc transform on the interval :

Wolfram Language code: Integrate[Sinc[c (t - x)]SpheroidalPS[2, 0, c, x], {x, -1, 1}]

Plot the eigenvalue:

Wolfram Language code: Plot[SpheroidalS1[2, 0, c, 1] ^ 2, {c, 1, 20}]

Find resonant frequencies for the Dirichlet problem in the prolate spheroidal cavity:

Wolfram Language code: Plot[SpheroidalS1[0, 0, k / (2 3^1 / 3) , 3], {k, 0, 20}, PlotPoints -> 20]

Determine the first few frequencies:

Wolfram Language code: FindRoot[SpheroidalS1[0, 0, k / (2 3^1 / 3) , 3], {k, 2, 5}, WorkingPrecision -> 50]
Wolfram Language code: FindRoot[SpheroidalS1[0, 0, k / (2 3^1 / 3) , 3], {k, 5, 8}, WorkingPrecision -> 50]

Plot the prolate and oblate functions:

Wolfram Language code: Plot[SpheroidalS1[2, 0, 10, r], {r, 1, 4}]
Wolfram Language code: Plot[SpheroidalS1[2, 0, -10 I, I r], {r, 0, 4}]

Build a near-spherical approximation to :

Wolfram Language code: nsLimitS1[n_, m_, z_, {c_, ord_Integer}] := (Normal[Series[SpheroidalPS[n1, -m1, c, x], {c, 0, ord}] /. LegendreP[k_, -m1, 2, x] :> SphericalBesselJ[k, z]](1 - c ^ 2 / z ^ 2)^m / 2 / SpheroidalRadialFactor[n, -m, c]) /. {n1 -> n, m1 -> m}

First few terms of the approximation:

Wolfram Language code: nsLimitS1[n, m, z, {c, 3}]//TraditionalForm

Compare numerically:

Wolfram Language code: (Table[nsLimitS1[3, 1, 1`30, {c, k}], {k, 2, 10, 2}] - SpheroidalS1[3, 1, c, 1 / c]) /. {c -> 1 / 100}

Possible Issues  (1)

Spheroidal functions do not evaluate for half-integer values of n and generic values of m:

Wolfram Language code: SpheroidalS1[3 / 2, 1, 1, 0.5]
Wolfram Research (2007), SpheroidalS1, Wolfram Language function, https://reference.wolfram.com/language/ref/SpheroidalS1.html.

Text

Wolfram Research (2007), SpheroidalS1, Wolfram Language function, https://reference.wolfram.com/language/ref/SpheroidalS1.html.

CMS

Wolfram Language. 2007. "SpheroidalS1." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SpheroidalS1.html.

APA

Wolfram Language. (2007). SpheroidalS1. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SpheroidalS1.html

BibTeX

@misc{reference.wolfram_2026_spheroidals1, author="Wolfram Research", title="{SpheroidalS1}", year="2007", howpublished="\url{https://reference.wolfram.com/language/ref/SpheroidalS1.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_spheroidals1, organization={Wolfram Research}, title={SpheroidalS1}, year={2007}, url={https://reference.wolfram.com/language/ref/SpheroidalS1.html}, note=[Accessed: 13-June-2026]}