WOLFRAM

Wolfram Language & System Documentation Center

SystemsModelDelayApproximate[sys,ord]

gives a delay-free system by using approximations of order ord of the time delays in system sys.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Generalizations & Extensions  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

SystemsModelDelayApproximate

SystemsModelDelayApproximate[sys,ord]

gives a delay-free system by using approximations of order ord of the time delays in system sys.

Details and Options

  • The system can be either a StateSpaceModel or a TransferFunctionModel.
  • For continuous-time systems, delays are approximated using PadeApproximant with order ord.
  • For discrete-time systems, delays are approximated poles for the integer part of the delay and a Thiran all-pass filter of order ord for the fractional part of the delay.

Examples

open all close all

Basic Examples  (2)

Approximate a StateSpaceModel with an input delay:

Wolfram Language code: SystemsModelDelayApproximate[StateSpaceModel[{{{-1}}, {{SystemsModelDelay[2]}}, {{1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], 3]

A TransferFunctionModel with delay:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{-1 + SystemsModelDelay[3]}}, 3 + s}, s], 2]

Scope  (4)

A continuous-time StateSpaceModel with symbolic delay:

Wolfram Language code: SystemsModelDelayApproximate[StateSpaceModel[{{{1, 1/2 + 2*SystemsModelDelay[τ]}, {0, -1}}, {{0}, {3}}, {{1, 0}, {0, 3}}, {{0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None], 2]

A discrete-time StateSpaceModel:

Wolfram Language code: SystemsModelDelayApproximate[StateSpaceModel[{{{0, 1}, {-1 + SystemsModelDelay[4]/2, -1/3}}, {{0}, {1}}, {{SystemsModelDelay[1], 2}}, {{0}}}, SamplingPeriod -> 0.25, SystemsModelLabels -> None]]

A continuous-time TransferFunctionModel:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{1, 2}, {E^(-3*s), s}}, 4 - 2*(1 + E^(-s))*s + s^2}, s] , 2]

A discrete-time TransferFunctionModel with integer delay:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{4*(-1/2 + z)*SystemsModelDelay[3]}}, 4*(1/2 + z)*(1 + z)}, z, SamplingPeriod -> 2, SystemsModelLabels -> None]]

With fractional delay:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{4*(-1/2 + z)*SystemsModelDelay[5/2]}}, 4*(1/2 + z)*(1 + z)}, z, SamplingPeriod -> 2, SystemsModelLabels -> None]]

Use only a first-order approximation:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{4*(-1/2 + z)*SystemsModelDelay[5/2]}}, 4*(1/2 + z)*(1 + z)}, z, SamplingPeriod -> 2, SystemsModelLabels -> None], 1]

Generalizations & Extensions  (1)

For discrete-time systems, if the order is omitted, it will be chosen automatically:

Wolfram Language code: SystemsModelDelayApproximate[StateSpaceModel[{{{1/2}}, {{SystemsModelDelay[3.1]}}, {{1}}, {{0}}}, SamplingPeriod -> τ, SystemsModelLabels -> None]]

Applications  (1)

The model of the lathe below uses an internal delay to account for a varying chip size:

Wolfram Language code: dde = 10 x''[t] + x'[t] + 100 x[t] == -200(f[t] + x[t] - x[t - 1]); lathe = StateSpaceModel[dde, {x[t], x'[t]}, {f[t]}, x[t], t]

The delay causes an instability:

Wolfram Language code: OutputResponse[lathe, UnitStep[t], {t, 0, 5}]; Plot[%, {t, 0, 5}, PlotRange -> All]

Approximate the delays to allow for controller design:

Wolfram Language code: approxLathe = Simplify@SystemsModelDelayApproximate[lathe, 2]
Wolfram Language code: kgains = StateFeedbackGains[approxLathe, {-5, -10, -15, -20}]; lgains = EstimatorGains[approxLathe, {-5, -10, -15, -20}];
Wolfram Language code: er = EstimatorRegulator[approxLathe, {lgains, kgains}, "EstimatorRegulatorFeedbackModel"]

Apply the controller to the original time-delay system:

Wolfram Language code: cl = SystemsModelFeedbackConnect[lathe, er]

The resulting closed-loop system is stable:

Wolfram Language code: OutputResponse[cl, UnitStep[t], {t, 0, 5}]; Plot[%, {t, 0, 5}, PlotRange -> All]

Properties & Relations  (1)

Zero-order approximations are equivalent to setting the delay equal to zero:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{SystemsModelDelay[3] - 3*SystemsModelDelay[4]}}, 3 + s}, s], 0]

Possible Issues  (1)

Approximating a discrete-time system with too large an order creates an unstable system:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{(0.5 + z)*SystemsModelDelay[1.5]}}, (-0.2 + z)*(0.2 + z)}, z, SamplingPeriod -> 1], 4]//TransferFunctionPoles

Instead, allow the order to be chosen automatically:

Wolfram Language code: SystemsModelDelayApproximate[TransferFunctionModel[{{{(0.5 + z)*SystemsModelDelay[1.5]}}, (-0.2 + z)*(0.2 + z)}, z, SamplingPeriod -> 1]]//TransferFunctionPoles
Wolfram Research (2012), SystemsModelDelayApproximate, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelDelayApproximate.html.

Text

Wolfram Research (2012), SystemsModelDelayApproximate, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelDelayApproximate.html.

CMS

Wolfram Language. 2012. "SystemsModelDelayApproximate." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/SystemsModelDelayApproximate.html.

APA

Wolfram Language. (2012). SystemsModelDelayApproximate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemsModelDelayApproximate.html

BibTeX

@misc{reference.wolfram_2026_systemsmodeldelayapproximate, author="Wolfram Research", title="{SystemsModelDelayApproximate}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/SystemsModelDelayApproximate.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemsmodeldelayapproximate, organization={Wolfram Research}, title={SystemsModelDelayApproximate}, year={2012}, url={https://reference.wolfram.com/language/ref/SystemsModelDelayApproximate.html}, note=[Accessed: 13-June-2026]}