WOLFRAM

Wolfram Language & System Documentation Center

f/:lhs=rhs

assigns rhs to be the value of lhs, and associates the assignment with the symbol f.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Different Kinds of Values  
Applications  
Properties & Relations  
Possible Issues  
See Also
Tech Notes
Related Guides
History
Cite this Page

TagSet

f/:lhs=rhs

assigns rhs to be the value of lhs, and associates the assignment with the symbol f.

Details

  • TagSet defines upvalues, downvalues or subvalues as appropriate.
  • The symbol f in f/:lhs=rhs must appear in lhs as the head of lhs, the head of the head, one of the elements of lhs, or the head of one of the elements.
  • A common case is f/:h[f[args]]=rhs.
  • You can see all the rules associated with a particular symbol by typing ?symbol.
  • If f appears several times in lhs, then f/:lhs=rhs associates the assignment with each occurrence.
  • When it appears in unevaluated symbolic form, TagSet is treated as a scoping construct so that variables in nested occurrences are renamed if necessary.

Examples

open all close all

Basic Examples  (1)

Define a symbolic property of a symbol:

Wolfram Language code: square/:area[square] = s ^ 2

Scope  (3)

Different Kinds of Values  (3)

For ownvalues, the tag is redundant:

Wolfram Language code: x/:x = 7; y = 7;
Wolfram Language code: {OwnValues[x], OwnValues[y]}

For downvalues, the tag is redundant:

Wolfram Language code: a/:a[zeta] = theta; b[zeta] = theta;
Wolfram Language code: {DownValues[a], DownValues[b]}

Use a tag to define upvalues:

Wolfram Language code: zeta/:a[zeta] = theta; b[zeta] = theta;
Wolfram Language code: {UpValues[zeta], DownValues[b]}

Applications  (1)

Build a database of exchange rates:

Wolfram Language code: chf/:rate[chf] = 0.812; eur/:rate[eur] = 1.317; gbp/:rate[gbp] = 1.963;
Wolfram Language code: rate[chf] / rate[eur]

Properties & Relations  (5)

^= defines upvalues in the same way as using a tag does:

Wolfram Language code: square/:area[square] = a ^ 2; area[rectangle] ^= a * b;
Wolfram Language code: {UpValues[square], UpValues[rectangle]}

The right side of an immediate definition is evaluated when the definition is made:

Wolfram Language code: int/:rand[int] = RandomInteger[];
Wolfram Language code: {rand[int], rand[int]}

The right side of a delayed definition is evaluated each time the definition is used:

Wolfram Language code: real/:rand[real] := RandomReal[]
Wolfram Language code: {rand[real], rand[real]}

Definitions with the same left side overwrite earlier ones:

Wolfram Language code: sq/:area[sq] = a ^ 2;
Wolfram Language code: sq/:area[sq] = s ^ 2;
Wolfram Language code: area[sq]

Definition prints definitions associated with a symbol:

Wolfram Language code: sq/:area[sq] = a ^ 2;
Wolfram Language code: Definition[sq]

Information prints various information about a symbol, including any definitions:

Wolfram Language code: ? sq

UpValues returns a list of rules corresponding to any upvalues defined:

Wolfram Language code: UpValues[sq]

Use =. to clear definitions with a particular left-hand side:

Wolfram Language code: sq/:area[sq] = s ^ 2; sq/:circ[sq] = 4s;
Wolfram Language code: sq/:circ[sq]=.
Wolfram Language code: {area[sq], circ[sq]}

Clear all definitions:

Wolfram Language code: Clear[sq]
Wolfram Language code: Definition[sq]

Possible Issues  (2)

In the presence of global variables, pattern variables may show unexpected behavior:

Wolfram Language code: x = 5;
Wolfram Language code: h/:f[h[x_]] = x ^ 2;
Wolfram Language code: f[h[2]]

Delayed assignments behave as expected:

Wolfram Language code: g/:f[g[x_]] := x ^ 2;
Wolfram Language code: f[g[2]]

Use upvalues to assign to subscripted variables:

Wolfram Language code: a/:Subscript[a, 1] = 5;
Wolfram Language code: FullForm[UpValues[a]]

Subscripted variables are distinct from indexed variables:

Wolfram Language code: a[1] = 6;
Wolfram Language code: FullForm[DownValues[a]]
Wolfram Research (1988), TagSet, Wolfram Language function, https://reference.wolfram.com/language/ref/TagSet.html.

Text

Wolfram Research (1988), TagSet, Wolfram Language function, https://reference.wolfram.com/language/ref/TagSet.html.

CMS

Wolfram Language. 1988. "TagSet." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/TagSet.html.

APA

Wolfram Language. (1988). TagSet. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/TagSet.html

BibTeX

@misc{reference.wolfram_2026_tagset, author="Wolfram Research", title="{TagSet}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/TagSet.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_tagset, organization={Wolfram Research}, title={TagSet}, year={1988}, url={https://reference.wolfram.com/language/ref/TagSet.html}, note=[Accessed: 13-June-2026]}