WOLFRAM

Wolfram Language & System Documentation Center

SystemModelReliability[model]

retrieves the lifetime distribution for model.

SystemModelReliability[model,"Components"]

gives a list of components in ReliabilityDistribution or FailureDistribution.

SystemModelReliability[model,"ComponentRules"]

gives a list of translation rules for components.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
Related Links
History
Cite this Page

SystemModelReliability

SystemModelReliability[model]

retrieves the lifetime distribution for model.

SystemModelReliability[model,"Components"]

gives a list of components in ReliabilityDistribution or FailureDistribution.

SystemModelReliability[model,"ComponentRules"]

gives a list of translation rules for components.

Details

Examples

open all close all

Basic Examples  (3)

Retrieve the lifetime distribution for a model, in this case a ReliabilityDistribution:

Wolfram Language code: SystemModelReliability[[image]]

Retrieve the lifetime distribution for a model:

Wolfram Language code: dist = SystemModelReliability[[image]];

Plot the survival function to see the likelihood a system works after a certain time:

Wolfram Language code: Plot[SurvivalFunction[dist, t], {t, 0, 3}]

Component names from the model are shortened:

Wolfram Language code: model = [image];
Wolfram Language code: dist = SystemModelReliability[model]

Retrieve rules that show the mapping to the original names from the model:

Wolfram Language code: SystemModelReliability[model, "ComponentRules"]

Scope  (3)

Compare the lifetimes between a parallel and a serial system:

Wolfram Language code: parallel = SystemModelReliability["DocumentationExamples.Basic.Parallel"];
Wolfram Language code: serial = SystemModelReliability["DocumentationExamples.Basic.Serial"];

Survival functions show a higher probability of functioning for the parallel system at any time:

Wolfram Language code: Plot[{SurvivalFunction[parallel, t], SurvivalFunction[serial, t]}, {t, 0, 3}, PlotLegends -> {"Parallel", "Serial"}]

Compute the expected lifetime for a system:

Wolfram Language code: dist = SystemModelReliability[[image]];

The expected lifetime is often called the mean time to failure:

Wolfram Language code: mttf = Mean[dist]

Analyze how structurally important components are for system reliability:

Wolfram Language code: model = [image];
Wolfram Language code: dist = SystemModelReliability[model];

Retrieve the original component names:

Wolfram Language code: names = SystemModelReliability[model, "Components"]

Looking at system structure, the EMF, inductor and inertia are the most important for reliability:

Wolfram Language code: BarChart[{StructuralImportance[dist]}, ChartLegends -> names]

Applications  (4)

Study the reliability of an electric motor:

Wolfram Language code: model = [image];

Retrieve the lifetime distribution, where the system works if one of the resistors works:

Wolfram Language code: dist = SystemModelReliability[model]

Show the probability of survival over time:

Wolfram Language code: Plot[SurvivalFunction[dist, t], {t, 0, 10}, PlotRange -> {0, 1}, Filling -> Axis]

Compute the mean time to failure:

Wolfram Language code: Mean[dist]

Retrieve the original component names referenced in the ReliabilityDistribution:

Wolfram Language code: componentNames = SystemModelReliability[model, "Components"]

Show how structurally important each component is for reliability:

Wolfram Language code: PieChart[StructuralImportance[dist], ChartLegends -> componentNames]

Analyze how important components are for system reliability:

Wolfram Language code: model = [image];
Wolfram Language code: dist = SystemModelReliability[model];

The mean time to failure for this model:

Wolfram Language code: mttf = Mean[dist]

BirnbaumImportance shows that the EMF component is the most important for reliability:

Wolfram Language code: names = SystemModelReliability[model, "Components"]
Wolfram Language code: Plot[Evaluate@BirnbaumImportance[dist, t], {t, 0, 10}, Filling -> Axis, PlotLegends -> names]

Compare with a model where the EMF component has been improved:

Wolfram Language code: hardmodel = [image];
Wolfram Language code: harddist = SystemModelReliability[hardmodel];

The mean system lifetime has improved around 11%:

Wolfram Language code: hardmttf = Mean[harddist]
Wolfram Language code: hardmttf / mttf

Model the reliability of an uninterruptible power supply (UPS) setup:

Wolfram Language code: model = [image];

Power is supplied from the utility through power lines, or from a battery through an inverter:

Wolfram Language code: dist = SystemModelReliability[model];

Compute the mean time to failure (MTTF) and convert it to years:

Wolfram Language code: mttf = Mean[dist]//N;
Wolfram Language code: UnitConvert[Quantity[mttf, "Hours"], "Years"]

Compare with a version of the same system with hardened components:

Wolfram Language code: modelhard = [image];
Wolfram Language code: disthard = SystemModelReliability[modelhard];

The MTTF for the hardened system is significantly higher:

Wolfram Language code: mttfhard = Mean[disthard]//N;
Wolfram Language code: UnitConvert[Quantity[mttfhard, "Hours"], "Years"]

Compute the two survival functions:

Wolfram Language code: {s, shard} = Map[SurvivalFunction, {dist, disthard}];

Show the survival functions for the two systems, indicating the different MTTF:

Wolfram Language code: Plot[{s[t], shard[t]}, {t, 0, 110000}, PlotRange -> {0, 1}, Filling -> Axis, Epilog -> {Red, Thick, Line[{{mttf, 0}, {mttf, s[mttf]}}], Line[{{mttfhard, 0}, {mttfhard, shard[mttfhard]}}]}, PlotLegends -> {"Standard", "Hardened"}, ImageSize -> Medium]

Model how failures impact system performance. A resistor in a DC motor fails at time 20, another at time 35:

Wolfram Language code: sim = SystemModelSimulate[[image]]

One resistor failure decreases motor speed; two failures make the motor fail completely:

Wolfram Language code: SystemModelPlot[sim, "inertia1.w", PlotRange -> All, GridLines -> {{20, 35}}, GridLinesStyle -> Directive[Red, Thick]]

Properties & Relations  (1)

Component names are changed when retrieving a system lifetime distribution:

Wolfram Language code: model = [image];
Wolfram Language code: SystemModelReliability[model]

Retrieve the translation rules applied:

Wolfram Language code: SystemModelReliability[model, "ComponentRules"]

Retrieve just the original names, in the same order as referenced in the system distribution:

Wolfram Language code: SystemModelReliability[model, "Components"]
Wolfram Research (2018), SystemModelReliability, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemModelReliability.html.

Text

Wolfram Research (2018), SystemModelReliability, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemModelReliability.html.

CMS

Wolfram Language. 2018. "SystemModelReliability." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SystemModelReliability.html.

APA

Wolfram Language. (2018). SystemModelReliability. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemModelReliability.html

BibTeX

@misc{reference.wolfram_2026_systemmodelreliability, author="Wolfram Research", title="{SystemModelReliability}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/SystemModelReliability.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemmodelreliability, organization={Wolfram Research}, title={SystemModelReliability}, year={2018}, url={https://reference.wolfram.com/language/ref/SystemModelReliability.html}, note=[Accessed: 12-June-2026]}