WOLFRAM

Wolfram Language & System Documentation Center

TabularRow[data]

represents a single row of a Tabular object.

TabularRow[data,{key1,key2,…}]

sets keyi as the name of column i of the tabular row object.

Details and Options
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Applications  
Properties & Relations  
See Also
Related Guides
History
Cite this Page

TabularRow

TabularRow[data]

represents a single row of a Tabular object.

TabularRow[data,{key1,key2,…}]

sets keyi as the name of column i of the tabular row object.

Details and Options

  • TabularRow is typically used to represent a row in a Tabular object. It contains column names and types.
  • Possible forms of input data in TabularRow include:
  • <|col1val1,col2val2,…|>association of values vali with column keys coli
    {val1,val2,…}list of values
  • TabularRow[{val1,val2,…},{col1,col2,…}] is equivalent to TabularRow[<|col1val1,col2val2,…|>].
  • The Normal form of TabularRow is a list of values when no column names are specified or an association of values when columns are named.

Examples

open all close all

Basic Examples  (3)

Create a TabularRow object from an association:

Wolfram Language code: TabularRow[<|"col1" -> 7, "col2" -> "cat", "col3" -> -3.1|>]

Check the types automatically assigned to each column:

Wolfram Language code: ColumnTypes[%]

Create a TabularRow object from a list of values:

Wolfram Language code: TabularRow[{7, "cat", -3.1}]

The entries of the row do not have column keys:

Wolfram Language code: ColumnKeys[%]

Extract a tabular row from a Tabular object:

Wolfram Language code: Tabular[{<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"a" -> 4, "b" -> 5, "c" -> 6|>}]
Wolfram Language code: %[[1]]

Normalize into an association:

Wolfram Language code: Normal[%]

Scope  (5)

Create a TabularRow with named columns:

Wolfram Language code: row1 = TabularRow[<|"c1" -> 3, "c2" -> "dog", "c3" -> True|>]

Alternatively, specify the column keys separately:

Wolfram Language code: row2 = TabularRow[{3, "dog", True}, {"c1", "c2", "c3"}]

Or more specifically:

Wolfram Language code: row3 = TabularRow[{3, "dog", True}, <|"ColumnKeys" -> {"c1", "c2", "c3"}|>]

The three rows are identical:

Wolfram Language code: row1 === row2 === row3

A TabularRow object can be empty:

Wolfram Language code: TabularRow[{}]
Wolfram Language code: TabularRow[<||>]

Construct a TabularRow object from a numeric vector, specifying column types:

Wolfram Language code: TabularRow[<|"a" -> 1, "b" -> 2, "c" -> 3|>, <|"ColumnTypes" -> {"Integer64", "Integer32", "Integer16"}|>]

Check the types stored:

Wolfram Language code: ColumnTypes[%]

Mix number, string and Boolean types:

Wolfram Language code: TabularRow[{1, "dog", True}, <|"ColumnTypes" -> {"Integer8", "String", "Boolean"}|>]
Wolfram Language code: ColumnTypes[%]

The elements of a TabularRow object can be lists:

Wolfram Language code: row = TabularRow[{{1, 2}, {"a", "b"}, {True, False}}]
Wolfram Language code: ColumnTypes[row]

Applications  (1)

Take a list of TabularRow expressions:

Wolfram Language code: data = Transpose@{RandomReal[1, 3], RandomDate[3], RandomChoice[Alphabet[], 3]}
Wolfram Language code: rows = TabularRow /@ data

Build a Tabular object from those rows:

Wolfram Language code: Tabular[rows]

Alternatively, use ToTabular:

Wolfram Language code: ToTabular[rows, "Rows"]

Normalize to get the data back:

Wolfram Language code: Normal[%]

Properties & Relations  (2)

Check validity of a TabularRow object with TabularRowQ:

Wolfram Language code: TabularRow[Alphabet[]]
Wolfram Language code: TabularRowQ[%]

A TabularRow object is not a valid one-row Tabular object:

Wolfram Language code: row = TabularRow[{1, "a", True}]
Wolfram Language code: {TabularRowQ[row], TabularQ[row]}

Construct a Tabular object with only that row:

Wolfram Language code: tab = Tabular[{row}]
Wolfram Language code: {TabularRowQ[tab], TabularQ[tab]}
Wolfram Research (2025), TabularRow, Wolfram Language function, https://reference.wolfram.com/language/ref/TabularRow.html.

Text

Wolfram Research (2025), TabularRow, Wolfram Language function, https://reference.wolfram.com/language/ref/TabularRow.html.

CMS

Wolfram Language. 2025. "TabularRow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TabularRow.html.

APA

Wolfram Language. (2025). TabularRow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TabularRow.html

BibTeX

@misc{reference.wolfram_2026_tabularrow, author="Wolfram Research", title="{TabularRow}", year="2025", howpublished="\url{https://reference.wolfram.com/language/ref/TabularRow.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tabularrow, organization={Wolfram Research}, title={TabularRow}, year={2025}, url={https://reference.wolfram.com/language/ref/TabularRow.html}, note=[Accessed: 13-June-2026]}