Wolfram Language & System Documentation Center

FilledCurve

FilledCurve[{segment₁,segment₂,…}]

represents a filled curve consisting of segment₁ followed by segment₂ etc.

FilledCurve[{component₁,component₂,…}]

represents a list of separate filled component curves component₁, component₂, etc.

Details and Options

FilledCurve can be used in Graphics (two-dimensional graphics).
FilledCurve[segment] is equivalent to FilledCurve[{segment}].
Possible forms of segment_i include:
Line[{pt₁,pt₂,…}] lines

BezierCurve[{pt₁,pt₂,…},…] Bézier curve

BSplineCurve[{pt₁,pt₂,…},…] B-spline curve
The first point on segment_i is taken to be the last point on segment_i-1. FilledCurve[{pr₁[{p₁,…,p_i}],pr₂[{q₁,…,q_j}],…}] is equivalent to FilledCurve[{pr₁[{p₁,…,p_i}],pr₂[{p_i,q₁,…,q_j}],…}].
Filled curves can be non-convex and intersect themselves. Self-intersecting curves are filled according to an even-odd rule that alternates between filling and not at each crossing.
FilledCurve[{component₁,component₂,…}] treats each component curve as a separate closed curve, but the filling behavior is determined as if they were part of the same curve.
The coordinates can be specified using:

	{x,y}	ordinary coordinates
	Scaled[{x,y}]	scaled coordinates
	ImageScaled[{x,y}]	image scaled coordinates
	Offset[{dx,dy},{x,y}]	absolute offset coordinates

Individual coordinates and lists of coordinates in segments can be Dynamic objects.
FaceForm and EdgeForm can be used to specify how the interiors and boundaries should be rendered.
Edge thickness can be specified using Thickness or AbsoluteThickness, as well as Thick, Thin, etc. in EdgeForm.
Edge dashing can be specified using Dashing or AbsoluteDashing, as well as Dashed, Dotted, etc. in EdgeForm; for FilledCurve the dashing will be computed across all segments for each component curve.
Edge coloring and transparency can be specified using CMYKColor, GrayLevel, Hue, Opacity, or RGBColor in EdgeForm.
Joining of curve segments can be specified using JoinForm.
Face coloring and transparency can be specified using CMYKColor, GrayLevel, Hue, Opacity, or RGBColor in FaceForm.
A texture can be applied using Texture and will be mapped to the curve using the VertexTextureCoordinates option specified for the curve.
VertexColors and VertexNormals options to Line will have no effect within a FilledCurve construct.

Examples

open all close all

Basic Examples (4)

Filled curve from a Bézier segment:

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};

Wolfram Language code: Graphics[FilledCurve[{BezierCurve[a]}]]

Filled curve with mixed curve segments:

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};

Wolfram Language code: Graphics[FilledCurve[{BezierCurve[a], Line[b]}]]

Filled curve with a hole:

Wolfram Language code: pts = {{0, 1}, {-1, -(1/2)}, {1, -(1/2)}};

Wolfram Language code: Graphics[FilledCurve[{{Line[2pts]}, {Line[pts]}}]]

Self-intersecting filled curve:

Wolfram Language code: Graphics[FilledCurve[{{Line[pts]}, {Line[TranslationTransform[{1, (1/2)}][pts]]}}]]

Differently styled filled curves:

Wolfram Language code:

a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};curve = FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}];

Wolfram Language code:

{Graphics[{Pink, curve}], Graphics[{EdgeForm[Thick], Pink, curve}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, curve}]}

Texture-mapped filled curve:

Wolfram Language code:

Graphics[{Texture[ExampleData[{"TestImage", "House"}]], FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}, VertexTextureCoordinates -> {{{0, (1/2)}, {(1/2), 1}, {1, (1/2)}, {(1/2), (1/12)}, {0, (1/2)}}, {{(1/4), (1/2)}, {(1/2), (3/4)}, {(3/4), (1/2)}, {(1/2), (7/24)}, {(1/4), (1/2)}}}]}]

Scope (15)

Graphics (9)

Specification (3)

Filled curve with a single line segment:

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[Line[{{-1, 0}, {-1, 1}, {0, 2}, {1, 1}, {1, 0}}]]}]

Filled curve with a single Bézier curve segment:

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[BezierCurve[{{-1, 0}, {-1, 2}, {1, 2}, {1, 0}}]]}]

Filled curve with a single B-spline curve segment:

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[BSplineCurve[{{-1, 0}, {-1, 1}, {0, 0}, {1, 1}, {1, 0}}]]}]

Filled curve with mixed curve segments:

Wolfram Language code:

Graphics[{Pink, EdgeForm[Blue], FilledCurve[{BSplineCurve[{{-2, 0}, {-1, 1}, {0, -1}, {1, 1}, {2, 0}}], Line[{{2, -1}, {-2, -1}}]}]}]

Filled curve with a hole:

Wolfram Language code:

Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {Line[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}]

Filled curve with multiple holes:

Wolfram Language code: pts = {{0, 1}, {-(Sqrt[3]/2), -(1/2)}, {(Sqrt[3]/2), -(1/2)}};

Wolfram Language code:

Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[4pts]}, {Line[TranslationTransform[{-1, 0}][pts]]}, {Line[TranslationTransform[{1, 0}][pts]]}}]}]

Filled curve with multiple components:

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[3pts]}, {Line[2pts]}, {Line[pts]}}]}]

Filled curve with self-intersections:

Wolfram Language code:

Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[pts]}, 
	{Line[TranslationTransform[{(Sqrt[3]/2), (1/2)}][pts]]}, {Line[TranslationTransform[{Sqrt[3], 1}][pts]]}}]}]

Styling (3)

Color directives specify the face colors of filled curves:

Wolfram Language code:

Table[Graphics[{c, FilledCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm and EdgeForm can be used to specify the styles of the interiors and boundaries:

Wolfram Language code:

Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], FilledCurve[{{BSplineCurve[{{-2, 0}, {-2, 2}, {0, 4}, {2, 2}, {2, 0}}]}, {BSplineCurve[{{-1, 1}, {-1, 2}, {0, 3}, {1, 2}, {1, 1}}]}}]}]

JoinForm can be used to specify the type of joins of boundaries:

Wolfram Language code: a = {{-2, 0}, {0, 2}, {2, 0}, {0, -2}};curve = FilledCurve[{{Line[2a]}, {Line[a]}}];

Wolfram Language code:

{Graphics[{EdgeForm[{JoinForm["Bevel"], Thickness[0.05]}], Pink, curve}, PlotRange -> 5], Graphics[{EdgeForm[{JoinForm["Meter"], Thickness[0.05]}], Pink, curve}, PlotRange -> 5]Graphics[{EdgeForm[{JoinForm["Round"], Thickness[0.05]}], Pink, curve}, PlotRange -> 5]}

Coordinates (3)

Use Scaled coordinates:

Wolfram Language code: Graphics[FilledCurve[BezierCurve[{Scaled[{0, 0}], Scaled[{.5, 1}], Scaled[{1, 0}]}]], Frame -> True]

Use ImageScaled coordinates:

Wolfram Language code: Graphics[FilledCurve[BezierCurve[{ImageScaled[{0, 0}], ImageScaled[{.5, 1}], ImageScaled[{1, 0}]}]], Frame -> True]

Use Offset coordinates:

Wolfram Language code:

Graphics[FilledCurve[BezierCurve[{Offset[{10, 10}, {0, 0}], Offset[{0, 50}, {.5, 1}], Offset[{-10, 10}, {1, 0}]}]], Frame -> True]

Regions (6)

Embedding dimension:

Wolfram Language code:

RegionEmbeddingDimension[FilledCurve[{BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]}]]

Geometric dimension:

Wolfram Language code:

RegionDimension[FilledCurve[{BSplineCurve[{{Subscript[c, 1], Subscript[c, 2]}, {Subscript[c, 3], Subscript[c, 4]}, {Subscript[c, 5], Subscript[c, 6]}}]}]]

Point membership test:

Wolfram Language code:

{RegionMember[FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}], {0, 0}], RegionMember[FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}], {1, 2}]}

Arc length:

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];

Wolfram Language code: {ArcLength[ℛ], RegionMeasure[ℛ]}

Centroid:

Wolfram Language code: c = RegionCentroid[ℛ]

Wolfram Language code: Graphics[{{Yellow, ℛ}, {Red, Point[c]}}]

Distance from a point:

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];

Wolfram Language code: {RegionDistance[ℛ, {1, 1}], RegionDistance[ℛ, {0, 0}]}

The distance to the nearest point for the filled curve:

Wolfram Language code:

{Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> Norm[{x, y}] == 1], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -3, 4}, {y, -3, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

Signed distance from a point:

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];

Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1}], SignedRegionDistance[ℛ, {0, 0}]}

Signed distance to the filled curve:

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Exclusions -> Norm[{x, y}] == 1, Mesh -> None]

A filled curve is bounded:

Wolfram Language code: ℛ = FilledCurve[{BSplineCurve[{{0, 0}, {1, 1}, {2, -1}}]}];

Wolfram Language code: BoundedRegionQ[ℛ]

Get its range:

Wolfram Language code: rr = RegionBounds[ℛ]

Wolfram Language code: Graphics[{{EdgeForm[Directive[Dashed, Red]], Opacity[0.1], Yellow, Rectangle@@Transpose[rr]}, ℛ}]

Generalizations & Extensions (2)

Each curve segment can have its own options for fine control:

Wolfram Language code:

pts = {{0., -0.5}, {0.5, -0.5}, {0.5, 0.5}, {0., 0.5}, {-0.5, 0.5}, {-0.5, -0.5}, {0., -0.5}};
w = {1, .5, .5, 1, .5, .5, 1};
k = {0, 0, 0, 1 / 4, 1 / 2, 1 / 2, 3 / 4, 1, 1, 1};

Wolfram Language code:

Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{BSplineCurve[2pts, SplineDegree -> 2, SplineKnots -> k, SplineWeights -> w]}, {BSplineCurve[pts, SplineDegree -> 2, SplineKnots -> k, SplineWeights -> w]}}]}]

By default, a Bézier segment will be attached without considering the tangent at the joining:

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[{{0, 0}, {2, 2}}], BezierCurve[{{4, 2}, {5, 1}, {6, 0}}]}}]}]

Automatic can be used in the first coordinate of a Bézier segment to create a smooth joint:

Wolfram Language code: Graphics[{Pink, EdgeForm[Blue], FilledCurve[{{Line[{{0, 0}, {2, 2}}], BezierCurve[{Automatic, {5, 1}, {6, 0}}]}}]}]

Options (2)

VertexTextureCoordinates (2)

Texture mapping with a filled Bézier curve:

Wolfram Language code:

Graphics[{Texture[ExampleData[{"TestImage", "House"}]], FilledCurve[{BezierCurve[{{-1, 0}, {0, 1}, {1, 0}}]}, VertexTextureCoordinates -> {{0, 0}, {1 / 2, 1}, {1, 0}}]}]

Texture mapping mapped to multiple component curves:

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}, {-1, 0}};

Wolfram Language code:

Graphics[{Texture[ExampleData[{"TestImage", "House"}]], FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}, VertexTextureCoordinates -> {{{0, (1/2)}, {(1/2), 1}, {1, (1/2)}, {(1/2), (1/12)}, {0, (1/2)}}, {{(1/4), (1/2)}, {(1/2), (3/4)}, {(3/4), (1/2)}, {(1/2), (7/24)}, {(1/4), (1/2)}}}]}]

Applications (5)

Graphics, Glyphs, etc. (2)

Define a letter with a filled curve:

Wolfram Language code:

a = FilledCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], 
	BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], 
	Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], 
	BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, 
	{Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}];

Wolfram Language code: Graphics[a]

Wolfram Language code: Graphics[{EdgeForm[Blue], LightGray, a}]

Extract a filled curve from a graphic:

Wolfram Language code: g = First[[image]];

Wolfram Language code: Head[g]

Rotate the glyph around the origin:

Wolfram Language code:

Graphics[{EdgeForm[Gray], 
	Table[{Hue[(t/2 π)], Rotate[g, t, {0, 0}]}, {t, 0, 2 π, (π/6)}]}]

Text Effects (1)

Import text as a filled curve in graphics, using PDF as an intermediate format:

Wolfram Language code:

text = First[First[ImportString[ExportString[Style["Wolfram", Italic, FontSize -> 24, FontFamily -> "Times"], "PDF"], {"PDF", "PageGraphics"}, "TextMode" -> "Outlines"]]];

Outline fonts using different edge and face forms:

Wolfram Language code: Graphics[{EdgeForm[Black], ColorData["Crayola", "Sunglow"], text}]

Cast the shadow by translation:

Wolfram Language code: Graphics[{Gray, Translate[text, {1, -1}], Red, text}]

3D text effect:

Wolfram Language code:

Graphics[{EdgeForm[Opacity[0.5]], Table[{ColorData["TemperatureMap"][t], Translate[text, 4{-t, t}]}, {t, 0, 1, (1/10)}]}, ImageSize -> Medium]

Text Banner (1)

Import text as a filled curve:

Wolfram Language code:

text = First[First[ImportString[ExportString[Style["MATHEMATICA", FontSize -> 72, FontFamily -> "Geogia"], "PDF"], {"PDF", "PageGraphics"}, "TextMode" -> "Outlines"]]];

Wolfram Language code: Graphics[text, Frame -> True]

Create envelope functions of banners using BSplineFunction:

Wolfram Language code:

top = BSplineFunction[{60, 200, 160}];
middle = BSplineFunction[{45, 150, -30, 45}];bottom = BSplineFunction[{-90, -100, 30}];

Wolfram Language code: Plot[{top[t], middle[t], bottom[t]}, {t, 0, 1}]

Define a function to rescale coordinates according to coordinates and envelope functions:

Wolfram Language code: stretch[x_, t_, f_, g_] := Rescale[x, {10, 60}, {f[t], g[t]}]

Deform the filled curves by replacing coordinates:

Wolfram Language code:

banner1 = text /. {x_Real, y_Real} :> {x, stretch[y, (x/430), bottom, middle]};
banner2 = text /. {x_Real, y_Real} :> {430 - x, stretch[y, 1 - (x/430), middle, top]};

Display:

Wolfram Language code: Graphics[{EdgeForm[Black], Blue, banner1, Red, banner2}]

Tessellation (1)

Create a curved edge of a tile:

Wolfram Language code: e1 = {{-(Sqrt[3]/2), -(1/2)}, {-(Sqrt[3]/6), 0}, {(Sqrt[3]/6), -1}, {(Sqrt[3]/2), -(1/2)}};

Wolfram Language code: Graphics[BezierCurve[{e1}], Axes -> True]

Rotate it by 120° to get additional edges:

Wolfram Language code:

e2 = Map[RotationTransform[120Degree], e1];
e3 = Map[RotationTransform[120Degree], e2];

Make a single tile with Bézier curve edges using a filled curve:

Wolfram Language code: tile = FilledCurve[{BezierCurve[e1], BezierCurve[Rest[e2]], BezierCurve[Rest[e3]]}];

Wolfram Language code: Graphics[{EdgeForm[Gray], FaceForm[Opacity[(1/2), Blue]], tile}, Axes -> True, Frame -> True, PlotRange -> 1]

Tile the plane by rotating and translating it:

Wolfram Language code:

Graphics[{EdgeForm[Opacity[(1/4), White]], FaceForm[Red], Table[With[{p = OddQ[i]⊻OddQ[j]} , {If[p, ColorData["HTML", "Crimson"], ColorData["HTML", "DarkBlue"]], Translate[Rotate[tile, (π/3) Boole[p], {0, 0}], {(Sqrt[3] i/2), (3 j/2) + (1/2) Boole[p]}]}], {i, 10}, {j, 4}]}]

Use line edges instead:

Wolfram Language code: % /. BezierCurve[a_] :> Line[a]

Properties & Relations (1)

By default, each component of a filled curve closes itself by adding a line segment at the end:

Wolfram Language code: a = {{-1, 0}, {0, 1}, {1, 0}};b = {{0, -(2/3)}};

Wolfram Language code: Graphics[{EdgeForm[Blue], Pink, FilledCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}]}]

On the contrary, JoinedCurve does not close the component by default:

Wolfram Language code: Graphics[JoinedCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}]]

Use the CurveClosed option to close the components in a curve:

Wolfram Language code: Graphics[JoinedCurve[{{BezierCurve[2a], Line[2b]}, {BezierCurve[a], Line[b]}}, CurveClosed -> True]]

Possible Issues (1)

VertexColors options specified within segments are ignored:

Wolfram Language code:

Graphics[{EdgeForm[Thick], Pink, FilledCurve[Line[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Yellow}]]}]

Neat Examples (2)

Random filled curves:

Wolfram Language code:

Module[{a = FilledCurve[{{Line[{{2, 3}, {0.8125, 0.625}}], 
	BezierCurve[{{0.6875, 0.375}, {0.375, 0.25}, {1.125, 0.25}}, SplineDegree -> 2], BezierCurve[{{0.8125, 0.375}, {0.9375, 0.625}}], 
	Line[{{1.3125, 1.375}, {2.4375, 1.375}, {2.8125, 0.625}}], 
	BezierCurve[{{2.9375, 0.375}, {2.625, 0.25}, {3.625, 0.25}}, SplineDegree -> 2], BezierCurve[{{3.3125, 0.375}, {3.1875, 0.625}}]}, 
	{Line[{{1.875, 2.5}, {1.375, 1.5}, {2.375, 1.5}}]}}]}, Graphics[Table[{EdgeForm[Black], Hue[RandomReal[]], Translate[Rotate[Scale[a, RandomReal[5]], RandomReal[2Pi]], RandomReal[20, {2}]]}, {30}]]]

Waving text banner:

Wolfram Language code:

Module[{l = Cases[First[First[ImportString[ExportString[Style["Mathematica", Bold, FontFamily -> "Helvetica", FontSize -> 12], "PDF"], {"PDF", "PageGraphics"}, "TextOutlines" -> True]]], FilledCurve[a__] :> {EdgeForm[Black], Yellow, FilledCurve[a]}, Infinity]}, Animate[Graphics[{l /. {x_Real, y_Real} :> {x, y + 6 Sin[(x/12) + t]}}], {t, 0, 8 π}, AnimationRunning -> False, SaveDefinitions -> True]]

Top

More Learning

Tech Support

Wolfram Solutions

Wolfram Solutions For Education

Get Started

Grow Your Skills

Work with Us

Educational Programs for Adults

Educational Programs for Youth

Read

FilledCurve

Details and Options

Examples

Basic Examples (4)

Scope (15)

Graphics (9)

Specification (3)

Styling (3)

Coordinates (3)

Regions (6)

Generalizations & Extensions (2)

Options (2)

VertexTextureCoordinates (2)

Applications (5)

Graphics, Glyphs, etc. (2)

Text Effects (1)

Text Banner (1)

Tessellation (1)

Properties & Relations (1)

Possible Issues (1)

Neat Examples (2)

Text

CMS

APA

BibTeX

BibLaTeX

	Line[{pt₁,pt₂,…}]	lines
	BezierCurve[{pt₁,pt₂,…},…]	Bézier curve
	BSplineCurve[{pt₁,pt₂,…},…]	B-spline curve

FilledCurve

Details and Options

Examples

Basic Examples (4)

Scope (15)

Graphics (9)

Specification (3)

Styling (3)

Coordinates (3)

Regions (6)

Generalizations & Extensions (2)

Options (2)

VertexTextureCoordinates (2)

Applications (5)

Graphics, Glyphs, etc. (2)

Text Effects (1)

Text Banner (1)

Tessellation (1)

Properties & Relations (1)

Possible Issues (1)

Neat Examples (2)

See Also

Related Guides

Related Links

History

Text

CMS

APA

BibTeX

BibLaTeX