WOLFRAM

Wolfram Language & System Documentation Center

SystemsModelOrder[sys]

gives the order of the state-space model sys.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
Possible Issues  
See Also
Related Guides
History
Cite this Page

SystemsModelOrder

SystemsModelOrder[sys]

gives the order of the state-space model sys.

Details

  • The system sys can be a standard or descriptor StateSpaceModel, an AffineStateSpaceModel, or a NonlinearStateSpaceModel, all with no delays.
  • The order of a standard continuous-time systems model is the number of integrators in the model and for standard discrete-time systems, the number of integer delays in the model.
  • For a descriptor StateSpaceModel, the order is taken to be the dimension of the slow subsystem.

Examples

open all close all

Basic Examples  (2)

The order of a state-space model:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{0, 1, 3}, {2, 5, 1}, {0, 3, 0}}, {{3}, {5}, {3}}, {{5, 2, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

The order of a descriptor state-space model:

Wolfram Language code: SystemsModelOrder[ssm = StateSpaceModel[{{{-1, 0, 0}, {0, 1, 0}, {0, 0, 1}}, {{1}, {0}, {1}}, {{1, 1, 1}}, {{0}}, {{1, 0, 0}, {0, 0, 1}, {0, 0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

It can be computed as the exponent of the polynomial Det[s e-a]:

Wolfram Language code: {a, e} = Normal[ssm][[{1, -1}]]; Exponent[Det[s e - a], s]

Scope  (6)

A standard state-space model:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{Subscript[a, 1], Subscript[a, 2]}, {Subscript[a, 3], Subscript[a, 4]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

A nonsingular descriptor state-space model:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0}}, {{Subscript[e, 1], 0}, {0, Subscript[e, 2]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

A singular descriptor state-space model:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{Subscript[c, 1], Subscript[c, 2]}}, {{0}}, {{Subscript[e, 1], 0}, {0, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

A discrete-time system with integer time delay:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{0, 1., 0.}, {0, 0., 1.}, {-1, -5., 2}}, {{0}, {0}, {1}}, {{-3*SystemsModelDelay[10], 1, 1}}, {{0}}}, SamplingPeriod -> τ, SystemsModelLabels -> None]]

An affine state-space model:

Wolfram Language code: SystemsModelOrder[AffineStateSpaceModel[{{Subscript[x, 1] - Subscript[x, 2], Subscript[x, 1]*Subscript[x, 2]}, {{0}, {1}}, {Subscript[x, 1]}, {{0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic}, Automatic, SamplingPeriod -> None]]

A nonlinear state-space model:

Wolfram Language code: SystemsModelOrder[NonlinearStateSpaceModel[{{u^2 + x + u*x}, {x}}, {x}, {u}, {Automatic}, Automatic, SamplingPeriod -> None]]

Applications  (2)

Use SystemsModelOrder and ControllableDecomposition to test for controllability:

Wolfram Language code: ssm = StateSpaceModel[{{{-3, -1, -3}, {2, 0, 3}, {2, 2, 1}}, {{1}, {0}, {-1}}, {{2, 1, 2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: SystemsModelOrder[ssm] === SystemsModelOrder[Last[ControllableDecomposition[ssm]]]
Wolfram Language code: ControllableModelQ[ssm]

Test for observability:

Wolfram Language code: ssm = StateSpaceModel[{{{-3, -1, -3}, {2, 0, 3}, {2, 2, 1}}, {{1}, {0}, {-1}}, {{2, 1, 2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: SystemsModelOrder[ssm] === SystemsModelOrder[Last[ObservableDecomposition[ssm]]]
Wolfram Language code: ObservableModelQ[ssm]

Properties & Relations  (3)

The order of a singular state-space model depends on the descriptor matrix:

Wolfram Language code: ssm = StateSpaceModel[{{{1, -2, 0, 0}, {0, 1, 4, 0}, {0, 0, 0, 1}, {0, 0, -4, -1}}, {{0}, {1}, {0}, {1}}, {{-2, 7/2, -4, 0}}, {{0}}, {{0, 1, 4, 0}, {0, 0, 0, 0}, {0, 0, 1, 0}, {0, 0, 3, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None]; SystemsModelOrder[ssm]

The order is equivalent to the exponent of the polynomial Det[s e-a]:

Wolfram Language code: {a, e} = Normal[ssm][[{1, -1}]]; Exponent[Det[s e - a], s]

It also equals the size of the slow system found with KroneckerModelDecomposition:

Wolfram Language code: kssm = Last@KroneckerModelDecomposition[ssm]

The slow system size is shown by the number of ones on the descriptor matrix diagonal:

Wolfram Language code: e = Normal[kssm][[5]]; Total[Diagonal[e]]

The order of a discrete-time time-delay system is the total number of delays in the system:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{1/2}}, {{SystemsModelDelay[6]}}, {{2}}, {{0}}}, SamplingPeriod -> 1, SystemsModelLabels -> None]]

The order of a system with no zero dynamics is the total of the vector relative orders:

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 1]*Subscript[x, 2], Subscript[x, 2]}, {{1, 1}, {0, 1}}, {Subscript[x, 1], Subscript[x, 2]}, {{0, 0}, {0, 0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None];

Use SystemsModelVectorRelativeOrders to get the relative orders:

Wolfram Language code: SystemsModelOrder[asys] == Total[SystemsModelVectorRelativeOrders[asys]]

Possible Issues  (1)

Discrete-time systems with fractional delays are not supported:

Wolfram Language code: SystemsModelOrder[StateSpaceModel[{{{1/4}}, {{SystemsModelDelay[4.3]}}, {{1}}, {{0}}}, SamplingPeriod -> 2, SystemsModelLabels -> None]]

Approximate the delays:

Wolfram Language code: SystemsModelOrder[SystemsModelDelayApproximate[StateSpaceModel[{{{1/4}}, {{SystemsModelDelay[4.3]}}, {{1}}, {{0}}}, SamplingPeriod -> 2, SystemsModelLabels -> None]]]
Wolfram Research (2010), SystemsModelOrder, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelOrder.html (updated 2014).

Text

Wolfram Research (2010), SystemsModelOrder, Wolfram Language function, https://reference.wolfram.com/language/ref/SystemsModelOrder.html (updated 2014).

CMS

Wolfram Language. 2010. "SystemsModelOrder." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/SystemsModelOrder.html.

APA

Wolfram Language. (2010). SystemsModelOrder. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/SystemsModelOrder.html

BibTeX

@misc{reference.wolfram_2026_systemsmodelorder, author="Wolfram Research", title="{SystemsModelOrder}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/SystemsModelOrder.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_systemsmodelorder, organization={Wolfram Research}, title={SystemsModelOrder}, year={2014}, url={https://reference.wolfram.com/language/ref/SystemsModelOrder.html}, note=[Accessed: 13-June-2026]}