WOLFRAM

Wolfram Language & System Documentation Center

f/:lhs:=rhs

assigns rhs to be the delayed value of lhs, and associates the assignment with the symbol f.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Left-Hand Sides  
Different Kinds of Values  
Applications  
Properties & Relations  
See Also
Tech Notes
Related Guides
History
Cite this Page

TagSetDelayed

f/:lhs:=rhs

assigns rhs to be the delayed value of lhs, and associates the assignment with the symbol f.

Details

  • TagSetDelayed defines upvalues, downvalues or subvalues as appropriate.
  • The symbol f in f/:lhs:=rhs must appear in lhs as the head of lhs, the head of the head, one of the elements of lhs or the head of one of the elements.
  • A common case is f/:h[f[args]]:=rhs.
  • You can see all the rules associated with a particular symbol by typing ?symbol.
  • If f appears several times in lhs, then f/:lhs:=rhs associates the assignment with each occurrence.
  • When it appears in unevaluated symbolic form, TagSetDelayed is treated as a scoping construct so that variables in nested occurrences are renamed if necessary.

Examples

open all close all

Basic Examples  (1)

Wolfram Language code: g/:f[g[x_]] := fg[x]
Wolfram Language code: {f[g[2]], f[h[2]]}

Scope  (7)

Left-Hand Sides  (4)

An expression with a delayed definition is evaluated every time it is used:

Wolfram Language code: int/:rand[int] := RandomInteger[]
Wolfram Language code: Table[rand[int], {5}]

Make definitions for special and general cases using immediate and delayed assignments:

Wolfram Language code: h/:f[h[0]] = h0; h/:f[h[x_]] := 2f[h[x - 1]]
Wolfram Language code: f[h[10]]

The tag can appear as an argument of the left side:

Wolfram Language code: sq/:area[sq, s_] := s ^ 2
Wolfram Language code: area[sq, 2]

The tag can appear as the head of an argument of the left side:

Wolfram Language code: sq/:area[sq[s_]] := s ^ 2
Wolfram Language code: area[sq[3]]

Different Kinds of Values  (3)

For ownvalues, the tag is redundant:

Wolfram Language code: x/:x := RandomReal[] y := RandomReal[]
Wolfram Language code: {OwnValues[x], OwnValues[y]}

For downvalues, the tag is redundant:

Wolfram Language code: f/:f[x_] := x ^ 2; g[x_] := x ^ 2
Wolfram Language code: {DownValues[f], DownValues[g]}

Use a tag to define upvalues:

Wolfram Language code: g/:f[g[x_]] := f1[x] f[h[x_]] := f2[x]
Wolfram Language code: {UpValues[g], DownValues[f]}

Applications  (1)

Implement modular arithmetic:

Wolfram Language code: mod/:mod[a_, p_] + mod[b_, p_] := mod[Mod[a + b, p], p] mod/:i_Integer mod[a_, p_] := mod[Mod[i a, p], p]
Wolfram Language code: mod[2, 5] + 3 mod[3, 5] - mod[1, 5]

Properties & Relations  (7)

^:= defines upvalues in the same way as using a tag does:

Wolfram Language code: g/:f[g[x_]] := f1[x]
Wolfram Language code: f[h[x_]] ^:= f2[x]
Wolfram Language code: {UpValues[g], UpValues[h]}

A tag defines only one upvalue; ^:= makes definitions for all symbols:

Wolfram Language code: g/:f1[g[x_], h[y_]] := gh[x y]
Wolfram Language code: f2[g[x_], h[y_]] ^:= gh[x y]
Wolfram Language code: {UpValues[g], UpValues[h]}

The right side of an immediate definition is evaluated when the definition is made:

Wolfram Language code: int/:rand[int] = RandomInteger[];
Wolfram Language code: {rand[int], rand[int]}

The right side of a delayed definition is evaluated each time the definition is used:

Wolfram Language code: real/:rand[real] := RandomReal[]
Wolfram Language code: {rand[real], rand[real]}

Definitions with the same left side overwrite earlier ones:

Wolfram Language code: h/:f[h[x_]] := f1[x]
Wolfram Language code: h/:f[h[x_]] := f2[x]
Wolfram Language code: Definition[h]

Definition prints definitions associated with a symbol:

Wolfram Language code: mod/:a_mod + b_mod := modPlus[a, b]
Wolfram Language code: Definition[mod]

Information prints various information about a symbol, including any definitions:

Wolfram Language code: ? mod

UpValues returns a list of rules corresponding to any upvalues defined:

Wolfram Language code: UpValues[mod]

Use =. to clear definitions with a particular left-hand side:

Wolfram Language code: h/:f[h[x_]] := f1[x]; h/:g[h[x_]] := g1[x];
Wolfram Language code: h/:f[h[x_]]=.
Wolfram Language code: {f[h[1]], g[h[1]]}

Clear all definitions:

Wolfram Language code: Clear[h]
Wolfram Language code: Definition[h]

Delayed assignment introduces a scope that is not affected by global variables:

Wolfram Language code: x = 5;
Wolfram Language code: h/:f[h[x_]] := x ^ 2
Wolfram Language code: {f[h[2]], x}

Immediate assignment does not introduce a scope:

Wolfram Language code: h/:g[h[x_]] = x ^ 2;
Wolfram Language code: {g[h[2]], x}
Wolfram Research (1988), TagSetDelayed, Wolfram Language function, https://reference.wolfram.com/language/ref/TagSetDelayed.html.

Text

Wolfram Research (1988), TagSetDelayed, Wolfram Language function, https://reference.wolfram.com/language/ref/TagSetDelayed.html.

CMS

Wolfram Language. 1988. "TagSetDelayed." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TagSetDelayed.html.

APA

Wolfram Language. (1988). TagSetDelayed. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TagSetDelayed.html

BibTeX

@misc{reference.wolfram_2026_tagsetdelayed, author="Wolfram Research", title="{TagSetDelayed}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/TagSetDelayed.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tagsetdelayed, organization={Wolfram Research}, title={TagSetDelayed}, year={1988}, url={https://reference.wolfram.com/language/ref/TagSetDelayed.html}, note=[Accessed: 13-June-2026]}