WOLFRAM

Wolfram Language & System Documentation Center

Translate[g,{x,y,…}]

represents graphics primitives g translated by the vector {x,y,…}.

Translate[g,{{x1,y1,…},{x2,y2,…}, …}]

represents multiple copies of g translated by a collection of vectors.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Properties & Relations  
Neat Examples  
See Also
Related Guides
Related Workflows
Related Links
History
Cite this Page

Translate

Translate[g,{x,y,…}]

represents graphics primitives g translated by the vector {x,y,…}.

Translate[g,{{x1,y1,…},{x2,y2,…}, …}]

represents multiple copies of g translated by a collection of vectors.

Details

  • Translate[g,{x,y,…}] in effect adds {x,y,…} to each set of coordinates that appear in the graphics primitives g.
  • For objects specified with scaled coordinates Scaled[{x,y}], Translate effectively applies its transformation to the corresponding ordinary coordinates.
  • Normal[expr] if possible replaces all Translate[gi,…] constructs by versions of the gi in which the coordinates have explicitly been transformed.
  • Translate with a list of vectors is a very efficient way to represent multiple, identical copies of an arbitrarily complex shape or image in a graphic.

Examples

open all close all

Basic Examples  (2)

Translation of a 2D graphics primitive:

Wolfram Language code: Graphics[Translate[Circle[], {1, 0}], Axes -> True]

Translate a 3D graphics primitive:

Wolfram Language code: Graphics3D[Translate[Sphere[], {1, 0, 0}], Axes -> True]

Scope  (4)

Transformation applied to a 2D shape:

Wolfram Language code: gr = {Rectangle[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0}]}, {Green, Point[{1, 1}]}};
Wolfram Language code: Graphics[{{Opacity[.35], Blue, gr}, Translate[{Opacity[.85], Red, gr}, {.5, .5}]}]

Transformation applied to a 3D shape:

Wolfram Language code: gr = {Cuboid[], AbsolutePointSize[10], Opacity[1], {Magenta, Point[{0, 0, 0}]}, {Green, Point[{1, 1, 1}]}};
Wolfram Language code: Graphics3D[{{Opacity[.35], Blue, gr}, Translate[{Opacity[.85], Red, gr}, {.5, .5, .5}]}, Boxed -> False]

The transformations can be nested:

Wolfram Language code: Graphics3D[{Sphere[], Translate[Sphere[], {2, 0, 0}], Translate[Translate[Sphere[], {2, 0, 0}], {0, 2, 0}]}, Boxed -> False]

Make multiple copies of a complex shape:

Wolfram Language code: shape = {Cylinder[{{0, 0, 0}, {0, 0, .5}}, .125], Cone[{{0, 0, -.5}, {0, 0, .5}}, .25]};
Wolfram Language code: Graphics3D[Translate[shape, {{0, 0, 0}, {1, 0, 0}, {2, 0, 0}}]]

Properties & Relations  (2)

When possible, Normal will transform the coordinates explicitly:

Wolfram Language code: Normal@Translate[Point[{x, y, z}], {x0, y0, z0}]

GeometricTransformation is a generalization of Translate:

Wolfram Language code: {Graphics[Translate[Circle[], {1, 3}], Axes -> True], Graphics[GeometricTransformation[Circle[], {IdentityMatrix[2], {1, 3}}], Axes -> True], Graphics[GeometricTransformation[Circle[], TranslationTransform[{1, 3}]], Axes -> True]}

Neat Examples  (1)

Rotating and translating a cylinder along a circle:

Wolfram Language code: Graphics3D[Table[Translate[Rotate[Cylinder[], t, {1, 0, 0}], 12{0, Cos[t], Sin[t]}], {t, Pi / 15Range[30]}], Boxed -> False]
Wolfram Research (2007), Translate, Wolfram Language function, https://reference.wolfram.com/language/ref/Translate.html (updated 2010).

Text

Wolfram Research (2007), Translate, Wolfram Language function, https://reference.wolfram.com/language/ref/Translate.html (updated 2010).

CMS

Wolfram Language. 2007. "Translate." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2010. https://reference.wolfram.com/language/ref/Translate.html.

APA

Wolfram Language. (2007). Translate. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Translate.html

BibTeX

@misc{reference.wolfram_2026_translate, author="Wolfram Research", title="{Translate}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/Translate.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_translate, organization={Wolfram Research}, title={Translate}, year={2010}, url={https://reference.wolfram.com/language/ref/Translate.html}, note=[Accessed: 13-June-2026]}