WOLFRAM

Wolfram Language & System Documentation Center

VertexColors

is an option for graphics primitives which specifies the colors to assign to vertices.

Details
Details and Options Details and Options
Examples  
Basic Examples  
Scope  
Graphics Objects  
Graphics3D primitives and Shapes  
Color Specification  
Visualization Functions  
Possible Issues  
Neat Examples  
See Also
Related Guides
History
Cite this Page

VertexColors

VertexColors

is an option for graphics primitives which specifies the colors to assign to vertices.

Details

Examples

open all close all

Basic Examples  (3)

Make a multicolored shape:

Wolfram Language code: Graphics[Polygon[{{0, 0}, {0, 1}, {1, 1}, {1, 0}}, VertexColors -> {Blue, Green, Brown, Purple}]]

Make a multicolored 3D shape:

Wolfram Language code: Graphics3D[{Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 1}}, VertexColors -> {Blue, Yellow, Orange}]}]

Make a multicolored line:

Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {1, 1}, {2, 0}}, VertexColors -> {StandardRed, StandardYellow, StandardGreen}]}]

Scope  (17)

Graphics Objects  (5)

Polygon:

Wolfram Language code: Graphics[Polygon[{{-1, 0}, {1, 0}, {0, Sqrt[3]}}, VertexColors -> {Red, Green, Blue}]]

Multi-polygons:

Wolfram Language code: Graphics[Polygon[{{{-1, 0}, {1, 0}, {0, Sqrt[3]}}, {{2, 0}, {4, 0}, {3, Sqrt[3]}}}, VertexColors -> {{Red, Green, Blue}, {Yellow, Cyan, Magenta}}]]

Line:

Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {2, 1}}, VertexColors -> {Red, Green}]}]
Wolfram Language code: Graphics[{Thick, Line[{{{0, 0}, {2, 1}}, {{1, 0}, {3, 1}}}, VertexColors -> {{Red, Green}, {Yellow, Blue}}]}]

Multi-points:

Wolfram Language code: Graphics[{PointSize[0.1], Point[{{0, 0}, {1, 1}, {2, 2}}, VertexColors -> {StandardRed, StandardYellow, StandardBlue}]}]

Triangle:

Wolfram Language code: Graphics[{Triangle[{{0, 0}, {0, 1}, {1, 1}}, VertexColors -> {Red, Green, Blue}]}]

Multi-triangles:

Wolfram Language code: Graphics[{Triangle[{{{0, 0}, {0, 1}, {1, 1}}, {{2, 0}, {2, 1}, {3, 1}}}, VertexColors -> {{Red, Green, Blue}, {Yellow, Cyan, Magenta}}]}]

In a GraphicsComplex, colors can be assigned for shared vertices:

Wolfram Language code: Graphics[{GraphicsComplex[{{0, 0}, {1, 0}, {0, 1}, {1, 1}, {.5, .5}}, {Polygon[{1, 2, 5}], Polygon[{3, 4, 5}]}, VertexColors -> {LightRed, DarkRed, LightBlue, DarkBlue, Purple}]}]

Graphics3D primitives and Shapes  (5)

Polygon:

Wolfram Language code: Graphics3D[Polygon[{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

Multi-polygons:

Wolfram Language code: Graphics3D[Polygon[{{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, {{0, -1, 1}, {0, 1, 1}, {-1, 0, 2}}}, VertexColors -> {{Red, Green, Blue}, {Cyan, Magenta, Yellow}}]]

Line:

Wolfram Language code: Graphics3D[{Thick, Line[{{0, 0, 0}, {1, 1, 1}, {2, 2, 1}}, VertexColors -> {Red, Green, Yellow}]}]

Multilines:

Wolfram Language code: Graphics3D[{Thick, Line[{{{0, 0, 0}, {2, 1, 1}}, {{1, 0, 0}, {3, 1, 1}}}, VertexColors -> {{Red, Green}, {Blue, Yellow}}]}]

Tube:

Wolfram Language code: Graphics3D[{Tube[{{0, 0, 0}, {1, 1, 1}, {2, 2, 1}}, 0.1, VertexColors -> {Red, Green, Yellow}]}]

Multi-tubes:

Wolfram Language code: Graphics3D[{Tube[{{{0, 0, 0}, {2, 1, 1}}, {{1, 0, 0}, {3, 1, 1}}}, .2, VertexColors -> {{Red, Green}, {Blue, Yellow}}]}]

Points:

Wolfram Language code: Graphics3D[{PointSize[0.1], Point[{{0, 0, 0}, {1, 1, 1}, {2, 1, 0}}, VertexColors -> {StandardRed, StandardGreen, StandardOrange}]}, PlotRangePadding -> .1]

In a GraphicsComplex, colors can be assigned for shared vertices:

Wolfram Language code: v = {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}};
Wolfram Language code: i = {{1, 2, 5}, {2, 3, 5}, {3, 4, 5}, {4, 1, 5}};
Wolfram Language code: Graphics3D[{GraphicsComplex[v, Polygon[i], VertexColors -> {Red, Green, Yellow, Blue, Opacity[.8, White]}]}]

Color Specification  (5)

Color directives can have different values for opacity:

Wolfram Language code: Graphics3D[Polygon[{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, VertexColors -> {RGBColor[0, 1, 0, .1], RGBColor[0, 1, 0, .4], RGBColor[0, 1, 0, .9]}]]

Directive can be used to combine a color with Opacity:

Wolfram Language code: Graphics3D[Polygon[{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, VertexColors -> {Red, Green, Directive[Blue, Opacity[.5]]}]]

Color directives representing different color spaces can be mixed:

Wolfram Language code: Graphics[Polygon[{{0, -1}, {0, 1}, {-1, 0}}, VertexColors -> {RGBColor[0, 1, 0], GrayLevel[.2], LABColor[.6, .5, 1]}]]

LightDarkSwitched specifications can be used:

Wolfram Language code: g = Graphics[{Thickness[.1], Line[{{0, 0}, {1, 1}}, VertexColors -> {LightDarkSwitched[LightRed, LightBlue], LightDarkSwitched[DarkRed, DarkBlue]}]}]; {Rasterize[g, LightDark -> "Light"], Rasterize[g, LightDark -> "Dark"]}

Use a raw number list to specify {red,green,blue} instead of RGBColor:

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]}]

Similarly, specify {red,green,blue,opacity}:

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {{1, 0, 0, .1}, {0, 1, 0.9}, {0, 0, 1, .5}}]}]

To specify gray levels, use {gray1,gray2,…}

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {.1, .9, .4}]}]

Gray level with opacity is specified as {gray,opacity}

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {{.5, 0}, {.5, 1}, {.5, .5}}]}]

Visualization Functions  (2)

ListPlot3D:

Wolfram Language code: ListPlot3D[{{0, 0, 1}, {1, 0, 0}, {0, 1, 0}}, VertexColors -> {Red, Green, Blue}, Lighting -> "Neutral"]

ListDensityPlot:

Wolfram Language code: ListDensityPlot[{{0, 0, 1}, {1, 0, 0}, {0, 1, 0}}, VertexColors -> {Red, Green, Blue}]

Possible Issues  (2)

Vertex colors specified within segments of a FilledCurve are ignored:

Wolfram Language code: Graphics[{EdgeForm[Thick], Pink, FilledCurve[Line[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Yellow}]]}]

A VertexColors list that is too short uses the default color for remaining points:

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {1, 1}, {2, 0}}, VertexColors -> {StandardOrange, StandardBlue}]}]

If the default primitive color has been changed by a directive, that will be used:

Wolfram Language code: Graphics[{StandardPurple, Polygon[{{0, 0}, {1, 1}, {2, 0}}, VertexColors -> {StandardOrange, StandardBlue}]}]

Neat Examples  (2)

Create opacity gradients on 3D polygons:

Wolfram Language code: PolyhedronData["GreatRhombicosidodecahedron"] /. Polygon[x_] :> Polygon[x, VertexColors -> Map[Opacity[If[EvenQ[#], 0, 1], White]&, x, {-1}]]

Use an image from ExampleData:

Wolfram Language code: pic = Reverse[ExampleData[{"TestImage", "Sailboat"}, "Data"] / 255.];

Plot the dataset with vertex colors, simulating the texture:

Wolfram Language code: ListPlot3D[Table[x + Sin[x y], {x, -5, 5, .1}, {y, -5, 5, .1}], Mesh -> None, VertexColors -> {pic[[5 ;; -5 ;; 5, 5 ;; -5 ;; 5]]}, Lighting -> "Neutral"]
Wolfram Research (2007), VertexColors, Wolfram Language function, https://reference.wolfram.com/language/ref/VertexColors.html (updated 2008).

Text

Wolfram Research (2007), VertexColors, Wolfram Language function, https://reference.wolfram.com/language/ref/VertexColors.html (updated 2008).

CMS

Wolfram Language. 2007. "VertexColors." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2008. https://reference.wolfram.com/language/ref/VertexColors.html.

APA

Wolfram Language. (2007). VertexColors. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/VertexColors.html

BibTeX

@misc{reference.wolfram_2026_vertexcolors, author="Wolfram Research", title="{VertexColors}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/VertexColors.html}", note=[Accessed: 13-June-2026]}

BibLaTeX

@online{reference.wolfram_2026_vertexcolors, organization={Wolfram Research}, title={VertexColors}, year={2008}, url={https://reference.wolfram.com/language/ref/VertexColors.html}, note=[Accessed: 13-June-2026]}