WOLFRAM

Wolfram Language & System Documentation Center

UniformPolyhedron["name"]

gives the uniform polyhedron with the given name.

UniformPolyhedron[{n,m}]

gives the uniform polyhedron with n sides of each face and m faces meeting at each vertex point.

UniformPolyhedron[{r,θ,ϕ},…]

rescales the uniform polyhedron by a factor r and rotates by an angle θ with respect to the z axis and angle ϕ with respect to the y axis.

UniformPolyhedron[{x,y,z},{r,θ,ϕ},…]

centers the uniform polyhedron at {x,y,z}.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Basic Uses  
Specifications  
Properties & Relations  
Neat Examples  
See Also
Related Guides
History
Cite this Page

UniformPolyhedron

UniformPolyhedron["name"]

gives the uniform polyhedron with the given name.

UniformPolyhedron[{n,m}]

gives the uniform polyhedron with n sides of each face and m faces meeting at each vertex point.

UniformPolyhedron[{r,θ,ϕ},…]

rescales the uniform polyhedron by a factor r and rotates by an angle θ with respect to the z axis and angle ϕ with respect to the y axis.

UniformPolyhedron[{x,y,z},{r,θ,ϕ},…]

centers the uniform polyhedron at {x,y,z}.

Details

  • UniformPolyhedron is also known as Platonic solid, Archimedean solid or regular star polyhedron.
  • UniformPolyhedron is typically used to generate base shapes for 3D modeling and as geometric regions.
  • UniformPolyhedron generates a Polyhedron centered at the origin with unit edge length.
  • Uniform polyhedrons can be specified with their standard names, Schläfli symbols {n,m} or Wenninger numbers, including:
  • {4,3}"Cube"
    {5,3}"Dodecahedron"
    {3,5}"Icosahedron"
    {3,4}"Octahedron"
    {3,3}"Tetrahedron"
  • {{5,2},5}"SmallStellatedDodecahedron"
    {{5,2},3}"GreatStellatedDodecahedron"
    {3,{5,2}}"GreatIcosahedron"
    {5,{5,2}}"GreatDodecahedron"

Examples

open all close all

Basic Examples  (2)

A dodecahedron:

Wolfram Language code: poly = UniformPolyhedron["Dodecahedron"]
Wolfram Language code: Graphics3D[poly]

Get a list of uniform polyhedra:

Wolfram Language code: EntityList[["EntityClass["Polyhedron", "Uniform"]"]]
Wolfram Language code: Graphics3D[UniformPolyhedron[#]] & /@ Take[%, 6]

Scope  (9)

Basic Uses  (6)

Generate an equilateral tetrahedron, octahedron, icosahedron, etc.:

Wolfram Language code: Table[Graphics3D[UniformPolyhedron[{3, m}]], {m, 3, 5}]

Color directives specify the face colors of uniform polyhedrons:

Wolfram Language code: Table[Graphics3D[{c, UniformPolyhedron[{3, 5}]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interior and boundary:

Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], UniformPolyhedron[{3, 5}]}]

Uniform polyhedra are three-dimensional geometric regions:

Wolfram Language code: RegionQ[UniformPolyhedron[{3, 4}]]

Geometric dimension:

Wolfram Language code: RegionDimension[UniformPolyhedron[{3, 4}]]

Find the geometric properties of a uniform polyhedron:

Wolfram Language code: Volume[UniformPolyhedron["Cube"]]

Centroid:

Wolfram Language code: RegionCentroid[UniformPolyhedron["Cube"]]

Surface area:

Wolfram Language code: SurfaceArea[UniformPolyhedron["Cube"]]

Modify the orientation of a uniform polyhedron:

Wolfram Language code: UniformPolyhedron[{1, Pi / 3, Pi / 4}, "Cube"]
Wolfram Language code: Graphics3D[%]

Translate it:

Wolfram Language code: UniformPolyhedron[{1, 2, 3}, {1, Pi / 3, Pi / 4}, "Cube"]

Specifications  (3)

A uniform polyhedron can be specified by its standard Wolfram Language name:

Wolfram Language code: UniformPolyhedron["Cube"]
Wolfram Language code: Graphics3D[%]

Uniform polyhedra can also be specified in Schläfli notation:

Wolfram Language code: UniformPolyhedron[{4, 3}]

Wenninger numbers:

Wolfram Language code: UniformPolyhedron[3]

Entities:

Wolfram Language code: UniformPolyhedron[[""Cube""]]

Alternate polyhedron numbering notations include Wenninger numbers:

Wolfram Language code: UniformPolyhedron[{"Wenninger", 4}]

Uniform numbers:

Wolfram Language code: UniformPolyhedron[{"Uniform", 22}]

Kaleido numbers:

Wolfram Language code: UniformPolyhedron[{"Kaleido", 27}]

Coxeter numbers:

Wolfram Language code: UniformPolyhedron[{"Coxeter", 25}]

Properties & Relations  (4)

Using PolyhedronData to get a uniform polyhedron:

Wolfram Language code: PolyhedronData["Dodecahedron"]
Wolfram Language code: Graphics3D[UniformPolyhedron["Dodecahedron"]]

Use ConvexPolyhedronQ to check the property of a uniform polyhedron:

Wolfram Language code: poly = UniformPolyhedron["Dodecahedron"]
Wolfram Language code: ConvexPolyhedronQ[poly]

SimplePolyhedronQ:

Wolfram Language code: SimplePolyhedronQ[poly]

All faces of uniform polyhedrons are uniform polygons:

Wolfram Language code: poly = UniformPolyhedron["Dodecahedron"]
Wolfram Language code: faces = poly[[2]]
Wolfram Language code: Graphics3D[Polygon[PolyhedronCoordinates[poly][[#]]]]& /@ faces

A uniform polyhedron is bounded:

Wolfram Language code: poly = UniformPolyhedron[{3, 5}];
Wolfram Language code: BoundedRegionQ[poly]

Get its range:

Wolfram Language code: rr = RegionBounds[poly]
Wolfram Language code: Graphics3D[{Red, poly, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

Neat Examples  (2)

Generate cubes of varying radii:

Wolfram Language code: polys = Table[UniformPolyhedron[r, {4, 3}], {r, 1, 4}];
Wolfram Language code: Graphics3D[{Opacity[0.2], polys}]

Generate cubes of varying starting angles:

Wolfram Language code: polys = Table[UniformPolyhedron[{1, t Pi / 6, Pi / 3}, {4, 3}], {t, 4}];
Wolfram Language code: Graphics3D[{Opacity[0.2], polys}]
Wolfram Research (2019), UniformPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/UniformPolyhedron.html.

Text

Wolfram Research (2019), UniformPolyhedron, Wolfram Language function, https://reference.wolfram.com/language/ref/UniformPolyhedron.html.

CMS

Wolfram Language. 2019. "UniformPolyhedron." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/UniformPolyhedron.html.

APA

Wolfram Language. (2019). UniformPolyhedron. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/UniformPolyhedron.html

BibTeX

@misc{reference.wolfram_2026_uniformpolyhedron, author="Wolfram Research", title="{UniformPolyhedron}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/UniformPolyhedron.html}", note=[Accessed: 12-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_uniformpolyhedron, organization={Wolfram Research}, title={UniformPolyhedron}, year={2019}, url={https://reference.wolfram.com/language/ref/UniformPolyhedron.html}, note=[Accessed: 12-June-2026]}